Encoding: UTF-8.
DATASET ACTIVATE Leeds10YrCrime7.
COMPUTE MeanDateTimeOccurred =MEAN(EarliestDateCommitted,LatestDateCommitted).
COMPUTE TimeDiff = LatestDateCommitted - EarliestDateCommitted.
FORMATS MeanDateTimeOccurred (TIME16) .
* Will have to change FORMAT to yy-mm-dd hh:mm:ss in the Data Editor .
VARIABLE LABELS TimeDiff 'Time Diff in Hrs:Mins'.

COMPUTE  N_DaysLateMinEarlyTrunc=DATEDIF(LatestDateCommitted, EarliestDateCommitted, "days").
VARIABLE LABELS  N_DaysLateMinEarlyTrunc.
VARIABLE LEVEL  N_DaysLateMinEarlyTrunc (SCALE).
FORMATS  N_DaysLateMinEarlyTrunc (F5.0).
VARIABLE WIDTH  N_DaysLateMinEarlyTrunc(5).
COMPUTE WkN0 = TRUNC(DATEDIFF(MeanDateTimeOccurred,DATE.DMY(03,01,2005),"days")/7).
FORMATS WkN0  (F5.0).

*Code to avoid calculating the binary variable 'Dark' if 'Latest' minus Earliest is >= 24 hours .
COMMENT to assign Sunrise and Sunset (hence the end of darkness and end of dauylight) on the day of the earliest possible cime date
  and (the sunrise and end darkness)on the following day.
* COMMENT determines whether the Time given is consistent with LightConditions
  Using Sunrise/Sunset Algorithm
  Source:
  Almanac for Computers, 1990
 	published by Nautical Almanac Office
 	United States Naval Observatory
 	Washington, DC 20392.
* Syntax 'SunRiseSet_Darkness_2.sps' copied from BirminghamCollab to operate intially on SampleOf32CrimesFrom10Yr4A.sav with variables:
* ID NewOffence NewOffence2 DateOffenceRecorded DateOffenceReported EarliestDateCommitted LatestDateCommitted HOClass Date1stCrimed msoa11cd
* DateOffenceRecorded1 DateReported1 EarliestDayCommitted1 LatestDayCommitted1 Date1stCrimed1 RecordedInRange ReportedInRange EarliestInRange
* LatestInRange Date1stCrimedInRange LeedsMSOA01 LeedsMSOANum EarliestTimeCommitted1 EarliestDayTimeCommitted1 EarliestTimeCommitted1A 
* LatestCommittedAfterEarliest filter_$ .

* The variables created in the sunrise/sunset (Darkness/Daylight) syntax program to see if the Darkness/Daylight lighting code given is consistent with the time claimed for the accident.
* TimeDecHrs 		The time claimed for the Road Traffic Accident (RTA) in decimal hours.
* BST 			Whether (1) or not (0) the date given was in British Summer Time.
* localThrs_Rise 	The hours part of the sunrise time for the date given in using local / clock time.
* localTmins_Rise	The minutes part of the sunrise time for the date given in using local / clock time.
* localThrs_Set	The hours part of the sunset time for the date given in using local / clock time.
* localTmins_Set	The minutes part of the sunrise time for the date given in using local / clock time.
* localT_DarkEnd		The sunrise time minus Â½ hour in decimal hours.
* localT_DarkStar		The sunset time plus Â½ hour in decimal hours.
* DiurnalPart		The part of the 24hrs for that date the claimed RTA-time resides -1, 0, +1	(-1 Before Daylight, 0 During Daylight, +1 After Daylight). 
* TimeRelDarkness	 The time, in decimal hours, relative to the nearest change between Darkness & Daylight; minus before & plus after .
* ClaimedDark01	 Whether the claimed lighting code was for Darkness 1 (lighting codes 4 to 7) or Daylight 0 (lighting code = 1).
* LightTimeConsistent	 Whether the lighting code claimed is consistent with the part of the 24hrs derived from the claimed time of the RTA  .
SET PRINTBACK NONE.

