
**************************************************************************
*** Appendix S8: Stata code of the tools                               ****
**************************************************************************


**************************************************************************
*** agest - a collection of tools for age estimation based on         ****
***         skeletal remains                                          ****
**************************************************************************

clear all 



****************************************************************************
*** some auxiliary routines 
*** 

program define errmsg 
  di as error "`2'"
  error `1'
end 

program define  _numlisttodata 
 syntax, numlist(numlist) gen(name)
  clear 
  local length : list sizeof numlist
  qui set obs `length'
  qui gen `gen' = . 
  forvalues i=1/`length' { 
  	gettoken value numlist:numlist
	qui replace `gen'=`value' if _n==`i' 
  }
end 
  	
program extractfromto 
  syntax , from(integer) to(integer) * 
  c_local from `from' 
  c_local to `to'
end 

****************************************************************************
*** oregress prob 
*** computing f(y|a) for ordinal regression models 
*** both beta and sigma paramterizations are supported 
 
program define oregressprob 
  syntax varlist, distf(string) from(integer) to(integer) ///   
        kappa(numlist) [trans(string) sigma(string) beta(string)] gen(name)
  gettoken vary vara: varlist 
  if "`sigma'"=="" & "`beta'"=="" errmsg 99901 "sigma or beta must be specified"
  if "`sigma'"!="" { 
  	local type sigma 
	confirm number `sigma' 
  } 
  else { 
  	local type beta
	confirm number  `beta' 
  } 
  qui gen double `gen'=. 
  local kap0 -1000
  local count 1
  foreach kap of local kappa { 
  	local kap`count++' `kap' 
  } 
  local kap`count' 1000 
  local count 0
  tempvar transa 
  if "`trans'"!="" { 
  	local expr = subinstr("`trans'","#","`vara'",.) 
	gen `transa' = `expr'
  } 
  else { 
  	gen `transa'=`vara'
  } 
  if inlist("`distf'","normal","logistic") local distf `distf'(#)
  if "`type'"=="sigma" { 
  	local arg1 ((\`kap\`++count''-\`transa')/\`sigma')
	local arg2 ((\`kap\`=\`count'-1''-\`transa')/\`sigma') 
  }
  else if "`type'"=="beta" { 
  	local arg1 (\`kap\`++count''-\`beta'*\`transa') 
	local arg2 (\`kap\`=\`count'-1''-\`beta'*\`transa')
  }
  forvalues y=`from'/`to' { 
  	local val1 `arg1' 
	local val2 `arg2' 
	local expr = subinstr("`distf'","#","`val1'",.) + "-" + /// 
	             subinstr("`distf'","#","`val2'",.)
	qui replace `gen'   =  `expr' if `vary'==`y'  
  }  
end 

***************************************************************************
*** normalstratprob
*** computing f(y|a) if the distribution of y is derived from the distribution 
*** of a|y and pi=P(y) assuming a normal distrubution of a|y  

program define normalstratprob 
  syntax varlist, from(integer) to(integer) /// 
     mu(numlist) sigma(numlist) pi(numlist) gen(name)
  gettoken vary vara: varlist 
  *di "nnn"
  *set trace on 
  qui gen `gen'=.  
  local count `from'
  foreach m of local mu { 
  	local mu`count++' `m' 
  } 
  local count `from'
  foreach s of local sigma { 
  	local sigma`count++' `s' 
  } 
  local count `from'
  foreach val of local pi { 
  	local pi`count++' `val' 
  } 
  tempvar aux 
  gen double sum=0.0 
  forvalues y=`from'/`to' {  
  	gen `aux'=normalden(`vara',`mu`y'',`sigma`y'')*`pi`y''  
	qui replace sum=sum+`aux' 
	qui replace `gen'=`aux' if `y'==`vary'
	drop `aux' 
  } 
  qui replace `gen'=`gen'/sum 
  drop sum 
end 

**************************************************************************
*** regressdens 
*** computing f(y|a) if given by a regression model 
***

program define regressdens 
  syntax varlist, alpha(real) beta(real) sigmaeps(real) gen(name)
  gettoken vary vara: varlist 
  gen double `gen' = normalden(`vary',`alpha'+`beta'*`vara',`sigmaeps')
end   

