
Electronic Supplementary Material (to be posted on our website)
Netlogo Computer Code

globals [ seconds

          minutes

          hours

          days

          day-1-north-site-foragers

          day-1-south-site-foragers

          day-2-north-site-foragers

          day-2-south-site-foragers

          current-recruits

          wagglers-North

          wagglers-South

          tremblers

          shakers

          stop-signallers

          recons-north

          recons-south

          reactivations-north

          reactivations-south

          recruits-north

          recruits-south

          novice-recruits-north

          novice-recruits-south

          waiting-at-feeder

          feeding-at-feeder

          total-foragers

          total-receivers

          freq-1

          phase-1

          freq-2

          phase-2

          freq-3

          stopped

          followed 

          guards ]

breed [ foragers forager ]

breed [ receivers receiver ]

foragers-own [ inside-state

               outside-state

               in-nest

               out-nest

               clock

               dance-clock

               time-out-clock
               feeder-clock

               time-back-clock

               wait-clock         

               being-followed               

               initial              

               genetic-scout 

               find-by-scouting

               recon-north

               recon-south

               reactivated-north

               reactivated-south

               recruited-north

               recruited-south

               novice-recruited-north

               novice-recruited-south            

               lost

               lost-site

               fight

               win

               load

               tempo               

               first-success

               north-success

               south-success       

               feeding

               gain

               cost           

               current-patch

               source-quality               

               time-of-day-north-found

               x1-position-of-find 

               y1-position-of-find     

               distance-to-find-1         

               time-of-day-south-found

               x2-position-of-find         

               y2-position-of-find

               distance-to-find-2          

               direction
               wait-time 

               stop-signalling

               waggle-dancing

               tremble-dancing                     

               stop-test

               followed-test ]

receivers-own [ crop-full

                quit-clock

                clock ]

patches-own [ nectar-conc

              enemies

              on-dancefloor ]

to setup

clear-all

  set seconds 1

  set minutes 0

  set hours 0

  set days 1
  set shakers 0

  set tremblers 0

  set total-foragers 0

  set waiting-at-feeder 0

  set feeding-at-feeder 0

  set day-2-north-site-foragers 0

  set day-2-south-site-foragers 0

  set recons-north 0

  set recons-south 0

  set reactivations-north 0

  set reactivations-south 0

  set recruits-north 0

  set recruits-south 0

  set novice-recruits-north 0

  set novice-recruits-south 0
  set freq-1 2

  set freq-2 reactivation-freq

  set phase-1 0

  set phase-2 0

  set freq-3 guard-recruit-rate

  set guards 0

  setup-turtles

  setup-patches

end
;; Create model landscape
to setup-patches

 ask patches [  

     set pcolor white

     set enemies 0

     set on-dancefloor False

     if (pxcor >= 0.4 * max-pxcor and pxcor <= 0.6 * max-pxcor) and pycor > 0.4 * max-pycor and pycor <= 0.6 * max-pycor 

        [ set pcolor grey

          set on-dancefloor True ]         

     if (pxcor >= 0.475 * max-pxcor and pxcor <= 0.525 * max-pxcor) and pycor > 0.8 * max-pycor and pycor <= 0.85 * max-pycor 

        [ set pcolor red

          set nectar-conc 2.5 ]      

     if (pxcor >= 0.475 * max-pxcor and pxcor <= 0.525 * max-pxcor) and pycor > 0.15 * max-pycor and pycor <= .2 * max-pycor 

        [ set pcolor blue

          set nectar-conc 0.75 ]]

end

