Supplement materials
	Mplus Script for the Path Analyses

	
Title: Model 1 Path Analyses
data: file= move.dat;

variable:
names= ID klasse_ma note_mrc
moni kogn bez moni2 kogn2 bez2 
TDiff1 TDiff2 TDiff3 TDiff4 TDiff5
TInd1 TInd2 TInd3 TInd4
migrc migrcm noteMrcm;

IDVARIABLE = id;
cluster = klasse_ma;

usevariable =
note_mrc noteMrcm
kogn kogn2
bez bez2
moni moni2
migrc migrcm
Tind Tbezug;

within = bez kogn moni migrc note_mrc;
between =  noteMrcm migrcm Tind Tbezug;

missing= all(888);

DEFINE:  center bez kogn moni (groupmean);
center migrcm noteMrcm (grandmean);
Tind = Sum (TDiff1 TDiff2 TDiff3 TDiff4 TDiff5)/5;
Tbezug= sum (TInd1 TInd2 TInd3 TInd4)/4;

analysis: type= twolevel;

model: 
%within%
bez2  on bez migrc note_mrc;
kogn2 on kogn bez migrc note_mrc;
moni2 on moni migrc note_mrc;

moni2 with kogn2 bez2;
kogn2 with bez2;

kogn with bez moni mspraRC note_mrc;
bez with moni mspraRC note_mrc;
moni with mspraRC note_mrc;
mspraRC with note_mrc;

%between%
bez2   on noteMrcm  migrcm Tind  Tbezug ;
kogn2 on noteMrcm  migrcm Tind  Tbezug ;
moni2 on noteMrcm  migrcm Tind  Tbezug;

moni2 with kogn2 bez2;
bez2 with kogn2;

Tind with Tbezug noteMrcm migrcm;
Tbezug with noteMrcm migrcm;
noteMrcm with migrcm;

output: stdyx sampstat modindices tech1;


	Mplus script for the Interaction Analyses

	
Title: Model 2 Interaction
data: file= move.dat;

variable:

names=
ID klasse_ma 
kogn kogn2 kogm kog2m 
Tind Tbezug 
migrc migrcm Zmigrcm 
ZTind ZmigInd
ZTbezug Zkogm Zkogn2 Zkogn;

IDVARIABLE = id;
cluster = klasse_ma;

usevariable = 
migrc zTBezug  ZTind
zkogn zkogn2 zkogm
Zmigrcm notercM IndMig DiffMig;

within = zkogn migrc;

between = zkogm  zTBezug ZTind  
Zmigrcm notercM IndMig DiffMig;

missing= all(888);

DEFINE:
IndMig = zTBezug*Zmigrcm;
DiffMig = ZTind*Zmigrcm;

analysis: type= twolevel;

model:
%within%
zkogn2  on migrc zkogn;

%between%
zkogn2   on zkogm notercM;

[zkogn2] (b0);
zkogn2 on zTBezug(b1);!y on x
zkogn2 on ZTind;
zkogn2 on Zmigrcm (b2); ! y on w
zkogn2 on DiffMig;
zkogn2 on IndMig (b3);!y on xw

MODEL Constraint:
NEW(VLow LOW_W MED_W HIGH_W VHigh Vmodlow modlow modmed modhigh Vmhig);
VLow = -2.00;
  LOW_W = -1.00; !  low value of W
  MED_W = 0.00; ! = Mean value
  HIGH_W = 1.00; ! high value of W
  VHigh = 2.00;

Vmodlow = b1 + b3*Vlow;
modlow = b1 + b3*low_w;
modmed = b1 + b3*med_w;
modhigh = b1 + b3*high_w;
Vmhig = b1 + b3*VHigh;

PLOT (Vlowmod low_mod med_mod high_mod Vhighmod) ;
LOOP (xvalue, -2.5, 2.5, 0.5) ;
        Vlowmod = (b0 + b2*Vlow) + (b1 + b3*Vlow)*xvalue;
        low_mod = (b0 + b2*low_w) + (b1 + b3*low_w)*xvalue;
        med_mod = (b0 + b2*med_w) + (b1+b3*med_w)*xvalue ;
        high_mod = (b0 + b2*high_w) + (b1+b3*high_w)*xvalue ;
        Vhighmod = (b0 + b2*Vhigh) + (b1+b3*Vhigh)*xvalue ;

    PLOT:
    TYPE = plot2 ;

    OUTPUT:
    STAND CINTERVAL; 