COMMENT Generate Pi then Degree to Radian Conversion.
COMPUTE #PI = 4* ARTAN(1.0) .
COMPUTE #DegToRad = #PI /180 .
Comment Input Latitude & Longitude for Leeds as Scratch variables.
COMPUTE #Latitude = 53.8008 .
COMPUTE  #Longitude = -1.5491 .
COMMENT Put Latitude & Longitude in Radians .
COMPUTE #LatitudeRad =  #Latitude * #DegToRad .
COMPUTE #LongitudeRad =  #Longitude * #DegToRad.
COMPUTE #HoursDiff = DATEDIFF(LatestDateCommitted, EarliestDateCommitted, "hours").
DO IF (#HoursDiff   LT 24).
LOOP #J =1 TO 2.
* Put #DateTime as the limit of the possible Date and Time that the event could have occurred.
IF( #J = 1)  #DateTime = EarliestDateCommitted .
IF( #J = 2)  #DateTime = LatestDateCommitted.
COMMENT Compute the year.
COMPUTE #Year = XDATE.YEAR(#DateTime).
COMMENT Compute the Day Number in the year.
COMPUTE #YearStart = DATE.DMY(01,01,#Year).
COMPUTE #DayInYear = DATEDIFF(#DateTime,#YearStart,"days")+1.
FORMATS #DayInYear (F4.0).
COMMENT Convert the time of the Event to Decimal Hours (local / clock time so includes #BST for example).
COMPUTE #TimeOfDay = XDATE.TIME( #DateTime).
COMPUTE #TimeDecHrs = #TimeOfDay/3600.
COMMENT Convert Longitude to hour value and calculate the Approximate time.
COMPUTE #LongHour = #Longitude/15.
COMPUTE #tRise = #DayInYear+((6 - #LongHour)/24).
COMPUTE #tSet  = #DayInYear+((18 - #LongHour)/24).
COMMENT  Calculate the Sun's mean anomaly.
COMPUTE #MRise =0.9856*#tRise -3.289 .
COMPUTE #MSet  =0.9856* #tSet -3.289  .
COMMENT Calculate the Sun's True Longitude.
COMPUTE #MRiseRads =  #DegToRad*#MRise.
COMPUTE #MSetRads  = #DegToRad*#MSet .
COMPUTE #SunLongRise = #MRise+(1.916*SIN(#MRiseRads)+0.020*SIN(2*#MRiseRads))+282.634.
IF ( #SunLongRise GE 360)  #SunLongRise=  #SunLongRise-360.
IF ( #SunLongRise LT 0)  #SunLongRise=  #SunLongRise+360.
COMPUTE #SunLongSet = #MSet+(1.916*SIN(#MSetRads)+0.020*SIN(2*#MSetRads))+282.634.
IF ( #SunLongSet GE 360)  #SunLongSet =  #SunLongSet-360.
IF ( #SunLongSet LT 0)  #SunLongSet=  #SunLongSet+360.
COMMENT 5a Calculate the Sun's Right Ascension .
COMPUTE #RA_RiseRads = ARTAN(0.91764*SIN(#SunLongRise*#DegToRad)/COS(#SunLongRise*#DegToRad)).
COMPUTE #RA_SetRads  = ARTAN(0.91764*SIN(#SunLongSet*#DegToRad)/COS(#SunLongSet*#DegToRad)).
COMPUTE #RA_RiseDeg =#RA_RiseRads/#DegToRad.
COMPUTE #RA_SetDeg  = #RA_SetRads/#DegToRad.
IF ( #RA_RiseDeg GE 360)  #RA_RiseDeg= #RA_RiseDeg-360.
IF ( #RA_RiseDeg LT 0)  #RA_RiseDeg=  #RA_RiseDeg+360.
IF ( #RA_SetDeg  GE 360)  #RA_SetDeg =#RA_SetDeg -360.
IF ( #RA_SetDeg  LT 0)  #RA_SetDeg =#RA_SetDeg  +360.
COMMENT 5b  the Sun's Right Ascension needs to be in the same quadrant as the longitude.
IF ( #SunLongRise GE 0)  #LongRiseQuad= Trunc(#SunLongRise/90) *90.
IF ( #SunLongRise LT 0)  #LongRiseQuad= (Trunc(#SunLongRise/90)-1) *90.
IF ( #RA_RiseDeg GE 0)  #RA_RiseQuad= Trunc(#RA_RiseDeg/90) *90.
IF ( #RA_RiseDeg LT 0)  #RA_RiseQuad= (Trunc(#RA_RiseDeg/90)-1) *90.
COMPUTE #RA_RiseDeg= #RA_RiseDeg+(#LongRiseQuad-#RA_RiseQuad).
IF ( #SunLongSet GE 0) #LongSetQuad= Trunc(#SunLongSet/90) *90.
IF ( #SunLongSet LT 0) #LongSetQuad= (Trunc(#SunLongSet/90)-1) *90.
IF ( #RA_SetDeg GE 0)  #RA_SetQuad= Trunc(#RA_SetDeg/90) *90.
IF ( #RA_SetDeg LT 0)  #RA_SetQuad= (Trunc(#RA_SetDeg/90)-1) *90.
COMPUTE #RA_SetDeg= #RA_SetDeg+(#LongSetQuad-#RA_SetQuad).
COMMENT 5c Convert RA to Hours.
COMPUTE #RA_RiseHrs = #RA_RiseDeg/15.
COMPUTE #RA_SetHrs = #RA_SetDeg/15.
COMMENT 6  Calculate the Sun's Declination.
COMPUTE #SinDecRise = 0.39782*SIN(#SunLongRise* #DegToRad ).
COMPUTE #CosDecRise = COS(ARSIN( #SinDecRise)).
COMPUTE #SinDecSet = 0.39782*SIN(#SunLongSet* #DegToRad ).
COMPUTE #CosDecSet = COS(ARSIN( #SinDecSet)).
COMMENT 7a Calculate the Sun's local Hour Angle which is the angle between the celestial meridian & the object's Hour Circle, measured westward from the meridian. 
COMMENT HourCircle is a circle on celestial sphere that passes through both poles .
COMPUTE #CosH_Rise= (COS(90.83333333*#DegToRad) - (#SinDecRise*SIN( #LatitudeRad)))/(#CosDecRise*COS(#LatitudeRad)).
COMPUTE #CosH_Set= (COS(90.83333333*#DegToRad) - (#SinDecSet*SIN( #LatitudeRad)))/(#CosDecSet*COS(#LatitudeRad)).
COMMENT 7b Finish calculating H & convert to hours.
COMPUTE #H_Rise=(360-(#PI/2 -ARSIN(#CosH_Rise))/#DegToRad)/15.
COMPUTE #H_Set=(#PI/2-ARSIN(#CosH_Set))/#DegToRad/15.
COMMENT 8 Calculate local mean time of rising/ setting.
COMPUTE #T_Rise= #H_Rise + #RA_RiseHrs -(0.06571*#tRise)-6.622.
COMPUTE #T_Set= #H_Set + #RA_SetHrs -(0.06571*#tSet)-6.622.
COMMENT Adjust bact to UT.
COMPUTE #UT_Rise =#T_Rise - #LongHour.
IF (#UT_Rise GE 24) #UT_Rise =#UT_Rise -24.
IF (#UT_Rise LT  0 ) #UT_Rise =#UT_Rise +24.
COMPUTE #UT_Set =#T_Set - #LongHour.
IF (#UT_Set GE 24) #UT_Set =#UT_Set -24.
IF (#UT_Set LT  0 ) #UT_Set =#UT_Set +24.
* denote whether in the #BST Dates. 
COMPUTE #BST=$SYSMIS.
DO IF ( 
   (#DateTime    >= DATE.DMY(27,03,2005)  & #DateTime < DATE.DMY(30,10,2005)) 
 | (#DateTime    >= DATE.DMY(26,03,2006)  & #DateTime < DATE.DMY(29,10,2006)) 
 | (#DateTime   >= DATE.DMY(25,03,2007)   & #DateTime < DATE.DMY(26,10,2007)) 
 | (#DateTime    >= DATE.DMY(30,03,2008)  & #DateTime < DATE.DMY(26,10,2008)) 
 | (#DateTime    >= DATE.DMY(29,03,2009)  & #DateTime < DATE.DMY(25,10,2009)) 
 | (#DateTime    >= DATE.DMY(28,03,2010)  & #DateTime < DATE.DMY(31,10,2010)) 
 | (#DateTime    >= DATE.DMY(27,03,2011)  & #DateTime < DATE.DMY(30,10,2011)) 
 | (#DateTime    >= DATE.DMY(25,03,2012)  & #DateTime < DATE.DMY(28,10,2012)) 
 | (#DateTime    >= DATE.DMY(31,03,2013)  & #DateTime < DATE.DMY(27,10,2013))
 | (#DateTime    >= DATE.DMY(30,03,2014)  & #DateTime < DATE.DMY(26,10,2014))
 | (#DateTime    >= DATE.DMY(29,03,2015)  & #DateTime < DATE.DMY(25,10,2015))
 ).
*There is potential for erroneous attribution for the early hours (before 2am) on the day of change.
COMPUTE #BST=1.
* If in #BST dates the #BST code is set but if the date were missing the missing value would be retained.
ELSE IF MISSING(#DateTime) NE 1 .
COMPUTE #BST=0.
END IF.
COMMENT 10. convert UT value to local time & convert to Hours & Minutes .
COMPUTE	#localT_Rise = #UT_Rise + #BST.
*COMPUTE	#localThrs_Rise = TRUNC(#localT_Rise).
*COMPUTE	#localTmins_Rise = 	(#localT_Rise - #localThrs_Rise)*60.
COMPUTE #localT_RiseHHMM = TIME.HMS(#localT_Rise).
COMPUTE	#localT_Set = #UT_Set + #BST.
*COMPUTE	#localThrs_Set = TRUNC(#localT_Set).
*COMPUTE	#localTmins_Set = 	(#localT_Set - #localThrs_Set)*60.
COMPUTE #localT_SetHHMM = TIME.HMS(#localT_Set).
* Calulate the end of Darkness & the start of Darkness.
COMPUTE #localT_DarkEndHHMM = TIME.HMS(#localT_Rise-0.5).
COMPUTE #localT_DarkStartHHMM = TIME.HMS(#localT_Set+0.5).
* Calulate if the Time given for the RTA is; before the end of Darkness (-1),in daylight (0),or after the start of Darkness(+1) & coded in DiurnalPart.
IF (#TimeDecHrs LT #localT_DarkEndHHMM/3600 ) #DiurnalPart=-1.
IF (#TimeDecHrs GE #localT_DarkEndHHMM/3600 AND #TimeDecHrs LE #localT_DarkStartHHMM/3600) #DiurnalPart=0.
IF (#TimeDecHrs GT #localT_DarkStartHHMM/3600 ) #DiurnalPart =+1.
* So -1 is predawn, 0 daylight &1 post sunset.
* Calulate the time given of RTA occurrence before Dark End so in predawn morning early in the 24hrs;  Gives -ve.
IF (#DiurnalPart=-1) #TimeRelDarkness = #TimeDecHrs - #localT_DarkEndHHMM/3600 .
* Calulate the time given of occurrence after Dark End, if this is LT time interval (DarkEnd - time) , so first part of Daylight; Gives +ve.
IF  (#DiurnalPart=0 & (#TimeDecHrs - #localT_DarkEndHHMM/3600) LT (#localT_DarkStartHHMM/3600- #TimeDecHrs) ) #TimeRelDarkness = #TimeDecHrs - #localT_DarkEndHHMM/3600.
* Calulate the given time of occurrence before Dark Start, if this is LT time interval (time- DarkEnd), so later in the Daylight period; Gives -ve.
IF  (#DiurnalPart=0 & (#TimeDecHrs - #localT_DarkEndHHMM/3600) GE (#localT_DarkStartHHMM/3600 - #TimeDecHrs) ) #TimeRelDarkness = #TimeDecHrs - #localT_DarkStartHHMM/3600.
* Calulate the given time of RTA occurrence after Dark Start, so gives late in the 24hrs ; Gives +ve.
IF (#DiurnalPart=1) #TimeRelDarkness = #TimeDecHrs- #localT_DarkStartHHMM/3600 .
*FORMATS localTDarkEndHHMM1 localT_DarkStartHHMM1 DarkEndHHMM2 localT_DarkStartHHMM2 (TIME5).
IF #J= 1 BST1 = #BST .
IF #J= 1 localT_RiseHHMM1  = #localT_RiseHHMM .
IF #J= 1 localT_SetHHMM1 = #localT_SetHHMM .
IF #J= 1 localT_DarkEndHHMM1 = #localT_DarkEndHHMM .
IF #J= 1 localT_DarkStartHHMM1 = #localT_DarkStartHHMM .
IF #J= 1 DiurnalPart1 = #DiurnalPart .
IF #J= 2 BST2 = #BST .
IF #J= 2 localT_RiseHHMM2  = #localT_RiseHHMM .
IF #J= 2 localT_SetHHMM2 = #localT_SetHHMM .
IF #J= 2 localT_DarkEndHHMM2 = #localT_DarkEndHHMM .
IF #J= 2 localT_DarkStartHHMM2 = #localT_DarkStartHHMM .
IF #J= 2 DiurnalPart2 = #DiurnalPart .
END LOOP.
FORMATS BST1 (F3.0) DiurnalPart1 (F3.0) localT_RiseHHMM1  localT_SetHHMM1 localT_DarkEndHHMM1 localT_DarkStartHHMM1 (TIME5).
FORMATS BST2 (F3.0) DiurnalPart2 (F3.0) localT_RiseHHMM2  localT_SetHHMM2 localT_DarkEndHHMM2 localT_DarkStartHHMM2 (TIME5).
VALUE LABELS DiurnalPart1 DiurnalPart2 -1 'Time Before Darknesss Ends' 0 'Time During Daylight' 1 'Time After Darknesss Starts'.
IF (XDATE.TDAY(LatestDateCommitted)  =  XDATE.TDAY(EarliestDateCommitted) & (DiurnalPart1 = DiurnalPart2)) DiurnalPart = DiurnalPart2 .
IF ((XDATE.TDAY(LatestDateCommitted)  =  XDATE.TDAY(EarliestDateCommitted) +1) & (DiurnalPart1 = +1 & DiurnalPart2 =-1)) DiurnalPart = 2 .
IF (DiurnalPart = -1) Dark =1. 
IF (DiurnalPart =  0) Dark =0. 
IF (DiurnalPart =  1) Dark =1. 
IF (DiurnalPart =  2) Dark =1. 
FORMATS DiurnalPart Dark (F3.0).
VARIABLE WIDTH BST1 DiurnalPart1 localT_RiseHHMM1  localT_SetHHMM1 localT_DarkEndHHMM1 localT_DarkStartHHMM1 (6)
 / BST2  DiurnalPart2 localT_RiseHHMM2  localT_SetHHMM2 localT_DarkEndHHMM2 localT_DarkStartHHMM2 DiurnalPart Dark (6).

END IF.
EXECUTE.
