In-plane free vibration analysis of an inclined taut cable with a point mass

Acta Mechanica

Moritz (Patreider^(1,2)), Markus (Wenin^2), Christoph (Adam^(1,* )) and Thomas ((Furtmüller)^1)

1Unit of Applied Mechanics, University of Innsbruck, Technikerstr. 13, Innsbruck, 6020, Austria
2CPE Computational Physics and Engineering, Weingartnerstr. 28, Lana, 39011, Italy

*Corresponding author. E-mail: christoph.adam@uibk.ac.at

An analytical theory for predicting the free in-plane vibrations of an inclined taut cable carrying a \txtr{point} mass is presented in this paper. A linearized eigenvalue formulation of the problem is derived. It is based on the nonlinear equations of motion and the quasi-static stretching assumption, which assumes that the dynamic tension is piecewise constant to the left and right of the point mass. By neglecting the equation of motion for the longitudinal vibrations in favor of the constitutive cable equation, the equation governing the lateral vibrations can be solved using its boundary conditions. Two coupled linear equations, whose non-trivial solution gives the natural frequencies of the system, can be constructed from the jump and continuity conditions in the longitudinal direction. The comparison of the results with those of a known Galerkin procedure shows that the analytical theory is sufficiently accurate in the applicable parameter range. These results reproduce the curve-veering and the elastic mode transition phenomena known from previous studies. As such, the theory presented here extends the range of applicability of previous analytical cable theories to include inclined cables with point masses as well.

The addition of the letter b to any variable corresponds to the dimensionless version of said variable that is represented by a bar in the paper. Example: ξb ⧦ (OverBar[ξ])

Supplementary material showing expressions too large to be reproduced in the paper

2.2 Static equilibrium configuration

Equations (15) and (16) in the manuscript giving the static equilibrium equations in rotated coordinates

(*static equilibrium, left and right domain*)
ηlb[ξb_]:=εc(1/2)(1-hb)ξb(1-ξb)(1-((εs)/3)(1-(3/2)hb)(1-2ξb))+εc mb ξb(1-ξmb)(1-εs mb(1-ξmb)-(1/2)εs(1-hb)(2-3ξb))
ηrb[ξb_]:=εc(1/2)(1-hb)ξb(1-ξb)(1-((εs)/3)(1-(3/2)hb)(1-2ξb))+εc mb ξmb(1-ξb)(1-εs mb(1-ξmb)-(1/2)εs(1-hb)(2-3ξb))

(*check boundary conditions and continuity at ξmb*)
{ηlb[0]==0,ηrb[1]==0,ηlb[ξmb]-ηrb[ξmb]==0}

3.2 Lateral component of the eigenfunctions

Equations (58) and (59) in the manuscript describing the lateral component νb of the eigenfunctions

(*solution lateral eigenfunctions*)
νlb[ξb_]:=C1 Sin[((2 ωb)/(εs))(Sqrt[1-εs ξb])]+C2 Cos[((2 ωb)/(εs))(Sqrt[1-εs ξb])]+((χlb)/((ωb)^2))εc(1-hb)(1-3εs mb(1-ξmb)+(1-(3/2)hb)(-εs+((2((εs)^2))/((ωb)^2))+2 εs ξb));
νrb[ξb_]:=C3 Sin[((2 ωb)/(εs))(Sqrt[1-εs mb-εs ξb])]+C4 Cos[((2 ωb)/(εs))(Sqrt[1-εs mb-εs ξb])]+((χrb)/((ωb)^2))εc(1-hb)(1+3εs mb ξmb+(1-(3/2)hb)(-εs+((2((εs)^2))/((ωb)^2))+2εs ξb));

Equations (40)(b)-(43)(b) in the manuscript are used to calculate the unknown amplitudes C1, C2, C3 and C4.

(*determination of C1, C2, C3 and C4 via continuity and boundary conditions*)

(*continuity condition of ν at the lumped mass*)
eq1=(νlb[ξmb]==νrb[ξmb])//Simplify;

(*jump condition at the position of the lumped mass in vertical direction*)
eq2=((1-εs mb-εs ξmb)(D[νrb[ξb],ξb]/.ξb->ξmb)-(1-εs ξmb)(D[νlb[ξb],ξb]/.ξb->ξmb)+χrb(D[ηrb[ξb],ξb]/.ξb->ξmb)-χlb(D[ηlb[ξb],ξb]/.ξb->ξmb)+mb ((ωb)^2)νlb[ξmb]==0)//Simplify;

(*boundary condition at left support*)
eq3=(νlb[0]==0)//Simplify;

(*boundary condition at right support*)
eq4=(νrb[1]==0)//Simplify;

{C1sol,C2sol,C3sol,C4sol}=SolveValues[{eq1,eq2,eq3,eq4},{C1,C2,C3,C4}][[1]];

Evaluate the cells below to see the full expressions (large expressions).

C1sol

C2sol

C3sol

C4sol

3.3 Longitudinal component of the eigenfunctions

The next step is to calculate the expression for μb based on the cable equation (39):

dμlbξmb[ξb_]=((χlb)/α)(1+(3/2)((D[ηlb[ξb],ξb])^2))-D[ηlb[ξb],ξb]D[νlb[ξb],ξb];
dμrbξmb[ξb_]=((χrb)/α)(1+(3/2)((D[ηrb[ξb],ξb])^2))-D[ηrb[ξb],ξb]D[νrb[ξb],ξb];

