$PROBLEM

$INPUT
ID TIME TAD AMT RATE DV CMT ADABIN EVID MDV ALB

$DATA IFLX_3000.csv IGNORE=C

$SUBROUTINES ADVAN13 TOL=6

$MODEL
COMP=(CENT,DEFDOSE)
COMP=(RETOT)
COMP=(PERI)		

$PK
CL = THETA(3) * (ALB/38)**THETA(8) * THETA(7)**ADABIN * EXP(ETA(1))
V1 = THETA(4) * EXP(ETA(2))
V3 = THETA(5) * EXP(ETA(3))
Q = THETA(6)

k10 = CL/V1
k13 = Q/V1
k31 = Q/V3

BMAX	= THETA(9) * EXP(ETA(4))
KSS    	= THETA(10)            
kdeg	= THETA(13)
kep	= THETA(14)

ksyn 	= BMAX*kdeg

A_0(1) 	= 0
A_0(2) 	= BMAX
A_0(3)	= 0           

PROP1	= THETA(2)
PROP2	= THETA(12)

S1 = V1
S2 = V3

$DES								
CT 		= A(1)/V1
C=0.5*((CT-A(2)-KSS)+SQRT(((CT-A(2)-KSS)**2)+(4*KSS*CT)))

DADT(1) = -(k10 + k13)*C*V1 + k31*A(3) - (kep*A(2)*C*V1/(KSS+C))
DADT(2) = ksyn - kdeg*A(2) - ((kep-kdeg)*A(2)*C/(KSS+C))
DADT(3) = k13*C*V1  - k31*A(3)				

$ERROR
A1 = A(1)
A2 = A(2)
A3 = A(3)

Ctot = A(1)/V1

RTOT = A(2)      
Cfree= 0.5*(Ctot-Rtot-KSS+SQRT((Ctot-Rtot-KSS)**2+4*KSS*Ctot))
RC   = Ctot - Cfree        
R    = Rtot - RC          

LNCP=LOG(0.000001)
IF (Cfree.GT.0) LNCP=LOG(Cfree)

LNTNF = LOG(0.000001)
IF (R.GT.0) LNTNF = LOG(R)

IF (CMT.EQ.1) THEN
W = SQRT(THETA(1)**2)
IPRED=LNCP
Y = IPRED+W*ERR(1)
IRES = DV-IPRED
IWRES = IRES/W
ELSE
IPRED = LNTNF
W = SQRT(THETA(11)**2)
Y = IPRED + W*ERR(2)
IRES = DV-IPRED
IWRES = IRES/W
ENDIF

$THETA
(0.21) 		;1 Add
(0) FIX 	;2 Prop
(0.407) 	;3 CL
(3.14) 		;4 V1
(1.65) 		;5 V2
(0.385) 	;6 Q
(2.15)		;7 ADA-CL
(-1.18) 	;8 ALB-CL
(0.00034) 	;9 BMAX (nM)
(23.8) 		;10 KSS
(0.415) 	;11 Add
(0) FIX 	;12 Prop
(5.12) FIX 	;13 kdeg  
(0.463) 	;14 kep

$OMEGA BLOCK(2)
 0.0812 
 0.014 0.0498 

$OMEGA
 0.402
 0.146

$SIGMA
 1 FIX 
 1 FIX 

$EST MAXEVAL=9999 NOABORT PRINT=5 METHOD=1 INTER POSTHOC ATOL=6 SIGL=6 NSIG=2
$COV COMP