**************************************************************************
*** showdescriptord 
*** visualization of f(y|a) for a discrete y 
*** 

program define showdescriptord 
  syntax, model(string) params(string) gridage(numlist) ///
     [ytitle(string) oversubopts(string)] * 
  if "`oversubopts'"=="" local oversubopts label(angle(90) alternate labsize(*0.8)) 
  if "`ytitle'"=="" local ytitle fraction 
  preserve 
  extractfromto, `params'
  clear 
  qui set obs `=`to'-`from'+1' 
  gen y=`from'+_n-1  
  local grlength : list sizeof gridage 
  qui expand `grlength'
  qui gen age = . 
  forvalues i=1/`grlength'  { 
  	gettoken  age gridage:gridage 
	qui: bys y: replace age=`age' if _n==`i'
  }
  gettoken model spec: model 
  `model' y age, `spec'  `params' gen(dens)
  *tabstat dens, s(n sum) by(age) 
  *list 
  qui { 
  bys age (y): gen cum=dens if _n==1 
  bys age (y): replace cum=cum[_n-1] + dens  if _n>1 
  bys age (y): gen low=0 if _n==1 
  bys age (y): replace low=cum[_n-1]   if _n>1 
  }
  local cmd 
  qui levelsof y, local(ys) 
  foreach y of local ys {
  	local cmd `cmd' (rarea cum low age if y==`y') 
  }
  twoway `cmd'  , legend(off) ytitle(`ytitle') `options' 
  *graph bar dens, over(y) asyvars /// 
     over(age, `oversubopts' ) /// 
     stack legend(off) ytitle(`ytitle') `options' 
  restore
end 

***************************************************************************
*** showdescriptcont 
*** visualization of a model of f(y|a) for a continous distrubution 
*** 

program define showdescriptcont 
  syntax, model(string) params(string) gridchar(numlist) gridage(numlist) * 
  preserve 
  clear 
  local nscore : list sizeof gridchar
  qui set obs `nscore' 
  qui gen score=. 
  forvalues i=1/`nscore' { 
  	gettoken value gridchar: gridchar
    qui replace score=`value' if _n==`i'
  } 
  local nage : list sizeof gridage
  qui expand `nage'
  qui gen age = . 
  forvalues i=1/`nage'  { 
  	gettoken  age gridage:gridage 
	qui: bys score: replace age=`age' if _n==`i'
  }
  gettoken model spec: model 
  `model' score age, `spec'  `params' gen(dens)
  twoway line score dens ,  by(age, row(1) note("")) xtitle("") xlab(none) `options' 
  restore
end 


/*
*** test code 
showdescriptord, model(oregressprob distf(normal(#))) gridage(20(1)80) /// 
   params(from(1) to(6) kappa(30 40 50 60 70 ) sigma(7.0) ) name(g1,replace) 

showdescriptord, model(oregressprob distf(logistic)) gridage(20(1)80) /// 
   params(from(1) to(6) kappa(30 40 50 60 70 ) sigma(7.0) ) oversubopts( label(labsize(*0.4)))
  
showdescriptord, model(oregressprob distf(normal) trans(log(#)) ) /// 
   gridage(20(1)80) params(from(1) to(6) kappa(3.03 3.30 3.41 3.81 4.27) sigma(0.3174) ) 
   
showdescriptord, model(oregressprob distf(normal) trans(log(#)) ) /// 
   gridage(20(1)80)  ///   
   params(from(4) to(14) beta(2.638)  /// 
     kappa(7.62 7.88 8.57 9.16 9.82 10.28 10.73 11.37 11.95 12.51) )

showdescriptord, model(oregressprob distf(logistic) trans(sqrt(#)) ) /// 
   gridage(20(1)80)  params(from(3) to(8) kappa(4 5 6 7 9) beta(1.0) )    

showdescriptord , model(normalstratprob) gridage(10(1)80) /// 
  params( from(2) to(6) mu(20 30 40 50 60) sigma(10 10 10 10 10) /// 
  pi(0.3 0.25 0.2 0.15 0.1) )  

showdescriptcont, model(regressdens) params(alpha(5) beta(1) sigmaeps(5.6)) /// 
   gridage(10(5)70) gridchar(0(1)100)   
yyy 
*/ 

************************************************************************
*** showdescriptandvarord
*** 

program define showdescriptandvarord 
  syntax varname , gridage(numlist) [combopts(string) left(string) fxsize(real 15)] * 
  if "`ytitle'"=="" local ytitle fraction 
  local var `varlist'
  local varname : var label  `var'
  if "`varname'"=="" local varname `var'
  qui count if !mi(`var')
  local varN = r(N)   
  local model : char `var'[model] 
  local params : char `var'[params]
  showdescriptord , model(`model') params(`params') gridage(`gridage') /// 
      nodraw name(g1,replace) `left'
  tempfile data 
  qui save `data'
  extractfromto, `params'
  clear 
  qui set obs `=`to'-`from'+1' 
  gen y=`from'+_n-1  
  qui levelsof y , local(ys)
  qui gen prob=. 
  foreach y of local ys { 
  	preserve
	use `data', clear 
  	qui count if `var'==`y' 
	local N=r(N)
	restore 
	qui replace prob=r(N) if y==`y'
  }
  egen sum=total(prob) 
  qui replace prob=prob/sum 
  gen const="`varname' (N=`varN')"
  graph bar prob, over(y) over(const) asyvars stack nodraw name(g2,replace) /// 
     legend(off) ytitle(`ytitle') fxsize(`fxsize') `options' 
  graph combine g1 g2, row(1) imargin(tiny) `combopts'
  use `data', clear 
end 

************************************************************************
*** showdescriptandvarcont 
*** 

program define showdescriptandvarcont
  syntax varname , gridage(numlist) gridchar(numlist) /// 
      [combopts(string) left(string) fxsize(real 15)] * 
  if "`ytitle'"=="" local ytitle fraction 
  local var `varlist'
  local varname : var label  `var'
  if "`varname'"=="" local varname `var'
  qui count if !mi(`var')
  local varN = r(N)   
  local model : char `var'[model] 
  local params : char `var'[params]
  showdescriptcont , model(`model') params(`params') gridage(`gridage') /// 
      gridchar(`gridchar') /// 
      nodraw name(g1,replace) `left'
  twoway histo `var', hor 	fxsize(`fxsize')  nodraw name(g2,replace) `options' 
  graph combine g1 g2, row(1) imargin(tiny) `combopts'
end 

/* 
*** test code 
input yord freq
1 2
2 6 
3 5
4 4
5 3
6 3
7 3
end 
expand freq    
gen ycont=rnormal(12,3)
char yord[model] oregressprob distf(logistic)
char yord[params] from(1) to(6) kappa(30 40 50 60 70 ) sigma(7.0)
char ycont[model] regressdens  
char ycont[params] alpha(8) beta(0.1) sigmaeps(3) 
showdescriptandvarord yord, gridage(20(1)80) /// 
 fxsize(25) left(ytitle(Anteil) oversubopts(label(labsize(*0.4)))) ylab(0(0.5)1) ytitle(Anteil)
showdescriptandvarcont ycont, gridage(20(10)80) gridchar(0(1)20)  /// 
 fxsize(25) left(ytitle(Score) ylab(0(5)20)) /// 
 start(0) width(5) ytitle(score) ylab(0(5)20)  xscale(off) 

yyy
*/ 
   
*********************************************************************
*** auxiliary functions for computing f(a) or characteristics of f(a) 

*** normal distribution   

program define normaldens 
  syntax varlist, mu(real) lnsigma(real) gen(name)
  local var `varlist' 
  qui gen  double `gen' = normalden(`var',`mu',exp(`lnsigma'))
end   

program define normalchar , rclass 
  return local mean mu  
  return local sd exp(lnsigma)
  return local chars mean sd 
end 

*** lognornmaldistribution 

program define lognormaldens  
 syntax varlist, mu(real) lnsigma(real) gen(name)
  local var `varlist' 
  qui gen  double `gen' = normalden(log(`var'),`mu',exp(`lnsigma'))/`var'
end 

program define lognormalchar  , rclass 
  syntax 
  local sigma2 (exp(lnsigma)^2) 
  return local mean exp(mu+0.5*`sigma2')
  return local sd  sqrt( (exp(`sigma2')-1) * exp(2*mu+`sigma2'))
  return local chars mean sd 
end 

*** weibull distribution 

program define weibulldens , rclass 
  syntax varlist, lnalpha(real) lnbeta(real) gen(name)
  local var `varlist' 
  qui gen  double `gen' = weibullphden(exp(`lnalpha'),exp(`lnbeta'), `var')
end 

*** uniform distribution 

program define uniformdens
  syntax varname , a(real) b(real) gen(name)
  local var `varlist' 
  qui gen double `gen' = cond(`var'<=`b' & `var'>=`a',1/(`b'-`a'),0) 
end 

*** spline density

program define splinedens 
  syntax varname, knots(numlist) gen(name) * 
  local numknots : list sizeof knots 
  local numpars = `numknots'-1 
  forvalues  i=1/`numpars' { 
    local args `args' beta`i'(real) 
  } 
  syntax varname, `args' knots(numlist) gen(name)
  local var `varlist'  
  mkspline _agest_x_ = `var' , cubic knots(`knots')
  qui gen double `gen'=0 
  forvalues  i=1/`numpars' { 
    qui replace `gen'=`gen'+`beta`i''*_agest_x_`i' 
  } 
  qui replace `gen'=exp(`gen') 
  drop _agest_x_*
end 

*** gompertzmakeham distribution 

program define gompertzmakehamdens 
 syntax varlist, lnalpha(real) lnbeta(real) lnlambda(real) gen(name) [aref(real 0)]
  local x `varlist' 
  local alpha = exp(`lnalpha')
  local beta = exp(`lnbeta')
  local lambda = exp(`lnlambda')
  local alphatrans = `alpha'/exp(`beta'*`aref')
  tempvar ebx 
  qui gen double `ebx' = exp(`beta'*`x')
  qui gen double `gen' = (`alphatrans'*`ebx'  + `lambda') * /// 
                     exp(- (`lambda' * `x') + (`alphatrans'/`beta') *(1-`ebx'))
  qui replace `gen' = 0 if mi(`gen')					 