The expressions for μb can be found by integration of the above expressions using the boundary conditions (40)(a) and (41)(a). Here the integration of the last terms in the expressions above are treated separately

IntLeft[ξb_]=(Integrate[FullSimplify[(D[ηlb[ξb],ξb]D[νlb[ξb],ξb]/.ξb->(1/(εs))(1-(((((εs ζb)/(2 ωb))))^2)))(-((εs ζb)/(2((ωb)^2)))),Assumptions->{0<ζb,0<εs<1,0<ωb}],ζb]/.ζb->((2 ωb)/(εs))(Sqrt[1-εs ξb]))//Simplify;

IntRight[ξb_]=(Integrate[FullSimplify[(D[ηrb[ξb],ξb]D[νrb[ξb],ξb]/.ξb->(1/(εs))(1-εs mb-(((((εs ζb)/(2ωb))))^2)))(-((εs ζb)/(2((ωb)^2)))),Assumptions->{0<ζb,0<εs<1,0<ωb,0<=mb}],ζb]/.ζb->((2 ωb)/(εs))(Sqrt[1-εs mb-εs ξb]))//Simplify;

Expand the cells below to see the full expressions.

IntLeft[ξb]

IntRight[ξb]

The longitudinal components μb of the eigenfunctions are then given by (equations (60) and (61) in the manuscript)

μlb[ξb_]=((χlb )/α)Integrate[1+(3/2)((D[ηlb[ξ],ξ])^2),{ξ,0,ξb}]-(IntLeft[ξb]-IntLeft[0]);
μrb[ξb_]=-(((χrb)/α) Integrate[1+(3/2)((D[ηrb[ξ],ξ])^2),{ξ,ξb,1}]-(IntRight[1]-IntRight[ξb]));

Expand the cells below to see the full expressions.

μlb[ξb]

μrb[ξb]

To simplify the calculations below we write an explicit expression for the value of μb at the position of the point mass

μlbξmb=((χlb)/α) Llb-(IntLeft[ξmb]-IntLeft[0])//Simplify;
μrbξmb=-(((χrb)/α) Lrb-(IntRight[1]-IntRight[ξmb]))//Simplify;

Evaluate the cells below to see the full expressions.

3.4 Natural frequencies

To solve the eigenvalue problem one now constructs the two remaining conditions based upon the so-far unused continuity and jump condition for μb.

Equation (65) in the manuscript

(*Note that ceq is equivalent to the continuity condition μlb[ξmb]=μrb[ξmb] when μ is expressed via the integrated cable equation*)
ceq=(((χlb Llb+χrb Lrb)/α)-(IntRight[1]+(IntLeft[ξmb]-IntRight[ξmb])-IntLeft[0]))/.C1->C1sol/.C2->C2sol/.C3->C3sol/.C4->C4sol;

Evaluate the cell below to see the full expression (VERY LARGE EXPRESSION).

ceq

Equation (66) in the manuscript

(*jump condition at the position of the lumped mass in chordwise direction*)
jeq=((1-εs mb-εs ξmb)dμrbξmb[ξmb]-(1-εs ξmb)dμlbξmb[ξmb]+χrb-χlb+mb ((ωb)^2) μlbξmb)/.C1->C1sol/.C2->C2sol/.C3->C3sol/.C4->C4sol;

Expand the cell below to see the full expression (VERY LARGE EXPRESSION).

jeq

To find the natural frequencies of the system one finds the coefficients of χlb and χrb in the above equations and writes them in a matrix (equation (67) in the manuscript).

C11=Coefficient[ceq,χlb];
C12=Coefficient[ceq,χrb];
C21=Coefficient[jeq,χlb];
C22=Coefficient[jeq,χrb];

coeffMat=(({{C11, C12}, {C21, C22}}));

Evaluate the cells below to see the full expressions (VERY LARGE EXPRESSIONS).

C11

C12

C21

C22

Finally the natural frequencies can be found as roots of the determinant of the coefficient matrix (equation (68) in the manuscript).

f[ωb_]=C11 C22-C12 C21;

Evaluate the cell below to see the full expression (EXTREMELY LARGE EXPRESSION).

f[ωb]

Addendum: Full form of mode shapes

The full form of the mode shapes (with amplitudes) is given by

νlbsol[ξb_]=νlb[ξb]/.C1->C1sol/.C2->C2sol;
νrbsol[ξb_]=νrb[ξb]/.C3->C3sol/.C4->C4sol;

μlbsol[ξb_]=((χlb )/α)Integrate[1+(3/2)((D[ηlb[ξ],ξ])^2),{ξ,0,ξb}]-(IntLeft[ξb]-IntLeft[0])/.C1->C1sol/.C2->C2sol;
μrbsol[ξb_]=((χrb)/α) Integrate[1+(3/2)((D[ηrb[ξ],ξ])^2),{ξ,ξmb,ξb}]+(IntRight[ξmb]-IntRight[ξb])+((χlb)/α) Llb-(IntLeft[ξmb]-IntLeft[0])/.C1->C1sol/.C2->C2sol/.C3->C3sol/.C4->C4sol;