$PROBLEM Final model #61
$INPUT ID TIME AMT RATE DROP DV CMT MDV TAD TADI OBES TBW LBW IBW BMI WHR AGE SEX LOQ IV ROUN 
; Parent=run18
$DATA BOTH.occ1.incl.BLOQ.11.csv     
$SUBROUTINES ADVAN6 TOL=5 
$MODEL
COMP=(PODOSE)
COMP=(CENTRAL)
COMP=(PERIP)
COMP=(PERIP2)
COMP=(TRANSIT1)
COMP=(TRANSIT2)
COMP=(TRANSIT3)
$PK
TVCL= THETA(1)
CL= TVCL*EXP(ETA(1))     	

TVF1= THETA(2)*THETA(10)**OBES
F1= TVF1*EXP(ETA(2))	                         ; oral bioavailability

TVV2= THETA(3)*(1+THETA(8)*(TBW-127))
V2= TVV2*EXP(ETA(5))                           ; volume (L) 

TVQ= THETA(4)
Q= TVQ*EXP(ETA(3))                               ; intercompartmental clearance (L/min)

TVV3= THETA(5)*(TBW/127)**THETA(9)
V3= TVV3*EXP(ETA(6))                           ; peripheral volume of distribution (L)

TVKA= THETA(6)*THETA(11)**OBES
KA= TVKA*EXP(ETA(4))	                         ; oral absoprtion rate or Ktr (min-1)

KTR= KA
V4= V3                                                       ; 2nd volume periph. compartment (L)
Q4= THETA(7)                                           ; clearance to 2nd periph. compartment (L/min)
;
S2=V2                            
S3=V3
;
K15=KA
K56=KTR
K67=KTR
K72=KTR
K20=CL/V2
K23=Q/V2
K32=Q/V3
K24=Q4/V2
K42=Q4/V4
$DES
DADT(1)= -K15*A(1)
DADT(2)=                                KTR*A(7) -K23*A(2) +K32*A(3) -K24*A(2) +K42*A(4) -K20*A(2)
DADT(3)=                                          K23*A(2) -K32*A(3)
DADT(4)=                                                              K24*A(2) -K42*A(4)
DADT(5)=  K15*A(1) -KTR*A(5)
DADT(6)=            KTR*A(5) -KTR*A(6)
DADT(7)=                      KTR*A(6) -KTR*A(7)
$ERROR
COM1=0
IF (OBES.EQ.0) COM1=1
COM2=0
IF (OBES.EQ.1) COM2=1
;
IPRED=F                                  ; individual prediction
;
Y1=IPRED*(1+ERR(1))           ; healthy volunteers
Y2=IPRED*(1+ERR(2))           ; morbidly obese patients
;
Y=Y1*COM1+Y2*COM2
;
IRES=DV-IPRED                      ; individual residual
DEL=0                                      ; if F=0, than see next lines
IF(IPRED.EQ.0)DEL=1
IWRES=(1-DEL)*IRES/(IPRED+DEL)        
$THETA      
 (0, 0.2)          ;CL (L/min)
(0, 0.3)           ;F1 healthy volunteers
(0, 30)            ;V2 (L)
(0, 0.9)           ;Q (L/min)
(0, 100)          ;V3 (L)
(0, 0.1)           ;KA healthy volunteers
(0, 0.1)           ;Q4
(0, 0.003)      ;TBW V2
(0, 2)              ;TBW V3 
(0, 2)              ;fraction F1 morbidly obese 
(0, 0.5)           ;fraction KA morbidly obese
;
$OMEGA         
0.03            ;CL
0.1              ;F1
0 FIX           ;Q 
0.2              ;KA
$OMEGA BLOCK(2)
0.3                      ;V2 (central)
0.05 0.1             ;V3 (peripheral)
;
$SIGMA       
0.005         ; healthy volunteers
0.1             ; morbidly obese
$EST SIGDIG=3 MAXEVAL=9999 PRINT=5 NOABORT METHOD=1 INTERACTION POSTHOC