end  

*** gompertz distribution 

program define gompertzdens 
 syntax varlist, lnalpha(real) lnbeta(real)  gen(name) [aref(real 0)]
  local x `varlist' 
  local alpha = exp(`lnalpha')
  local beta = exp(`lnbeta')
  local alphatrans = `alpha'/exp(`beta'*`aref')
  tempvar ebx 
  qui gen double `ebx' = exp(`beta'*`x')
  qui gen double `gen' = (`alphatrans'*`ebx' ) * /// 
                     exp((`alphatrans'/`beta') *(1-`ebx'))
  qui replace `gen' = 0 if mi(`gen')					 
end  

*** polygon density 

program define polygondens  
  syntax varname , x(numlist)  gen(name)  [fix(integer 2)] * 
  local var `varlist' 
  local np : list sizeof x 
  local from 0 
  local to = `np'-1
  local fromi=1 
  local toi=`to'-1 
  forvalues i=`fromi'/`toi' {
  	if `i'!=`fix' { 
      local args `args' lnalpha`i'(real) 
	}
	else { 
	  local lnalpha`i' 0
	}
  } 
  syntax  varname , x(numlist)  gen(name)  [fix(integer 2)] *  `args' 
  local y`from' 0 
  local y`to' 0 
  forvalues i=`fromi'/`toi' {
  	local y`i' = exp(`lnalpha`i'')
  } 
  forvalues i=`from'/`to' {
  	gettoken x`i' x :x 
  }
  gen double `gen' = 0.0 
  forvalues i=`fromi'/`to' { 
  	local im1=`i'-1
	qui replace `gen' = `y`im1'' + /// 
	   (`var'-`x`im1'')/(`x`i''-`x`im1'')*(`y`i''-`y`im1'') /// 
	   if `var'>=`x`im1'' & `var' < `x`i''
  }

end 

****************************************************************************
*** mymodel: main auxiliary program to compute log-likelihood 

program define mymodel 
  local params : char _dta[params]
  local densage : char _dta[densage]
  gettoken densage call : densage 
  args lnf `params'
  foreach par of local params { 
  	local vars `vars' ``par''
	local call `call' `par'(`=``par''[1]')
  } 
  tempvar ftheta sumftheta
  preserve 
  qui: bys age: keep if _n==1 
  if `:char _dta[supertrace]' di "`call'" _c 
 `densage'dens age , `call'  gen(`ftheta')
  if `:char _dta[trapez]' qui replace `ftheta' = `ftheta'*width
  egen double `sumftheta' = total(`ftheta')
  qui replace `ftheta'=`ftheta'/`sumftheta'
  tempfile aux 
  keep age `ftheta' 
  qui save `aux' 
  restore 
  qui merge n:1 age using `aux' , nogen assert(3)
  tempvar prod sum
  gen double `prod'=fca*`ftheta' 
  sort line age 
  by line: egen double `sum'=total(`prod')
  qui: by line (age): replace `lnf'= cond(_n==1,log(`sum'),0) 
  qui sum `lnf' 
  if `:char _dta[supertrace]' di " ll=" r(sum)