to setup-turtles

  create-foragers bees

  create-receivers middle-age-bees

    ask foragers [ set size 4

                   set color black

                   set shape "bug"

                   ;hide-turtle

                   setxy ( 85 + random-float 30 ) ( 85 + random-float 30 )

                   set inside-state 1

                   set outside-state 0

                   set in-nest True

                   set out-nest False

                   set initial False

                   set dance-clock 0

                   set being-followed False       

                   set find-by-scouting False           

                   set clock 0

                   set feeding False

                   set feeder-clock 0

                   set time-out-clock 0

                   set time-back-clock 0

                   set wait-clock 0               

                   set gain 0

                   set cost 0

                   set tempo 0       

                   set novice-recruited-north False

                   set novice-recruited-south False

                   set recruited-north False

                   set recruited-south False

                   set recon-north False

                   set recon-south False

                   set reactivated-north False

                   set reactivated-south False

                   set lost False

                   set lost-site 0

                   set fight False

                   set win 1                    
                   set load False

                   set source-quality 0                

                   set first-success 0

                   set north-success 0

                   set south-success 0
                   set direction 0                

                   set current-patch 0

                   set time-of-day-north-found 0

                   set time-of-day-south-found 0

                   set x1-position-of-find 0

                   set y1-position-of-find 0    

                   set distance-to-find-1 0

                   set x2-position-of-find 0

                   set y2-position-of-find 0    

                   set distance-to-find-2 0            

                   set waggle-dancing False           

                   set tremble-dancing False

                   set stop-signalling False

                   ifelse who > (initial-foragers-north + initial-foragers-south) and random-float 1 <= .03 

                     [ set genetic-scout True ]

                     [ set genetic-scout False ]  

            ]

    ask receivers [ set size 4

                    hide-turtle

                    set shape "bug"

                    set color blue

                    setxy ( 85 + random-float 30 ) ( 85 + random-float 30 )

                    set quit-clock 0

                    set clock 0

                    set crop-full false ] 

end

to go

  ;;  Send Foragers to North Site Feeder
 ask foragers [

  if who <= 2 and seconds = 5 [ set direction 1

                                set outside-state 3

                                leave-nest ]

  if who > 2 and who <= 5 and seconds = 60 [ set direction 1

                                set outside-state 3

                                leave-nest ]]

;;  Trigger Forager and Receiver Behavior
 ask foragers [ 

   ifelse in-nest = True 

     [ nest-behavior ]

     [ outside-behavior ]]

 ask receivers [ receiver-behavior ]

;; Various outputs from model
  set total-foragers count foragers

  set total-receivers count receivers

  set recons-north count foragers with [ recon-north = True ]

  set recons-south count foragers with [ recon-south = True ]

  set reactivations-north count foragers with [ reactivated-north = True ]

  set reactivations-south count foragers with [ reactivated-south = True ]

  set recruits-north count foragers with [ recruited-north = True ]

  set recruits-south count foragers with [ recruited-south = True ]

  set novice-recruits-north count foragers with [ novice-recruited-north = True ]

  set novice-recruits-south count foragers with [ novice-recruited-south = True ]

  if minutes mod freq-3 = phase-1 and guards < 50 [ set guards guards + 1 ]

  if days = 1 [ set day-1-north-site-foragers count foragers with [ current-patch = 1 ]]

  if days = 1 [ set day-1-south-site-foragers count foragers with [ current-patch = 2 ]]

  set Wagglers-North count foragers with [ inside-state = 4 and current-patch = 1 ] 

  set Wagglers-South count foragers with [ inside-state = 4 and current-patch = 2 ]  

  set Tremblers count foragers with [ inside-state = 5 ]

  set Stop-signallers count foragers with [ inside-state = 7 ]

  set Shakers count foragers with [ inside-state = 6 ]

  set current-recruits count foragers with [ outside-state = 4 ]

  set stopped count foragers with [ stop-test = True ]

  set followed count foragers with [ followed-test = True ]

  set waiting-at-feeder count foragers with [ outside-state = 7 ]

  set feeding-at-feeder count foragers with [ outside-state = 8 ]

;;Stop Condition
  if minutes > 30 and day-1-north-site-foragers = 0 [ stop ]

  set seconds seconds + 1

  set minutes seconds / 60

  set hours seconds / 3600

end

