You are free to use this script. If you find it useful please cite the corresponding paper  "High Finesse Fiber Fabry-Pérot Cavities: Stabilization and Mode Matching". 
For questions and comments contact J. Gallego "gallego@iap.uni-bonn.de".

Please make sure that the data file 'data.csv' and the two '.jpg' figures are in the same folder as this Mathematica notebook;

1.Parameters;

Laser light;
c:=3*(10^8);(*[m/s] Speed of light in vacuum*)
(Subscript[n, f]):=1.45367;(*Refractive index of the fiber ((Subscript[SiO, 2])),no (Subscript[Ta, 2])(Subscript[O, 5]) coating taken into account*)
(Subscript[λ, laser]):=0.85;(*[µm] Optical wavelength of the laser light *)
(Subscript[ν, laser]):=(c/(Subscript[λ, laser]));(*[MHz] Radial frequency of the laser light *)
(Subscript[k, f]):=((2π (Subscript[n, f]))/(Subscript[λ, laser]));(*[((µm)^(-1))] k-vector of the laser light inside the fiber*)

Mirrors coating;
(Subscript[𝒯, HT]):=490*(10^(-6));  (*[ppm] Transmission of the incoupling mirror @850nm*)
(Subscript[𝒯, LT]):=0.9*(10^(-6));(*[ppm] Transmission of the outcoupling mirror @850nm*)
(Subscript[ℒ, HT]):=26*(10^(-6)); (*[ppm] Absorption and Scattering losses of the incoupling mirror @850nm*)
(Subscript[ℒ, LT]):=4*(10^(-6));(*[ppm] Absorption and Scattering losses of the outcoupling mirror @850nm*)
(Subscript[ℒ, sum]):=(Subscript[𝒯, HT])+(Subscript[𝒯, LT])+(Subscript[ℒ, HT])+(Subscript[ℒ, LT]); (*[ppm] Total cavity round-trip losses @850nm*)