end 

*************************************************************************
*** computefca 
*** computes the values of f(c|a) for a dataset with c (varlist) and 
*** age values 

program define computefca 
  syntax varlist , agevar(varname) fca(name)
  gen double `fca'=1 
  foreach var of local varlist { 
  	local model : char `var'[model]
	local modelparams: char `var'[params]
	gettoken model  spec : model 
	tempvar dens
	`model' `var' `agevar' , `spec' `modelparams' gen(`dens')
	qui replace `fca'=`fca'*`dens' if !mi(`var')
  }
end 

*************************************************************************
*** the main tools 

*************************************************************************
*** popest 
*** paramteric estimation of population distribution 
*** 

program define popest , eclass 
  syntax varlist , densage(string) params(string) gridage(numlist) /// 
     [iterate(integer 25) inits(numlist) trapez supertrace] * 
  preserve 
  local grid : list uniq gridage  
  tempvar aux 
  egen `aux'=rownonmiss(`varlist') 
  qui drop if `aux'==0 
  gen line=_n 
  local grlength : list sizeof grid 
  qui expand `grlength'
  qui gen age = .
  local cgrid `grid' 
  forvalues i=1/`grlength' { 
  	gettoken  age cgrid:cgrid 
	qui: bys line: replace age=`age' if _n==`i' 
  } 
  if "`trapez'"=="trapez" { 
    qui: bys line (age): gen width=(age[_n+1]-age[_n-1])/2 
    qui: bys line (age): replace width=(age[2]-age[1])/2 if _n==1
    qui: bys line (age): replace width=(age[_N]-age[_N-1])/2 if _n==_N
  }
  computefca `varlist' , agevar(age) fca(fca) 
  qui count if mi(fca) 
  if r(N)>0 error 99997 
  char _dta[params] `params' 
  char _dta[densage] `densage'  
  char _dta[trapez] `="`trapez'"=="trapez"'
  char _dta[supertrace] `="`supertrace'"=="supertrace"'
  foreach par of local params { 
  	local modelpar `modelpar' (`par':)
  }
  ml model lf mymodel `modelpar' 
  if "`inits'"!="" {  
  	foreach par of local params { 
	  gettoken init inits:inits
  	  local modelinits `modelinits' `par':_cons = `init'
	}
	ml init `modelinits'
  }  
  *ml check 
  ml max , iter(`iterate') `options'
  ereturn local densage `densage' 
  ereturn local params `params'
  ereturn local gridage `grid'
  restore 
end 

***********************************************************************
*** describedist 
*** postestimation command 
*** describing the distribution by computing characteristics numerically 
*** 

program define describedist , rclass 
  syntax, stats(string) [gridage(numlist) trans(string) normgrid(numlist) /// 
                 graph gridgraph(numlist) place(string asis) placeopts(string) ] * 
  if "`placeopts'"=="" local placeopts mlabpos(3) mlabcol(black)
  local densage `e(densage)'
  local params `e(params)'
  if "`gridage'"=="" local gridage `e(gridage)'
  foreach param of local params { 
  	local opts `opts' `param'(`=_b[`param':_cons]')
  }
  preserve 
  _numlisttodata, numlist(`gridage') gen(age) 
  sort age 
  gettoken densage spec : densage 
  `densage'dens age, `spec' `opts' gen(prob) 
  if "`trans'"!="" replace age = `=subinstr("`trans'","#","age",.)'
  local oldstats `stats' 
  local stats 
  foreach stat of local oldstats { 
    if regexm("`stat'","probgt\((.*)\)") {
	  local num = regexs(1) 
	  gen probgt`num'=(age>`num')*100
	  local args `args' (mean) probgt`num' 
	  local vars `vars' probgt`num' 
	} 
   else if regexm("`stat'","probge\((.*)\)") {
	  local num = regexs(1) 
	  gen probge`num'=(age>=`num')*100
	  local args `args' (mean) probge`num' 
	  local vars `vars' probge`num' 
	} 
	else if regexm("`stat'","problt\((.*)\)") {
	  local num = regexs(1) 
	  gen problt`num'=(age<`num')*100
	  local args `args' (mean) problt`num' 
	  local vars `vars' problt`num' 
	} 
    else if regexm("`stat'","proble\((.*)\)") {
	  local num = regexs(1) 
	  gen proble`num'=(age<0`num')*100
	  local args `args' (mean) proble`num' 
	  local vars `vars' proble`num' 
	} 
	else { 
	  local args `args' (`stat') `stat'=age 
	  local vars `vars' `stat' 
	}  
  }
  collapse `args'  [aw=prob] 
  list , noobs 
  if "`graph'"=="graph" { 
	foreach var of local vars { 
	  gettoken y place : place 
	  gettoken x place : place 
	  gettoken text place : place 
	  gettoken format place : place 
	  local call `call' /// 
	     (scatteri `y' `x' `"`text'`=string(`var',"`format'")'"' , msym(i) `placeopts' )
	} 
	if "`normgrid'"!="" { 
	  clear 
	  _numlisttodata, numlist(`normgrid') gen(age) 
      sort age 
      `densage'dens age, `spec' `opts' gen(prob) 
	  collapse (sum) prob 
	  local norm=prob 
	} 
	else { 
	  local norm 1 
	} 
	clear 
    if "`gridgraph'"=="" local gridgraph `gridage' 
	_numlisttodata, numlist(`gridgraph') gen(age) 
    sort age 
    `densage'dens age, `spec' `opts' gen(prob) 
    qui replace prob = max(0,prob/`norm') 
	qui replace prob=prob*100 
  	twoway (line prob age)  `call' /// 
	  , legend(off) /// 
	  ytitle(% per year) `options' 
  } 
  restore 
end 

***********************************************************************
*** indest
*** postestimation command 
*** computations of individual posterior means 
*** 

program define indest 
  syntax varlist, [postmean(name) postsd(name) postmode(name) /// 
     gridage(numlist) densage(string)] 
  tempvar line 
  gen `line'=_n 
  if "`densage'"=="" { 
  	local densage `e(densage)'
    local params `e(params)'
    foreach param of local params { 
  	  local opts `opts' `param'(`=_b[`param':_cons]')
    }
  } 
  if "`gridage'"=="" local gridage `e(gridage)'
  if "`gridage'"=="" errmsg 99991 "gridage() must be specified" 
  preserve 
  _numlisttodata, numlist(`gridage') gen(age) 
  gettoken densage spec : densage 
  `densage'dens age, `spec' `opts' gen(prob) 
  keep age prob 
  tempfile agetoprob 
  qui save `agetoprob' 
  restore 
  preserve 
  cross using `agetoprob'
  tempvar fca
  computefca `varlist' , agevar(age) fca(`fca') 
  keep `line' age `fca' prob 
  tempfile lineagetofca
  qui save `lineagetofca'
  restore
  if "`postmean'"!="" | "`postsd'"!="" { 
    if "`postmean'"=="" { 
	  tempvar newvar 
	  local postmean `newvar' 
	} 
    preserve 
    use `lineagetofca' , clear 
    gen double z = `fca'*prob*age 
    gen double n = `fca'*prob 
    collapse (sum) z n   , by(`line') 
    gen `postmean' = z/n 
    keep `line' `postmean' 
    tempfile linepostmean
    qui save `linepostmean'
    restore 
    qui merge 1:1 `line' using `linepostmean', nogen assert(3)    
  }
  if "`postsd'"!="" { 
    preserve 
    use `lineagetofca' , clear 
    qui merge n:1 `line' using `linepostmean', nogen assert(3)   
    gen double z = `fca'*prob*(age-`postmean')^2 
    gen double n = `fca'*prob 
    collapse (sum) z n  , by(`line') 
    gen `postsd' = sqrt(z/n) 
    keep `line' `postsd' 
    tempfile linepostsd
    qui save `linepostsd'
    restore 
    qui merge 1:1 `line' using `linepostsd', nogen assert(3) 
  } 
  if "`postmode'"!="" { 
    preserve 
    use `lineagetofca' , clear 
	gen double aux = `fca'*prob  
	bys `line': egen double max=max(aux) 
	qui keep if max==aux 
	collapse (mean) age, by(`line') 
    gen `postmode' = age
    keep `line' `postmode' 
    tempfile linepostmode
    qui save `linepostmode'
    restore 
    qui merge 1:1 `line' using `linepostmode', nogen assert(3) 
  } 
end   



*************************************************************************
*** describedistt 
*** postestimation command 
*** computing characteristics (including CIs) using formulas 
*** (not yet used) 

program define describedistt , rclass 
  syntax
  local densage `e(densage)'
  local params `e(params)'
  `densage'char 
  return list 
  foreach char in `r(chars)' { 
  	local expr `r(`char')'
    foreach param of local params { 
  	  local expr = subinstr("`expr'","`param'","_b[`param':_cons]",.) 
    }
    local exprs  `exprs' (`char':`expr')
  }
  return add 
  cap noi nlcom `exprs' 
  return add 
end 


/* 
*** test code 
global  standardmodel oregressprob  distf(logistic) 
global  standardparams from(1) to(7) kappa(25 35 45 55 65 75 ) sigma(10.0)
	 
input y1 y2 y3 freq
1 1 2 2
2 3 1 6 
3 2 4 5
4 5 3 4
5 4 6 3
6 7 5 3
7 6 7 3
end 

expand freq 

forvalues i=1/3 { 
  char y`i'[model] $standardmodel 
  char y`i'[params] $standardparams
} 

showdescriptandvarord y1 , gridage(1(1)100)

*** fitting of a normal model with different grids and integration methods 

local spec0 params(mu lnsigma) densage(lognormal) inits(3 -1) 
local spec1 params(beta1 beta2) densage(spline knots(20 40 60)) 
local spec2 params(beta1 beta2 beta3) densage(spline knots(20 30 40 60)) 
local spec3 params(beta1 beta2 beta3 beta4) densage(spline  knots(20 30 40 50 60)) 
local spec4 params(lnalpha1 lnalpha3 lnalpha4 ) densage(polygon x(0 20 40 60 80 100) fix(2)) 
local spec5 params(lnalpha lnbeta) densage(gompertz aref(50)) 

forvalues s=0/5 { 

popest y1 y2 y3, gridage(1(1)120 ) `spec`s'' 

indest y1 y2 y3 , postmean(pm1) postsd(ps1) 
indest y1 y3 , postmean(pm2)  
indest y1 y3 , postsd(psd2) 
indest y1 y3 , postmode(pd2)  
indest y2 y3 , postmean(pm3) postsd(psd3) postmode(pd3) `uninf' 

local uninf   gridage(1(1)120) densage(uniform a(1) b(120))
indest y1 y2 y3 , postmean(um1) postsd(ps1) `uninf' 
indest y1 y3 , postmean(um2)  `uninf' 
indest y1 y3 , postsd(usd2)  `uninf' 
indest y1 y3 , postmode(ud2)  `uninf' 
indest y2 y3 , postmean(um3) postsd(usd3) postmode(ud3) `uninf' 
list in 1/7 


describedist , stats( mean sd p10 p90 probgt(40) problt(50) proble(10) probge(40))  /// 
   graph gridgraph(1(1)120) xlab(-0(10)120) normgrid(1(1)120) /// 
   place( 2 100 "mean=" %5.1f /// 
          1.8 100 sd= %5.1f /// 
		  1.6 100 "p10=" %5.1f /// 
		  1.4 100 "p90=" %5.1f /// 
		  1.2 100 "P(>40) = " %5.1f /// 
		  1.0 100 "P(<50) = " %5.1f /// 
		  0.8 100 "P({&le}10) = " %5.1f /// 
          0.6 100 "P({&ge}40) = " %5.1f )  placeopts(mlabsize(*1.2) mlabcol(black) ) 
}		 
*/ 




