### Model 3: Gamma distribution

# Model

model{
 
 for(j in 1:40){
   zeros[j]       <- 0
   zeros[j]       ~  dpois(zeros.means[j])  
   zeros.means[j] <- -lGammaInf[j] + 10000
   
   Gamma[j]       <- exp(-loggam(phi) + phi*(log(phi) - log(mu[j])) + (phi - 1)*log(Y[j])
                         - (phi*Y[j])/mu[j]) 
   
   e[j]           <- equals(Y[j],0.000001)
   GammaInf[j]    <- e[j]*p[j] + (1 - e[j])*Gamma[j]*(1 - p[j]) 
   lGammaInf[j]   <- log(max(0.00000000001, min(0.99999999999, GammaInf[j])))
   
   mu[j]  <- exp(alpha[Treatment[j]] + b[Block[j]])

   logit(Q1[j]) <- (beta[1] + beta[2]*log(mu[j]))
   p[j] <- max(0.00000000001, min(0.99999999999, Q1[j]))

   nu[j] <- mu[j]*(1 - p[j]) 
  }


# Treatment means
  
  p2[1]  <- (p[4]  + p[13] + p[30] + p[36])/4 
  p2[2]  <- (p[5]  + p[16] + p[29] + p[33])/4 
  p2[3]  <- (p[1]  + p[17] + p[28] + p[32])/4 
  p2[4]  <- (p[6]  + p[20] + p[23] + p[35])/4 
  p2[5]  <- (p[9]  + p[12] + p[25] + p[37])/4 
  p2[6]  <- (p[2]  + p[11] + p[27] + p[38])/4 
  p2[7]  <- (p[10] + p[18] + p[21] + p[31])/4 
  p2[8]  <- (p[7]  + p[14] + p[26] + p[34])/4 
  p2[9]  <- (p[8]  + p[15] + p[22] + p[39])/4 
  p2[10] <- (p[3]  + p[19] + p[24] + p[40])/4 

  mu2[1]  <- (mu[4]  + mu[13] + mu[30] + mu[36])/4 
  mu2[2]  <- (mu[5]  + mu[16] + mu[29] + mu[33])/4 
  mu2[3]  <- (mu[1]  + mu[17] + mu[28] + mu[32])/4 
  mu2[4]  <- (mu[6]  + mu[20] + mu[23] + mu[35])/4 
  mu2[5]  <- (mu[9]  + mu[12] + mu[25] + mu[37])/4 
  mu2[6]  <- (mu[2]  + mu[11] + mu[27] + mu[38])/4 
  mu2[7]  <- (mu[10] + mu[18] + mu[21] + mu[31])/4 
  mu2[8]  <- (mu[7]  + mu[14] + mu[26] + mu[34])/4 
  mu2[9]  <- (mu[8]  + mu[15] + mu[22] + mu[39])/4 
  mu2[10] <- (mu[3]  + mu[19] + mu[24] + mu[40])/4 

  nu2[1]  <- (nu[4]  + nu[13] + nu[30] + nu[36])/4 
  nu2[2]  <- (nu[5]  + nu[16] + nu[29] + nu[33])/4 
  nu2[3]  <- (nu[1]  + nu[17] + nu[28] + nu[32])/4 
  nu2[4]  <- (nu[6]  + nu[20] + nu[23] + nu[35])/4 
  nu2[5]  <- (nu[9]  + nu[12] + nu[25] + nu[37])/4 
  nu2[6]  <- (nu[2]  + nu[11] + nu[27] + nu[38])/4 
  nu2[7]  <- (nu[10] + nu[18] + nu[21] + nu[31])/4 
  nu2[8]  <- (nu[7]  + nu[14] + nu[26] + nu[34])/4 
  nu2[9]  <- (nu[8]  + nu[15] + nu[22] + nu[39])/4 
  nu2[10] <- (nu[3]  + nu[19] + nu[24] + nu[40])/4 

  
# Priors
  
  for (i in 1:10){  
  alpha[i] ~ dnorm(0.01, 0.1)  
   }

  beta[1] ~ dnorm(0.01, 0.1)
  beta[2] ~ dnorm(0.01, 0.1)I(, 0)

  
  phi ~ dgamma(0.01, 0.01)
  
  B <- 0.1                        
  inv.B.squared <- 1/pow(B, 2)
  z ~ dnorm(0, inv.B.squared)      
  chisq.1 ~ dgamma(0.5, 0.5)       
  s.b <- abs(z)/sqrt(chisq.1)      
  prec.b <- 1/pow(s.b, 2)

  for(i in 1:8){
    b[i] ~ dnorm(0, prec.b)
  }
}