;;Behavioral States from Fig 1
to nest-behavior

  ifelse inside-state = 1

    [ bee-in ][

  ifelse inside-state = 2

    [ find-receiver ][

  ifelse inside-state = 3

    [ unload ][

  ifelse inside-state = 4

    [ waggle-dance ][

  ifelse inside-state = 5

    [ tremble-dance ][

  ifelse inside-state = 6

    [ Vibration-signal ][

  ifelse inside-state = 7

    [ Stop-Signal ][

  ifelse inside-state = 8

    [ delay-1 ]

    [ delay-2 ]

    ]]]]]]]

end

to outside-behavior

  ifelse outside-state = 1 

    [ scout ][

  ifelse outside-state = 2 

    [ fly-around ][       

  ifelse outside-state = 3 

    [ return-to-feeder ][

  ifelse outside-State = 4

    [ search-for-site ][

  ifelse outside-State = 5

    [ no-success ][

  ifelse outside-State = 6

    [ at-feeder ][

  ifelse outside-State = 7

    [ wait-at-feeder ][

  ifelse outside-State = 8

    [ feed ]

    [ fly-home ]]]]]]]]

end

;; Bee returns to nest, delays for 60 s, calculate costs and benefits of foraging trip

to bee-in

  ifelse clock = 60 * tempo

  [ ifelse load = True 

    [ set gain 290 * source-quality

      set cost (time-out-clock * 0.0433806 + feeder-clock * 0.0282063 + time-back-clock * .0642387)

      set time-out-clock 0

      set feeder-clock 0

      set time-back-clock 0

      set inside-state 2

      set clock 0 ][

  ifelse lost = True

    [ set lost False

      set gain 290 * source-quality

      set cost (time-out-clock * 0.0433806 + feeder-clock * 0.0282063 + time-back-clock * .0642387)

      set time-out-clock 0

      set feeder-clock 0

      set time-back-clock 0

      set clock 0

      set inside-state 7 ]

    [ set clock 0

      set inside-state 8 ]]]

  [ set clock clock + 1 ]

end

;; Look for nectar receiver that is one the same patch and has an empty crop
to find-receiver

  let unloader one-of receivers-here with [ crop-full = false ]  

    ifelse unloader != nobody                   

      [ ask unloader [ set crop-full True

                       set quit-clock 0 ]

        set inside-state 3

        set wait-time clock

        set clock 0 ]

      [ set clock clock + 1

        wiggle ]

end

;; Unload nectar (60s), determine which signal, if any, the bee will perform based on wait time to find receiver 

to unload

  ifelse clock >= random-normal 60 10           

    [ ifelse first-success <= 2 and random-float 1 < 0.10 

        [ set wait-time 0       ;; shaking signal

          set inside-state 6        

          set clock 0 ][

      ifelse wait-time <= 60 and source-quality > 1.1 and random-float 1 <= ((0.0435 * (gain - cost) / cost) - 0.74) * (1 - wait-time / 60)

        [ set wait-time 0      ;; waggle dance 

          set inside-state 4

          set clock 0 ][

      ifelse wait-time >= 20 and random-float 1 < (wait-time - 20) / 60

        [ set wait-time 0

          set inside-state 5      ;; tremble-dance

          set clock 0 ]

        [ set wait-time 0

          set inside-state 8       ;; no signal

          set clock 0 ]]]]      

    [ set clock clock + 1 ]

end

;;Perform Waggle Dance for length of time given by equation in text, only one recruit can get info about dance at a time, takes 6 s for recruit to get info from dance
to waggle-dance

  ifelse clock >= win * 60 * (0.0435 * (gain - cost) / cost) - 0.74      

    [ set dance-clock 0

      set being-followed False

      set clock 0

      set win 1

      set inside-state 8 ][

  ifelse being-followed = True and dance-clock <= 6    
    [ set clock clock + 1

      set dance-clock dance-clock + 1 ][

  ifelse being-followed = True and dance-clock > 6

    [ set dance-clock 0

      set being-followed False

      set clock clock + 1 ]

    [ set clock clock + 1 ]

    ]]

end

;;Tremble dance for 2 min, recruit number of nectar receivers set by user
to tremble-dance

  ifelse clock >= 120                         

    [ hatch-receivers per-capita-receiver-recruitment-rate [ 

                  set size 4

                    hide-turtle

                    set shape "bug"

                    set color blue

                    setxy ( 85 + random-float 30 ) ( 85 + random-float 30 )

                    set clock 0

                    set crop-full false ]

      set clock 0

      set inside-state 8 ]

    [ set clock clock + 1 ]