Geometry  of the hybrid cavity;
(Subscript[R, HT]):=150;(*[ Radius Of Curvature (ROC) for the incoupling mirror; average from the two axis of the ellipsoid*)
(Subscript[R, LT]):=50000;(*[µm] Radius Of Curvature (ROC) for the outcoupling mirror*)
(Subscript[w, f]):=2.6; (*[µm] Mode field radius of the fiber core mode*)
(Subscript[d, f]):=2; (*[µm]Decentrarion from the core of the incoupling fiber to the geometrical center of the mirror structure*)
(Subscript[L, cav]):=16.9;(*[µm] Cavity lenght*)

Cavity mode and cavity linewidth ;
g[L_,R_]:=1-L/R;(*Resonator g-parameter, used for calculating spot-size at the mirror (Subscript[w, mirror])*)
(Subscript[w, mirror])[L_]:=(Sqrt[L((Subscript[λ, laser])/π)(Sqrt[g[L,(Subscript[R, LT])]/(g[L,(Subscript[R, HT])]*(1-g[L,(Subscript[R, HT])]g[L,(Subscript[R, LT])]))])]); (*[µm] Cavity-mode spot-size at the incoupling fiber-mirror for a given cavity length[µm]*)
(Subscript[w, cav]):=(Subscript[w, mirror])[(Subscript[L, cav])]; (*[µm] Cavity mode spot-size at the incoupling fiber-mirror*)
(Subscript[R, cav])=(Subscript[R, HT]) ;(*[µm] Cavity-modes wavefront radius of curvature*)
ℱ:=((2π)/(Subscript[ℒ, sum]));(*Cavity Finesse @850nm*)
(Subscript[Δν, FSR]):=(c/(2 (Subscript[L, cav])));(*[MHz] Cavity Free Spectral Range*)
κ:=((π c)/(2 (Subscript[L, cav]) ℱ)); (*[MHz] Half-Width Half-Maximum (HWHM) of the cavity transmission*)

2.Overlap Amplitudes α and β;
Overlap integral formalism ⟨(Subscript[Ψ, f])|Φ⟩ ;

The overlap integrals that appear in our model are α=⟨(Subscript[(SuperPlus[ψ]), cav])|(Subscript[(SuperPlus[ψ]), f])⟩ and β=⟨(Subscript[(SuperMinus[ψ]), f])|(Subscript[ψ, r])⟩. Therefore we only need to calculate overlaps of the kind ⟨((Subscript[ψ, f])^±)|ϕ⟩=(SuperStar[(⟨ϕ|((Subscript[ψ, f])^±)⟩)]), where |ϕ⟩ is a displaced, inclined Gaussian mode representing either the cavity or the reflected mode. For the fiber mode furthermore (Subscript[(SuperPlus[ψ]), f])(x,y)=(Subscript[(SuperMinus[ψ]), f])(x,y)=(Subscript[ψ, f])(x,y)∈ℝ holds, as shown below in (Subscript[ψ, f])[x_]= .....
The overlap integrals are computed as 2D integral over the x- and y-coordinates, performed at a certain plane z=(Subscript[z, 0]). All the beams involved in the calculations (fiber-, reflected- and cavity-modes) are Gaussian modes, whose spatial component separate into two independent orthogonal parts such that: ϕ(x,y)=(Subscript[ϕ, x])(x)(Subscript[ϕ, y])(y). 
This reduces the 2D overlap integral to a product of two 1D overlap integrals:

⟨(Subscript[ψ, f])|ϕ⟩=(∫_(-∞)^(+∞))(∫_(-∞)^(+∞))(SuperStar[(Subscript[ψ, f])])(x,y)ϕ(x,y)dxdy=(∫_(-∞)^(+∞))(SuperStar[(Subscript[ψ, f,x])])(x)(Subscript[ϕ, x])(x)dx (∫_(-∞)^(+∞))(SuperStar[(Subscript[ψ, f,y])])(y)(Subscript[ϕ, y])(y)dy

Fiber Mode;
(Subscript[ψ, f])[x_]:=((((2/(π ))))^(1/4))(Sqrt[(1/(Subscript[w, f]))])(E^(-((x^2)/((Subscript[w, f])^2))));(*1D Fiber-mode: Gaussian mode of waist (Subscript[w, f]) at the focus point (R+∞)*)
Reflected and Cavity Modes;
Φ[x_,k_,w_,R_,d_,θ_]:=((((2/(π ))))^(1/4))(Sqrt[(1/w)])(E^(-((((x-d))^2)/(w^2))))(E^(-I k((((x-d))^2)/(2R))))(E^(-I k (x-d)θ)); (*1D general Gaussian mode at a given z0 point with spotsize w=w(z0) and wavefront radius of R=R(z0) *)

Overlap integral ;
(*Overlap[k_,w1_,w2_,R2_,d2_,θ2_]=Integrate[Conjugate[(Subscript[ψ, f])[x]]*Φ[x,k,w2,R,d,θ],{x,-∞,∞},Assumptions->{k>0,k∈Reals,w2>0,w2∈Reals,R>0,R∈Reals,d∈Reals,θ∈Reals}]*)
Overlap[k_,w2_,R_,d_,θ_]:=((2 (E^(-(((d^2) (4 R+2 I k  (w2^2))-4 I d k R (w2^2) θ+(k^2) R ((Subscript[w, f])^2) (w2^2) (θ^2))/(2 I k ((Subscript[w, f])^2) (w2^2)+4 R (((Subscript[w, f])^2)+(w2^2)))))))/(Sqrt[(Subscript[w, f]) (((I k)/R)+2 ((1/((Subscript[w, f])^2))+(1/(w2^2)))) w2])); (*Analytical solution to the overlap integral depicted above*)


Geometrical considerations ;

For the calculation of mode matching power efficiencies ϵ, only the absolute value of the overlap integral matters, and the complex phase plays no role. Nevertheless, for the reflective mode matching problem the complex overlap amplitudes are the relevant and α and β must be evaluated at the very same z=(Subscript[z, 0]) plane. The position (Subscript[z, 0]) is nevertheless arbitrary as the problem is independent of the plane chosen at each cavity configuration.
We calculate the amplitudes for arbitrary cavity-mode alignment angles and fiber-mirror decentrations. For simplicity we choose the plane touching the lowest point of the mirror (see figure below) as the evaluation plane z=0. Since all the modes need to be described in the evaluation plane, we take into account the phase-shifts of the extra optical path required to propagate the modes to z=0. We are free to assume that the fiber mode (+ and -) has zero phase at z=0. Independently we consider that the cavity mode has zero phase at the surface of the curved mirror.
The cavity mode thus acquires an extra phase (Subscript[k, f])(Subscript[Δl, cav])((Subscript[θ, c])) before reaching the z=0 plane. The relative phase of the reflected mode|(Subscript[ψ, r])⟩ (compared to the fiber mode |(Subscript[(SuperPlus[ψ]), f])⟩) is approximately given by 2 (Subscript[k, f])(Subscript[Δl, f])((Subscript[d, f])) due to the optical path between z=0 and the mirror surface. Both lengths are calculated from geometrical considerations (always calculating in second order approximation of all transverse angles and coordinates) and the corresponding acquired phases add to α and β, respectively.

filePathFig1=NotebookDirectory[]<>"Supplementary_fig1.jpg";
OverlapPlane=Import[filePathFig1]

(Subscript[Δl, f])[df_]:=(1/2)((df^2)/(Subscript[R, HT])); (*[µm] Distance between z=0 plane and the position of the fiber-core at the mirror surface for a given fiber decentration (Subscript[d, f])[µm]*)
(Subscript[Δl, cav])[θcav_]:=(Subscript[R, HT]) (((θcav)^2)/2); (*[µm] Distance between z=0 plane and the position of the cavity-mode at the mirror surface for a given cavity-mode angle (Subscript[θ, cav])[µm]*)

dfx[ϕ_,df_]:=df*Cos[ϕ]; (*[µm] Fiber-mirror decentration in the x-axis*)
dfy[ϕ_,df_]:=df*Sin[ϕ]; (*[µm] Fiber-mirror decentration in the y-axis*)
dx[θcav_,ϕ_,df_]:=(Subscript[R, HT])*Sin[θcav]-dfx[ϕ,df]; (*[µm] x-axis distance between the fiber-core and the cavity-mode at a given cavity-mode angle (Subscript[θ, c,x])[rad]*)
dy[θcav_,ϕ_,df_]:=(Subscript[R, HT])*Sin[θcav]-dfy[ϕ,df];(*[µm] y-axis distance between the fiber-core and the cavity-mode at a given cavity-mode angle (Subscript[θ, c,y])[rad]*)

Coefficients;
α=(SuperStar[(⟨(Subscript[(SuperPlus[ψ]), f])|(Subscript[(SuperPlus[ψ]), cav])⟩)])  where |(Subscript[(SuperPlus[ψ]), cav])⟩is a right-propagating Gaussian beam with wavefront radius (Subscript[R, cav])=-|(Subscript[R, HT])|, a spot size w=(Subscript[w, cav]) and an angle (Subscript[θ, cav]). The Cavity mode also includes the (Subscript[k, f])(Subscript[Δl, cav])((Subscript[θ, c]))phase factor ;
β=⟨(Subscript[(SuperMinus[ψ]), f])|(Subscript[ψ, r])⟩ where |(Subscript[ψ, r])⟩is a left-propagating Gaussian beam with wavefront radius (Subscript[R, cav])=-(1/2)|(Subscript[R, HT])| a spot size w=(Subscript[w, f])and an angle θ=-2((Subscript[d, f])/(|(Subscript[R, HT])|)). The reflected mode also includes the 2 (Subscript[k, f])(Subscript[Δl, f])((Subscript[d, f]))phase factor ;

α[θcavx_,θcavy_,ϕ_,df_]:=(E^(-I (Subscript[k, f]) (Subscript[Δl, cav])[(Sqrt[((θcavx)^2)+((θcavy)^2)])]))Conjugate[Overlap[ (Subscript[k, f]),(Subscript[w, cav]),-(Subscript[R, HT]),dx[θcavx,ϕ,df],-θcavx]*Overlap[ (Subscript[k, f]),(Subscript[w, cav]),-(Subscript[R, HT]),dy[θcavy,ϕ,df],-θcavy]];
β[df_]:=(E^(-I (Subscript[k, f]) 2 (Subscript[Δl, f])[df])) Overlap[-(Subscript[k, f]),(Subscript[w, f]),-(Subscript[R, HT])/2,0,-2df/(Subscript[R, HT])]*Overlap[-(Subscript[k, f]),(Subscript[w, f]),-(Subscript[R, HT])/2,0,0]; (*β is the same independently of ϕ, so we choose ϕ=0*)




3.Reflected line shape;

ϵ[θcavx_,θcavy_,ϕ_,df_]:=Abs[((α[θcavx,θcavy,ϕ,df])^2)]; (*(Subscript[ϵ, HT]) mode matching efficiency*)
ηr[df_]:=((Abs[β[df]])^2);
ζ[νcav_]:=(((Subscript[𝒯, HT]) (E^( I 2π((((Subscript[ν, laser])-νcav))/(Subscript[Δν, FSR])) )))/(1-(1-(1/2)(Subscript[ℒ, sum]))(E^( I 2π((((Subscript[ν, laser])-νcav))/(Subscript[Δν, FSR]))  ))));  (*Complex amplitude containing information about the mirror coatings and cavity resonance ν[MHz]*)
Pout[νcav_,θcavx_,θcavy_,ϕ_,df_]:=((Abs[β[df]-((α[θcavx,θcavy,ϕ,df])^2)ζ[νcav]])^2); (*Reflected power*)

ηℒ[θcavx_,θcavy_,ϕ_,df_]:=((4(Subscript[𝒯, HT]))/(Subscript[ℒ, sum]))(Re[β[df]*Conjugate[((α[θcavx,θcavy,ϕ,df])^2)]]-((ϵ [θcavx,θcavy,ϕ,df])^2) (Subscript[𝒯, HT])/(Subscript[ℒ, sum])); (*Lorenztian amplitude*) 
𝒜[θcavx_,θcavy_,ϕ_ ,df_]:=((Im[β[df]*Conjugate[((α[θcavx,θcavy,ϕ,df])^2)]])/(Re[β[df]*Conjugate[((α[θcavx,θcavy,ϕ,df])^2)]]-((ϵ [θcavx,θcavy,ϕ,df])^2) (Subscript[𝒯, HT])/(Subscript[ℒ, sum]))); (*Asymmetry factor*) 
v[νcav_]:=((2π)/κ)((Subscript[ν, laser])-νcav); (*Dimensionless detuning*) 
(Subscript[v, min])[θcavx_,θcavy_,ϕ_,df_]:=((1-(Sqrt[1+((𝒜[θcavx,θcavy,ϕ,df])^2)]))/(𝒜[θcavx,θcavy,ϕ,df])); (*Shift of the minimum of reflected power dip from the resonance condition*) 
PoutTaylor[v_,θcavx_,θcavy_,ϕ_,df_]:=ηr[df]-ηℒ[θcavx,θcavy,ϕ,df]((1/(1+(v^2)))-𝒜[θcavx,θcavy,ϕ,df](v/(1+(v^2)))); (*Reflected power, taylor-expanded expression*)
ηdip[θcavx_,θcavy_,ϕ_,df_]:=1-(1/(ηr[df]))PoutTaylor[(Subscript[v, min])[θcavx,θcavy,ϕ,df],θcavx,θcavy,ϕ,df]; (*Reflected dip depth*)
4.Data;
filePathData=NotebookDirectory[]<>"data.csv";
filePathFig3=NotebookDirectory[]<>"Supplementary_fig2.jpg";
Import[filePathFig3]
data=Import[filePathData];

Scanned cavity mode angle (Subscript[θ, cav,x]) ≡θx ;
dataPoints=Length[data[[1]]]; (*Number of values for θx*)
θxSteps=1/25;(*Angle steps between consecutive data points*)
θxExp = Table[-i*θxSteps,{i,1,dataPoints}]; (*θx rotation angle of the outcoupling mirror with respect to the fiber-mirror in degrees*)
θxExpError=θxSteps/2;

Asymmetry factor 𝒜; 
𝒜Exp=data[[1]]; (*Asymmetry factor of the reflection dip, each point averaged over 10 measurements*)
𝒜ExpStd=data[[2]];(*Standard deviation of the average*)

Reflection dip depth (Subscript[η, dip]);
ηdipExp=data[[3]];(*Reflection Dip Depth, each point averaged over 10 measurements*)
ηdipExpStd=data[[4]]; (*Reflection Dip Depth standard deviation of the average*)

Mode matching coefficient (Subscript[ϵ, HT])≡ϵ;
ϵExp=data[[5]]; (*Transmission peak hight normalized to maximum transmission, each point averaged over 10 measurements*)
ϵExpStd=data[[6]]; (*Transmission peak hight standard deviation of the average*)

5.Fit;

Residual functions: (Subscript[f, Res])(i)=|f((Subscript[θx, i]))-(Subscript[data, i])((|)^2); 
ϵRes[i_,{θy_,ϕ_,θxOff_,CT_,d_}]:=((Abs[ϵ[θxExp [[i]]*π/180-θxOff,θy,ϕ,d]-ϵExp[[i]]*CT])^2);
ηdipRes[i_,{θy_,ϕ_,θxOff_,d_}]:=((Abs[ηdip[θxExp [[i]]*π/180-θxOff,θy,ϕ,d]-ηdipExp[[i]]])^2);
𝒜Res[i_,{θy_,ϕ_,θxOff_,d_}]:=((Abs[𝒜[θxExp [[i]]*π/180-θxOff,θy,ϕ,d]-𝒜Exp[[i]]])^2);
Residual[θy_,ϕ_,θxOff_,CT_,d_]:=(∑_(m=1)^dataPoints)(ϵRes[m,{θy,ϕ,θxOff,CT,d}]+ηdipRes[m,{θy,ϕ,θxOff,d}]+𝒜Res[m,{θy,ϕ,θxOff,d}]);

Initial guess and Lower/Upper boundaries; 

(*Photodiode calibration constant. Normalization of transmission peak height to theoretical value of ϵ*)
CT0=0.8;
CTLow=0.74;
CTUpp=0.82;

(*Cavity-mode x-axis angle offset θxOff[rad]*)
θxOff0=-2.35(π/180);
θxOffLow=-2.5(π/180);
θxOffUpp=-2.1(π/180);

(*Decentration-axis angle ϕ[rad]*)
ϕ0=0(π/180);
ϕLow=0(π/180);
ϕUpp=25(π/180);

(*Cavity-mode y-axis angle θy[rad]*)
θy0=0(π/180);
θyLow=-1(π/180);
θyUpp=1(π/180);

Fit;
FitResults=FindMinimum[{Residual[θy,ϕ,θxOff,CT,(Subscript[d, f])],θyLow≤ θy≤ θyUpp&&ϕLow≤ ϕ≤ ϕUpp&&θxOffLow≤θxOff≤ θxOffUpp &&CTLow≤ CT≤ CTUpp},{{θy,θy0},{ϕ,ϕ0},{θxOff,θxOff0},{CT,CT0}},MaxIterations->2000];

θyFit=θy/.FitResults[[2]];
ϕFit=ϕ/.FitResults[[2]];
θxOffFit=θxOff/.FitResults[[2]];
CTFit=CT/.FitResults[[2]];
dFit=(Subscript[d, f]);

Print["Fit parameters results"]
Print["CT = "<>ToString[CTFit]]
Print["(Subscript[θ, c, x, off]) = "<>ToString[θxOffFit*180/π]<>"˚"]
Print["ϕ = "<>ToString[ϕFit*180/π]<>"˚"]
Print["(Subscript[θ, c, y]) = "<>ToString[θyFit*180/π]<>"˚"]

Theory plots;
ϵPlot=Plot[ϵ[θx*π/180,θyFit,ϕFit,dFit],{θx,-1.5,3},PlotStyle->Darker[Blue],PlotRange->{-0.5,1.5},AxesOrigin->{-1.5,0},AxesLabel->{HoldForm[θx [˚]],None},AxesStyle->Directive[GrayLevel[0],AbsoluteThickness[2]],PlotLabel->None,LabelStyle->{FontFamily->"Helvetica Neue",20,GrayLevel[0],Bold}];
ηdipPlot=Plot[ηdip[θx*π/180,θyFit,ϕFit,dFit],{θx,-1.5,3},PlotStyle->Darker[Red]];
𝒜Plot=Plot[𝒜[θx*π/180,θyFit,ϕFit,dFit],{θx,-1.5,3},PlotStyle->Darker[Green]];

Experimental plots;

(*Tables to plot data+errorbars*)
Needs["ErrorBarPlots`"];
ϵData=Table[{{θxExp[[i]]-θxOffFit*(180/π),ϵExp[[i]]*CTFit},ErrorBar[θxExpError,ϵExpStd[[i]]]},{i,1,dataPoints}];
ηdipData=Table[{{θxExp[[i]]-θxOffFit*(180/π),ηdipExp[[i]]},ErrorBar[θxExpError,ηdipExpStd[[i]]]},{i,1,dataPoints}];
𝒜Data=Table[{{θxExp[[i]]-θxOffFit*(180/π),𝒜Exp[[i]]},ErrorBar[θxExpError,𝒜ExpStd[[i]]]},{i,1,dataPoints}];

ϵExpPlot=ErrorListPlot[ϵData,PlotStyle->Directive[Blue,PointSize[Small]]];
ηdipExpPlot=ErrorListPlot[ηdipData,PlotStyle->Directive[Red,PointSize[Small]]];
𝒜ExpPlot=ErrorListPlot[𝒜Data,PlotStyle->Directive[Green,PointSize[Small]]];

Show[{ϵPlot,ηdipPlot,𝒜Plot,ϵExpPlot,ηdipExpPlot,𝒜ExpPlot}]

Fit  with the decentration as an additional free parameter;
(*Fiber-mirror decentration d[µm]*)
d0=(Subscript[d, f]);
dLow=1.5;
dUpp=3;

FitResults=FindMinimum[{Residual[θy,ϕ,θxOff,CT,d],θyLow≤ θy≤ θyUpp&&ϕLow≤ ϕ≤ ϕUpp&&θxOffLow≤θxOff≤ θxOffUpp &&CTLow≤ CT≤ CTUpp && dLow≤ d≤ dUpp},{{θy,θy0},{ϕ,ϕ0},{θxOff,θxOff0},{CT,CT0},{d,d0}},MaxIterations->2000];

θyFit=θy/.FitResults[[2]];
ϕFit=ϕ/.FitResults[[2]];
θxOffFit=θxOff/.FitResults[[2]];
CTFit=CT/.FitResults[[2]];
dFit=d/.FitResults[[2]];

Print["Fit parameters results"]
Print["CT = "<>ToString[CTFit]]
Print["(Subscript[θ, c, x, off]) = "<>ToString[θxOffFit*180/π]<>"˚"]
Print["ϕ = "<>ToString[ϕFit*180/π]<>"˚"]
Print["(Subscript[θ, c, y]) = "<>ToString[θyFit*180/π]<>"˚"]
Print["(Subscript[d, f]) = "<>ToString[dFit]<>"µm"]

Theory plots;
ϵPlot=Plot[ϵ[θx*π/180,θyFit,ϕFit,dFit],{θx,-1.5,3},PlotStyle->Darker[Blue],PlotRange->{-0.5,1.5},AxesOrigin->{-1.5,0},AxesLabel->{HoldForm[θx [˚]],None},AxesStyle->Directive[GrayLevel[0],AbsoluteThickness[2]],PlotLabel->None,LabelStyle->{FontFamily->"Helvetica Neue",20,GrayLevel[0],Bold}];
ηdipPlot=Plot[ηdip[θx*π/180,θyFit,ϕFit,dFit],{θx,-1.5,3},PlotStyle->Darker[Red]];
𝒜Plot=Plot[𝒜[θx*π/180,θyFit,ϕFit,dFit],{θx,-1.5,3},PlotStyle->Darker[Green]];

Experimental plots;

(*Tables to plot data+errorbars*)
Needs["ErrorBarPlots`"];
ϵData=Table[{{θxExp[[i]]-θxOffFit*(180/π),ϵExp[[i]]*CTFit},ErrorBar[θxExpError,ϵExpStd[[i]]]},{i,1,dataPoints}];
ηdipData=Table[{{θxExp[[i]]-θxOffFit*(180/π),ηdipExp[[i]]},ErrorBar[θxExpError,ηdipExpStd[[i]]]},{i,1,dataPoints}];
𝒜Data=Table[{{θxExp[[i]]-θxOffFit*(180/π),𝒜Exp[[i]]},ErrorBar[θxExpError,𝒜ExpStd[[i]]]},{i,1,dataPoints}];

ϵExpPlot=ErrorListPlot[ϵData,PlotStyle->Directive[Blue,PointSize[Small]]];
ηdipExpPlot=ErrorListPlot[ηdipData,PlotStyle->Directive[Red,PointSize[Small]]];
𝒜ExpPlot=ErrorListPlot[𝒜Data,PlotStyle->Directive[Green,PointSize[Small]]];

Show[{ϵPlot,ηdipPlot,𝒜Plot,ϵExpPlot,ηdipExpPlot,𝒜ExpPlot}]