
Figure S1 Goodness-of-fit plots of the final model. The dotted line represents the linear regression line for the observed data with a 95% confidence interval shown as grey shaded area. (a) observed versus population-predicted unbound isavuconazole concentrations. (b) observed versus individual-predicted unbound isavuconazole concentrations. (c) conditional weighted residuals versus time after dose for unbound isavuconazole. (d) conditional weighted residuals versus population-predicted unbound isavuconazole concentrations. (e) observed versus population-predicted total isavuconazole concentration. (f) observed versus individual-predicted total isavuconazole concentration. (g) conditional weighted residuals versus time after dose for total isavuconazole concentrations. (h) conditional weighted residuals versus population-predicted total isavuconazole concentration.
Figure S2 Measured unbound isavuconazole concentrations versus model derived unbound isavuconazole concentrations (a) and measured unbound isavuconazole concentrations versus unbound isavuconazole concentrations calculated using a fixed unbound fraction of 1% (b). 
Figure S3 Box-and-whisker plots of simulated unbound (a) and total (b) isavuconazole trough concentrations (Cmin) at day 3, 7, and 14 days of therapy. Boxes represent the median and 25th and 75th percentile, whiskers represent the range of maximum and minimum values within 1.5x the interquartile range. The dashed horizontal line represents the threshold total isavuconazole Cmin of 2 mg/L currently recommended by international guidelines [1].
Figure S4 Box-and-whisker plots of simulated unbound (a) and total (b) isavuconazole area under the concentration-time curve (AUC) at day 3, 7, and 14 days of therapy. Boxes represent the median and 25th and 75th percentile, whiskers represent the range of maximum and minimum values within 1.5x the interquartile range. The dashed horizontal line represents the total isavuconazole AUC of 60 mg∙h/L. 

S1. DETAILS PROTEIN BINDING ANALYSIS
As described, three different protein binding models to describe the relationship between total and unbound concentrations were tested: a specific (saturable), non-specific (linear) and combined specific and non-specific protein binding model [2, 3]. The specific protein binding model is described by equations 1 and 2, where Cbound = Cbound,specific. The non-specific binding model is described by equations 1 and 3, where Cbound = Cbound,non-specific. The combined specific and non-specific binding model is described by equations 1-3, where Cbound = Cbound,specific + Cbound,non-specific.
(1) Ctotal = Cunbound + Cbound
(2) Cbound,specific = (Cunbound ∙ Bmax) / (kd + Cunbound)
(3) Cbound,non-specific = kns ∙ Cunbound
Here, Ctotal is the total isavuconazole concentration, Cunbound the protein unbound isavuconazole concentration, Cbound the protein bound isavuconazole concentration, Cbound,specific the protein bound isavuconazole concentration by means of specific binding, Cbound,non-specific the protein bound isavuconazole concentration by means of non-specific binding, Bmax the maximum binding capacity, kd the equilibrium dissociation constant, and kns the rate constant of the non-specific protein binding. 

S2. FINAL MODEL CONTROL STREAM
; --- ANOUK M.E. JANSEN, 2023 
$PROBLEM ISAVUCONAZOLE TOTAL AND UNBOUND PK
$INPUT …
$DATA data.csv IGNORE=@ 
; --- UNITS: MILLIGRAMS, LITERS, HOURS

$SUBROUTINES ADVAN5

$MODEL
COMP=(CENTRAL)
COMP=(PERIPHERAL)
COMP=(ORAL)

$PK
; --- CALCULATION TIME AFTER DOSE
IF (NEWIND.LE.1) THEN
DOSE=0	      
TDOS=0	      
ENDIF
IF (AMT.GT.0) THEN
DOSE=AMT
TDOS=TIME
ENDIF
TAD=TIME-TDOS

; --- ALLOMETRIC SCALING FACTORS
ALLOCL = ((WT/70)**0.75)
ALLOV  = ((WT/70)**1.00)

; --- TYPICAL VALUES FIXED EFFECTS
TVCL = THETA(1) 
TVV  = THETA(2)
TVQ  = THETA(3) 
TVV2 = THETA(4)

; --- TYPICAL VALUES RANDOM EFFECTS
BSVCL = ETA(1)
BSVV  = ETA(2)
BSVQ  = ETA(3)
BSVV2 = ETA(4)

BSVKA = ETA(5)
BSVF3 = ETA(6)
BSVD1 = ETA(7)

; --- BOX-COX TRANSFORMATION OF BSVCL 
PHICL  = EXP(BSVCL)
BXCL  = THETA(7)
ETACL = (PHICL**BXCL-1)/BXCL

; --- PK PARAMETERS
CL = TVCL * ALLOCL * EXP(ETACL)
V  = TVV  * ALLOV  * EXP(BSVV)
Q  = TVQ  * ALLOCL * EXP(BSVQ)
V2 = TVV2 * ALLOV  * EXP(BSVV2)

; --- DESCRIPTION OF ABSORPTION FOR PRE-STUDY ORAL DOSING BASED ON KOVANDA ET AL. [4]
KA = 6.5 * EXP(BSVKA) 	
F3 = 0.974 * EXP(BSVF3)
D1 = 1 * EXP(BSVD1)

; --- SCALING
S1 = V

; --- DISTRIBUTION
K12 = Q/V
K21 = Q/V2
K10 = CL/V
K31 = KA

$ERROR
CU=F

; --- PROTEIN BINDING MODEL
TVBMAX  = THETA(5)
BSVBMAX = ETA(8)
BMAX    = TVBMAX * EXP(BSVBMAX)
KD      = THETA(6)

CB   = (BMAX*CU)/(KD+CU)
CTOT = CU+CB

; --- RESIDUAL ERROR MODEL
IF(UNB.EQ.0) IPRED = CTOT
IF(UNB.EQ.1) IPRED = CU

IF(UNB.EQ.0) Y=IPRED+IPRED*ERR(1)
IF(UNB.EQ.1) Y=IPRED+IPRED*ERR(2)

$THETA
; --- UNBOUND ISAVUCONAZOLE PK
(0, 215)   	; 1. CL
(0, 2330) 	; 2. V
(0, 2590) 	; 3. Q
(0, 28200) 	; 4. V2

; --- ISAVUCONAZOLE PROTEIN BINDING
(0, 6.64)	; 5. BMAX
0.0806 FIX	; 6. KD 

; ---- BOX-COX TRANSFORMATION OF BSVCL
(-1.28)		; 7. SHAPE FACTOR BOX-COX

$OMEGA
0.771   		; 1. IIV CL
0 FIX  		; 2. IIV V
0 FIX 		; 3. IIV Q
0 FIX 		; 4. IIV V2
0.2116 FIX  	; 5. IIV KA (KOVANDA ET AL.)
0.0049 FIX  	; 6. IIV F3 (KOVANDA ET AL.)
1.74 FIX 	; 7. IIV D1
0.0654		; 8. IIV BMAX

$SIGMA
0.0103 		; 1. PROP RES TOT
0.0202 		; 2. PROP RES UNB