end

;;Perform vibration signal for 20 min, recruit number of new foragers set by user
to Vibration-signal

  ifelse clock >= 1200                            

    [ if count foragers < max-forager-population [ hatch-foragers per-capita-forager-recruitment-rate [ 

                   set size 4

                   set color black

                   set shape "bug"

                   ;hide-turtle

                   setxy ( 85 + random-float 30 ) ( 85 + random-float 30 )

                   set clock 0

                   set inside-state 1

                   set outside-state 0

                   set in-nest True

                   set out-nest False

                   set initial False

                   set dance-clock 0

                   set being-followed False

                   set find-by-scouting False

                   set feeding False

                   set feeder-clock 0

                   set time-out-clock 0

                   set time-back-clock 0

                   set gain 0

                   set cost 0

                   set tempo 0

                   set novice-recruited-north False

                   set novice-recruited-south False

                   set recruited-north False

                   set recruited-south False

                   set recon-north False

                   set recon-south False

                   set reactivated-north False

                   set reactivated-south False

                   set lost False

                   set lost-site 0

                   set fight False

                   set win 1                    

                   set load False

                   set source-quality 0

                   set first-success 0

                   set north-success 0

                   set south-success 0

                   set direction 0

                   set current-patch 0

                   set time-of-day-north-found 0

                   set time-of-day-south-found 0

                   set x1-position-of-find 0

                   set y1-position-of-find 0    

                   set distance-to-find-1 0

                   set x2-position-of-find 0

                   set y2-position-of-find 0    

                   set distance-to-find-2 0

                   set waggle-dancing False           

                   set tremble-dancing False

                   set stop-signalling False  ]]

      set clock 0

      set inside-state 8 ]

    [ set clock clock + 1 ]

end

;;Perform Stop Signal for 2 min, stop foragers on the same patch with probability set at start of run, afterwards either go back to same site or become unemployed
to stop-signal

  ifelse clock >= 120

    [ ifelse first-success > 0 and random-float 1 < .75 
      [ set clock 0

        set lost False

        set outside-state 3 

        leave-nest ]

      [ set clock 0

        set lost False

        set inside-state 8  ]]  

    [ let dancer one-of foragers-here with [ inside-state = 4 ]     

       ifelse dancer != nobody and [ current-patch ] of dancer = current-patch

        [ ask dancer [ if random-float 1 < stop-signal-strength 

                          [ set clock 0

                            set dance-clock 0

                            set being-followed False

                            set win 1

                            set inside-state 8 ] 

          set stop-test True ]

          set clock clock + 1

          wiggle ]

        [ wiggle

          set clock clock + 1 ]]

end

;;If genetic scout, then scout, if employed forager, then go back to site if it is above quality 0.75, if employed forager and site quality below 0.75, then go back to site if probability of abandonment is not met
to delay-1 

  ifelse clock >= 60

  [ ifelse genetic-scout = True          ;; genetic scout

      [ set clock 0

        set load False

        set outside-state 1 

        leave-nest ][

    ifelse load = True and source-quality = 0.75 and random-float 1 >= abandonment-rate     ;; continue with site       

      [ set load False

        set outside-state 3 

        leave-nest ][

    ifelse load = True and source-quality > 0.75                   

      [ set load False

        set outside-state 3

        leave-nest ]

      [ set load False

        set current-patch 0

        set direction 0

        set inside-state 9 ]]]]

   [ set clock clock + 1 ]

end

;;Implement decision making process shown on Figure 1 for unemployed foragers

to delay-2

  inside-nest-cycle

end

