
[bookmark: _GoBack]Stata codes to simulate data
/* Age and DAS28 at baseline for males */
clear
matrix C = (1, .15 \ .15, 1)
corr2data das28_0 age, means(4 65) sds(1.2 13) corr(C) n(100) seed(1)
generate sex = 0
save "simulated data.dta", replace 
/* Age and DAS28 at baseline for females */
clear
corr2data das28_0 age, means(4.2 60) sds(1.2 13) corr(C) n(200) seed(2)
generate sex = 1  
replace das28_0 = 8 if das28_0 > 8
replace das28_0 = 1 if das28_0 <1
append using "simulated data.dta"
/* DAS28 at follow-up */
set seed 3
generate das28_1 = 0.5*das28_0 + 0.02*age + 0.05*sex + 0.3 +rnormal(0,1)
replace das28_1 = 10 if das28_1 > 10
replace das28_1 = 0 if das28_1 <0
/* Treatment allocation, label variables and patient id */
generate p = 1/(1+exp(-(0.25*das28_0  + 0.2*age + 0.4*sex - 14)))
generate treatment = rbinomial(1,p)
drop p
generate id = _n
order id, first
label variable id "Patient id"
replace das28_0 = round(das28_0, 0.1)
label variable das28_0 "DAS28 at baseline"
replace das28_1 = round(das28_1, 0.1)
label variable das28_1 "DAS28 at follow-up" 
replace age = round(age, 0.1)
label variable age "Age"
label variable sex "Sex"
label variable treatment "Treatment"
save "simulated data.dta", replace