to inside-nest-cycle

  ifelse x1-position-of-find = 0 and x2-position-of-find = 0

    [ let dancer one-of foragers-here with [ inside-state = 4 ]    

      ifelse dancer != nobody and [ being-followed ] of dancer = False     ;; Novice Recruitment

        [ ask dancer [ set being-followed True ] 

          ifelse [ current-patch ] of dancer = 1 

            [ set direction 1 ]

            [ set direction 2 ]    

          leave-nest 

          find-or-not ][ 

      ifelse clock >= random-normal 10800 500        ;; Novice Scout

        [ set outside-state 1 

          leave-nest ]

        [ set clock clock + 1

          wiggle

          set inside-state 9 ]]]

    [ experienced-cycle ]

end

to experienced-cycle

  let dancer one-of foragers-here with [ inside-state = 4 ]   

  ifelse dancer != nobody 

    [ ifelse [ current-patch ] of dancer = 1 and x1-position-of-find != 0  and seconds mod freq-2 = phase-2 and random-float 1 < reactivation-rate ;; reactivation 1

        [ set direction 1 

          set reactivated-north True

          set outside-state 3

          leave-nest ][

      ifelse [ current-patch ] of dancer = 2 and x2-position-of-find != 0 and seconds mod freq-2 = phase-2 and random-float 1 < reactivation-rate ;; reactivation 2

        [ set direction 2

          set reactivated-south True

          set outside-state 3

          leave-nest ][

      ifelse clock >= time-to-switch and [ current-patch ] of dancer = 1 and [ being-followed ] of dancer = False and initial = False     ;; switch / recruited to site 1

        [ ask dancer [ set being-followed True ]

          set direction 1

          set first-success 0

          leave-nest

          find-or-not ][

      ifelse clock >= time-to-switch and [ current-patch ] of dancer = 2 and [ being-followed ] of dancer = False and initial = False    ;; switch / recruited to site 2

        [ ask dancer [ set being-followed True ]

          set direction 2

          set first-success 0

          leave-nest

          find-or-not ][

      ifelse time-of-day-north-found = seconds and random-float 1 < recon-prob        ;; recon 1

        [ set recon-north True

          set direction 1

          set outside-state 3

          leave-nest ][

      ifelse time-of-day-south-found = seconds and random-float 1 < recon-prob        ;; recon 2  

        [ set recon-south True

          set direction 2

          set outside-state 3

          leave-nest ][

      ifelse clock >= 10800        ;; Experienced Scout

          [ leave-nest

            set outside-state 1 ]

          [ set clock clock + 1

            wiggle

            set inside-state 9 ]]]]]]]]

     [ ifelse seconds = time-of-day-north-found and random-float 1 < recon-prob       ;;Recon site 1

        [ set recon-north True

          set direction 1

          set outside-state 3

          leave-nest ][

      ifelse seconds = time-of-day-south-found and random-float 1 < recon-prob        ;;Recon site 2

        [ set recon-south True

          set direction 2

          set outside-state 3

          leave-nest ][

      ifelse clock >= 10800 and initial = False        ;; Experienced Scout

          [ leave-nest

            set outside-state 1 ]

          [ wiggle

            set clock clock + 1

            set inside-state 9 ]]]]

end

to leave-nest    

      ifelse direction = 1

        [ setxy 100 121 ]

        [ setxy 100 80 ]

      set clock 0

      set in-nest False

      set out-nest True

      set inside-state 0

end

;;Either Find site or not
to scout  

  set direction 0

  let j random 3

  ifelse j = 0

    [ set direction 1

      set outside-state 2 ][

  ifelse j = 1

    [ set direction 2

      set outside-state 2 ]

    [ set outside-state 2 ]]      

end

;;If found site then go there, else fly around then go home
to fly-around

  setxy 165 100

  ifelse clock >= 250 and (direction = 1 or direction = 2)

    [ set clock 0

      set outside-state 3 ][

  ifelse clock >= 840

    [ set clock 0

      set outside-state 9 ]

    [ set clock clock + 1 ]]

end

;;Find site with probability set at start of run

to find-or-not

  ifelse direction = 1

  [ ifelse random-float 1 < prob-finding-site

     [ set outside-state 4

       if x1-position-of-find = 0 and x2-position-of-find = 0 [ set novice-recruited-north True ]

       if x1-position-of-find != 0 or x2-position-of-find != 0 [ set recruited-north True ]]

     [ setxy 35 100

       set direction 0

       set outside-state 5 ]]

  [ ifelse random-float 1 < prob-finding-site

     [ set outside-state 4

       if x1-position-of-find = 0 and x2-position-of-find = 0 [ set novice-recruited-south True ]

       if x1-position-of-find != 0 or x2-position-of-find != 0 [ set recruited-south True ]]

     [ setxy 35 100

       set direction 0

       set outside-state 5 ]]

end

to no-success

  ifelse clock >= searching-time-lost

    [ set clock 0

      set outside-state 9 ]

    [ set clock clock + 1 ]

end

;;Recruit on way to site for the first time
to search-for-site  

  if pcolor = red or pcolor = blue [ set outside-state 6 ]

    ifelse direction = 1 and time-out-clock = 0

     [ facexy 100 161 ]

     [ if time-out-clock = 0 [ setxy 100 80

                               facexy 100 40 ]]

    fd .4 

    set time-out-clock time-out-clock + 1 

end

;;Experienced forager returning to site
to return-to-feeder 

    ifelse direction = 1 and time-out-clock = 0

     [ facexy 100 161 ]

     [ if time-out-clock = 0 [ facexy 100 40 ]]

       if pcolor = red or pcolor = blue [ set outside-state 6 ]

     fd .4 

     set time-out-clock time-out-clock + 1 

end

;;Arrive at feeder, either fight or not depending on equation, if lose fight go home
to at-feeder

 ifelse guards <= 47 and random-float 1 < (1 / 50) * guards     

   [ set lost True                       

     set outside-state 9 ][  

 ifelse guards > 47 and random-float 1 < 0.95

   [ set lost True                       

     set outside-state 9 ] 

   [ set outside-state 7 ]]       ;; no fight / win fight

end

to wait-at-feeder                    ;; time to get to honey stores

  ifelse wait-clock >= 20

    [ set wait-clock 0

      set feeding True

      set outside-state 8 ]

    [ set wait-clock wait-clock + 1  

      set time-out-clock time-out-clock + 1 ]

end

;;Feed at site, store information about site, then go home
to feed

    ifelse feeder-clock > 100    ;; add feeder-rate

    [ set load True

      set feeding False

      ifelse pcolor = red

        [ set current-patch 1 

          set north-success north-success + 1

          if x1-position-of-find = 0 [ set time-of-day-north-found seconds ]

          set x1-position-of-find pxcor

          set y1-position-of-find pycor 

          set source-quality nectar-north

          ifelse nectar-north < 1

            [ set tempo 1 ]

            [ set tempo 2 ]]

        [ set current-patch 2 

          set south-success south-success + 1

          if x2-position-of-find = 0 [ set time-of-day-south-found seconds ]

          set x2-position-of-find pxcor

          set y2-position-of-find pycor 

          set source-quality nectar-south

          ifelse nectar-south < 1

            [ set tempo 1 ]

            [ set tempo 2 ]]

       set first-success first-success + 1

       set outside-state 9 ]

    [ set feeder-clock feeder-clock + 1 ]

end

to fly-home

  ifelse time-back-clock >= 100 

    [ setxy 98 120                

      set clock 0

      set in-nest True

      set out-nest False

      set inside-state 1

      set outside-state 0 ]

    [ set time-back-clock time-back-clock + 1 ]

end

;; Move around looking for foragers to unload, if none found after 20 min quit
to receiver-behavior

  ifelse quit-clock > 1200 and count receivers > 300

  [ die ]

  [ ifelse crop-full = True and clock < 1200

     [ set clock clock + 1 ][

    ifelse crop-full = True and clock >= 1200

     [ set crop-full False

       set clock 0 ]

     [ set quit-clock quit-clock + 1

       wiggle ]]]

end

to wiggle

   ifelse [ on-dancefloor ] of patch-ahead wiggle-distance = False 

        [ facexy 100 100 ]

        [ fd wiggle-distance

          lt random-float 90 - random-float 90 ]    

end


