
SAS Code Used for Data Handling and Statistical Analyses
All analyses were conducted using SAS® Studio Version 3.8, (SAS Institute Inc., Cary, NC, USA).
Text highlighted in yellow can be used to explore predictors of utility in people with primary-progressive multiple sclerosis (PPMS)
libname moac "/folders/myfolders/";

*************************************************************************************
Select patients based on RRMS, SPMS
*************************************************************************************;

*Import medical history (mh) data;
data mh_1; 
	set moac.mh;
	drop STUDYID DOMAIN MHSEQ MHGRPID MHREFID MHSPID MHTERM MHMODIFY MHLLT MHPRESP MHOCCUR MHSTAT MHREASND MHBODSYS MHSOC MHLOC MHLAT MHSEV MHPATT MHCONTRT VISITNUM VISIT MHDTC MHSTDTC MHENDTC MHDY MHSTDY MHENDY MHDUR MHSTRF MHENRF MHEVLINT MHENRTPT MHENTPT MHHLGT;
run;

data mh; 
	set mh_1;
if mhdecod in ("Relapsing-remitting multiple sclerosis","Secondary progressive multiple sclerosis","Primary progressive multiple sclerosis");
	if mhdecod = "Relapsing-remitting multiple sclerosis" then MSType = "RRMS";
	if mhdecod = "Secondary progressive multiple sclerosis" then MSType = "SPMS";
	if mhdecod = "Secondary progressive multiple sclerosis" then MSType = "PPMS";
	if MSType = "RRMS" then MSTypeCode = 1;
	if MSType = "SPMS" then MSTypeCode = 2;
if MSType = "PPMS" then MSTypeCode = 3;
	drop mhcat mhscat mhdecod;
run;

*Remove duplicates from mh data;
proc sort data=mh nodupkey; by usubjid; run;

*************************************************************************************
Merge medical history mh1 with demographics, removing duplicates
*************************************************************************************;

*Import demographics (dm) data;
data dm_1; 
	set moac.dm;
drop STUDYID DOMAIN RFSTDTC_ RFENDTC_ RFSTDTC RFENDTC DTHDTC DTHFL SITEID INVID INVNAM BRTHDTC DMDTC DMDY DMENDY DMDTC_TS ARMCD ARM ACTARMCD ACTARM COUNTRY;
run;

*Remove duplicates from dm data;
proc sort data=dm_1 nodupkey; by usubjid; run;

*Merge mh and dm data;
data mh_dm; merge mh (in=a) dm_1;
	by usubjid;
	if a;
run;



*************************************************************************************
Create one observation of SF36 per time point to derive SF-6D
*************************************************************************************;

*Import RAND-36 V1.0 (SF36) from questionnaires (qs) data;
data sf36_1; 
	set moac.qs;
	if QSCAT in ("RAND-36 V1.0");
	if VISIT in ("BASELINE WEEK 0","BASELINE","DAY 1","V2 - BASELINE","VISIT 2") then QSDY=1;
	SF36Q_char = substr(QSTESTCD,6,2);
	SF36Q_num = input(SF36Q_char, 2.);
drop SF36Q_char QSTESTCD QSORRES QSSTRESC QSSPID QSORRESU QSSTRESU QSSTAT QSREASND QSBLFL QSDRVFL QSEVAL QSDTC QSTPT QSTPTNUM QSELTM QSTPTREF QSRFTDTC QSEVLINT VISITDY;
run;

*Find records with repeated SF36 questions assigning dup=0;
proc sort data=sf36_1; by usubjid QSDY VISITNUM VISIT SF36Q_num; run;

data sf36_2;
	set sf36_1;
	by usubjid QSDY VISITNUM VISIT SF36Q_num;
	dup = 1; /*1 indicates duplicate = false for sorting purposes*/
	if SF36Q_num = lag(SF36Q_num) then dup = 0;
run;

proc sort data=sf36_2; by usubjid QSDY VISITNUM VISIT SF36Q_num dup; run;

*Keep non-duplicates keeping only records with dup=1;
data sf36_3;
	set sf36_2;
	if dup = 1;
	drop dup;
run;

*Transpose SF36 data to have one observation per visit;
proc sort data=sf36_3; by usubjid QSDY VISITNUM VISIT SF36Q_num; run;

proc transpose data=sf36_3 out=sf36_4 (drop = _name_ _label_) prefix=sf;
	by usubjid QSDY VISITNUM VISIT;
	var QSSTRESN;
	id SF36Q_num;
run;

*Assign 9 to missing data as per SF-6D convension to convert to sf6d;
data sf36_5;
	set sf36_4;
	array sfqs sf1-sf36;
	do over sfqs;
		if sfqs = . then sfqs = 9;
	end;
run;


data sf36_sf6d;
	set sf36_5;

*****************************************************************************
Converting sf36 in sf6d. Code provided by The University of Sheffield under a non-commercial license and it is not shown here. The code directly uses the variables sf1-sf36 from the dataset 'sf36_5', which were specified as such to just copy and paste the code provided by The University of Sheffield.

Access to the programs to convert SF36 to SF6D can be requested at: https://licensing.sheffield.ac.uk/i/health-outcomes/SF-6D.html.

After the code is run, a new dataset called 'sf36_sf6d' is created, with a column labeled 'sf6d', which has the sf6d utility for each observation 
*****************************************************************************;
run;


*Set data to identify the first available observation for each patient with available sf6d;
data sf36_sf6d_1;
	set sf36_sf6d;
	by usubjid;
	dup = 0;
	if (first.usubjid and VISIT in("BASELINE","BASELINE WEEK 0") and sf6d ne .) then dup = 1;
run;

proc sort data=sf36_sf6d_1; by usubjid QSDY VISITNUM; run;

*Identify observations that had dup = 1 above, and assign an increasing value so it is unique and
different than 0 for each observation of every patient that has sf6d data;
data sf36_sf6d_2;
	set sf36_sf6d_1;
	by usubjid;
	retain Prior_value;
	if first.usubjid then do;
		Prior_value = dup;
		Cumulative_dup = Prior_value;
	end;
	if first.usubjid = 0 then do;
		Cumulative_dup = dup + Prior_value;
		Prior_value = Cumulative_dup;
	end;
run;

*Set data with just sf6d taking out the intermediate steps and observations with missing sf6d;
data sf6d;
	set sf36_sf6d_2;
	if Cumulative_dup = 1;
	if sf6d ne .;
drop sf1-sf36 sf24r sf27r sf28r pf1 rl1 sc1 pn1 mh1 v1 mst1 most SFPhys SFRole SFSocial SFPain SFMental SFVital SFIndex rand1 rand2 rand3 dup Prior_value Cumulative_dup;
run;


*************************************************************************************
Import EDSS from questionnaires (qs) data and creating one observation per time point
*************************************************************************************;

data edss_1; 
	set moac.qs;
	if QSCAT in ("EDSS");
	if VISIT in ("BASELINE WEEK 0","BASELINE","DAY 1","V2 - BASELINE","VISIT 2") then QSDY=1;
	EDSS = QSSTRESN;

	/*Group EDSS by range*/
	if edss = 0 then edss_cat = "0";
	if edss = 1 or edss= 1.5 then edss_cat = "1-1.5";
	if edss = 2 or edss= 2.5 then edss_cat = "2-2.5";
	if edss = 3 or edss= 3.5 then edss_cat = "3-3.5";
	if edss = 4 or edss= 4.5 then edss_cat = "4-4.5";
	if edss = 5 or edss= 5.5 then edss_cat = "5-5.5";
	if edss = 6 or edss= 6.5 then edss_cat = "6-6.5";
	if edss = 7 or edss= 7.5 then edss_cat = "7-7.5";
	if edss = 8 or edss= 8.5 then edss_cat = "8-8.5";
	if edss = 9 or edss= 9.5 then edss_cat = "9-9.5";

drop QSSTRESN STUDYID DOMAIN QSSEQ QSCAT QSSCAT QSTEST QSGRPID QSTESTCD QSORRES QSSTRESC QSSPID QSORRESU QSSTRESU QSSTAT QSREASND QSBLFL QSDRVFL QSEVAL QSDTC QSTPT QSTPTNUM QSELTM QSTPTREF QSRFTDTC QSEVLINT VISITDY;
run;

*************************************************************************************
Merge SF6D and EDSS data by ID and visit day 
*************************************************************************************;
proc sort data=sf6d; by usubjid qsdy; run;
proc sort data=edss_1; by usubjid qsdy; run;

data sf6d_edss; 
	merge sf6d (in=a) edss_1;
	by usubjid qsdy;
	if a;
run;

*************************************************************************************
Merge the above data sf6d_edss with medical history and demographics data (mh-dm) by ID
*************************************************************************************;
proc sort data=sf6d_edss; by usubjid; run;
proc sort data=mh_dm; by usubjid; run;
data master_1; 
	merge mh_dm (in=a) sf6d_edss;
	by usubjid;
	if a;
	if sf6d ne .;
run;



*************************************************************************************
Create one observation of T25FW, 9HPT, PASAT per time point from the functional test (ft) data
*************************************************************************************;

* import FT data (T25FW, NHPT, PASAT);
data ft_1;
	set moac.ft;
	if FTCAT in ("NHPT","T25FW","PASAT");
if FTTEST in ("T25FW1-Time to Complete 25-Foot Walk","NHPT01-Time to Complete 9-Hole Peg Test","PASAT1-Total Correct");
   	if VISIT in ("BASELINE WEEK 0","BASELINE","DAY 1","V2 - BASELINE","VISIT 2") then FTDY=1;
drop STUDYID DOMAIN FTSEQ FTGRPID FTREFID FTSPID FTTSTDTL FTPOS FTSTAT FTREASND FTNAM FTMETHOD FTBLFL FTDRVFL FTEVAL VISITDY FTDTC FTTPT FTTPTNUM FTELTM FTTPTREF FTRFTDTC FTREPNUM;
run;

*Set T25FW data;
data t25fw_1;
	set ft_1;
	if FTCAT in ("T25FW");
	if FTTEST in ("T25FW1-Time to Complete 25-Foot Walk");
	if FTSTRESN>180 then FTSTRESN = 180;/*Setting max 180 seconds by convention of test*/
	drop FTSCAT FTORRES FTORRESU FTSTRESC FTSTRESU;
run;

proc sort data=t25fw_1; by usubjid FTDY VISITNUM VISIT; run;

data t25fw_2;
	set t25fw_1;
	t25fwprev = lag(FTSTRESN);
	if (VISIT = lag(VISIT)) and (usubjid = lag(usubjid)) then dup = 1;
		else dup = 0;
run;

*Macro used to look at the next observation. This is needed to calculate the average for patients with
two measures of the test. It is used for T25FW, NHPT and PASAT;
*Obtained from: https://blogs.sas.com/content/sgf/2017/11/01/hopping-for-the-best-calculations-across-sas-dataset-observations/;
%macro hop(d,x,y,j);
   _p_ = _n_ + &j;
   if (1 le _p_ le _o_) then set &d(keep=&x rename=(&x=&y)) point=_p_ nobs=_o_;
%mend hop;

data t25fw_3;
	set t25fw_2;
	if dup = 0 then
	do;
		%hop(t25fw_2,VISIT,TEMP1, 1)
		if VISIT ne TEMP1 then dup = 2;
	end;
	if dup = 1 then t25fw = (FTSTRESN+t25fwprev)/2;
	if dup = 2 then t25fw = FTSTRESN;
run;

data t25fw_4;
	set t25fw_3;
	if dup ne 0;
	QSDY = FTDY;
	drop t25fwprev dup TEMP1 FTDY FTTESTCD FTTEST FTCAT FTSTRESN;
run;

proc sort data=master_1; by usubjid QSDY; run;
proc sort data=t25fw_4; by usubjid QSDY; run;

*Merge mh, dm, sf6d, edss, t25fw;
data master_2; 
	merge master_1 (in=a) t25fw_4;
	by usubjid QSDY;
	if a;
run;

*Set NHPT_dh data;
data nhpt_dh_1;
	set ft_1;
	if FTCAT in ("NHPT");
	if FTSCAT in ("DOMINANT HAND");
	if FTSTRESN>300 then FTSTRESN = 300;/*Setting max 300 seconds by convention of test*/
	drop FTTESTCD FTTEST FTCAT FTSCAT FTORRES FTORRESU FTSTRESC FTSTRESU;
run;

proc sort data=nhpt_dh_1; by usubjid FTDY VISITNUM VISIT; run;

data nhpt_dh_2;
	set nhpt_dh_1;
	nhpt_dhprev = lag(FTSTRESN);
	if (VISIT = lag(VISIT)) and (usubjid = lag(usubjid)) then dup = 1;
		else dup = 0;
run;

data nhpt_dh_3;
	set nhpt_dh_2;
	if dup = 0 then
	do;
		%hop(nhpt_dh_2,VISIT,TEMP1, 1)
		if VISIT ne TEMP1 then dup = 2;
	end;
run;

data nhpt_dh_4;
	set nhpt_dh_3;
	by usubjid;
	if (first.usubjid and last.usubjid) then dup = 1;
	if dup = 1 then nhpt_dh = (FTSTRESN+nhpt_dhprev)/2;
	if dup = 2 then nhpt_dh = FTSTRESN;
run;

data nhpt_dh_5;
	set nhpt_dh_4;
	if dup ne 0;
	QSDY = FTDY;
	drop nhpt_dhprev dup TEMP1 FTDY FTSTRESN;
run;

proc sort data=master_2; by usubjid QSDY; run;
proc sort data=nhpt_dh_5; by usubjid QSDY; run;

*Merge mh, dm, sf6d, edss, t25fw, nhpt_dh;
data master_3; 
	merge master_2 (in=a) nhpt_dh_5;
	by usubjid QSDY;
	if a;
run;

*Set NHPT_ndh data;
data nhpt_ndh_1;
	set ft_1;
	if FTCAT in ("NHPT");
	if FTSCAT in ("NON-DOMINANT HAND");
	if FTSTRESN>300 then FTSTRESN = 300;/*Setting max 300 seconds by convention of test*/
	drop FTTESTCD FTTEST FTCAT FTSCAT FTORRES FTORRESU FTSTRESC FTSTRESU;
run;

proc sort data=nhpt_ndh_1; by usubjid FTDY VISITNUM VISIT; run;

data nhpt_ndh_2;
	set nhpt_ndh_1;
	nhpt_ndhprev = lag(FTSTRESN);
	if (VISIT = lag(VISIT)) and (usubjid = lag(usubjid)) then dup = 1;
		else dup = 0;
run;

data nhpt_ndh_3;
	set nhpt_ndh_2;
	if dup = 0 then
	do;
		%hop(nhpt_ndh_2,VISIT,TEMP1, 1)
		if VISIT ne TEMP1 then dup = 2;
	end;
run;

data nhpt_ndh_4;
	set nhpt_ndh_3;
	by usubjid;
	if (first.usubjid and last.usubjid) then dup = 1;
	if dup = 1 then nhpt_ndh = (FTSTRESN+nhpt_ndhprev)/2;
	if dup = 2 then nhpt_ndh = FTSTRESN;
run;

data nhpt_ndh_5;
	set nhpt_ndh_4;
	if dup ne 0;
	QSDY = FTDY;
	drop nhpt_ndhprev dup TEMP1 FTDY FTSTRESN;
run;

proc sort data=master_3; by usubjid QSDY; run;
proc sort data=nhpt_ndh_5; by usubjid QSDY; run;

*Merge mh, dm, sf6d, edss, t25fw, nhpt_dh, nhpt_ndh;
data master_4; 
	merge master_3 (in=a) nhpt_ndh_5;
	by usubjid QSDY;
	if a;
run;

*Set PASAT data;
data pasat_1;
	set ft_1;
	if FTCAT in ("PASAT");
	if FTSTRESN>60 then FTSTRESN = 60;/*Setting max 60 correct answers by convention of test*/
	drop FTTESTCD FTTEST FTCAT FTSCAT FTORRES FTORRESU FTSTRESC FTSTRESU;
run;

proc sort data=pasat_1; by usubjid FTDY VISITNUM VISIT; run;

data pasat_2;
	set pasat_1;
	pasatprev = lag(FTSTRESN);
	if (VISIT = lag(VISIT)) and (usubjid = lag(usubjid)) then dup = 1;
		else dup = 0;
run;

data pasat_3;
	set pasat_2;
	if dup = 0 then
	do;
		%hop(pasat_2,VISIT,TEMP1, 1)
		if VISIT ne TEMP1 then dup = 2;
	end;
run;

data pasat_4;
	set pasat_3;
	by usubjid;
	if (first.usubjid and last.usubjid) then dup = 1;
	if dup = 1 then pasat = round((FTSTRESN+pasatprev)/2);
	if dup = 2 then pasat = FTSTRESN;
run;



data pasat_5;
	set pasat_4;
	if dup ne 0;
	QSDY = FTDY;
	drop pasatprev dup TEMP1 FTDY FTSTRESN;
run;

proc sort data=master_4; by usubjid QSDY; run;
proc sort data=pasat_5; by usubjid QSDY; run;

*Merge mh, dm, sf6d, edss, t25fw, nhpt_dh, nhpt_ndh, pasat;
data master_5; 
	merge master_4 (in=a) pasat_5;
	by usubjid QSDY;
	if a;
run;

data master_6;
	set master_5;
	by usubjid;
	retain sf6d_base;
	if first.usubjid then sf6d_base = sf6d;
		else sf6d_base = sf6d_base;
run;

proc sort data=master_6; by usubjid QSDY VISITNUM; run;

*************************************************************************************
Relapses from clinical events (ce) dataset
*************************************************************************************;
data relapse_1;
	set moac.ce;
	/*Options in line below are to obtain only confirmed relapses*/
if MIDS in ("MS RELAPSE 1","MS RELAPSE 2","MS RELAPSE 3","MS RELAPSE 4","MS RELAPSE 5","MS RELAPSE 6","MS RELAPSE 7","MS RELAPSE 8","MS RELAPSE 9");
	Relapses_char = substr(MIDS,12,1);
	Relapses_num = input(Relapses_char, 1.);
drop STUDYID DOMAIN CESEQ CEGRPID CEREFID CESPID CETERM CEMODIFY CEDECOD CECAT CESCAT CEPRESP CEOCCUR CESTAT CEREASND CEBODSYS CELOC CELAT CEPATT CEOUT CESHOSP CECONTRT CETOXGR EPOCH CEDTC CESTDTC CEENDTC CEDY CESTRF CEENRF CEEVLINT CEEVINTX CESTRTPT CEENRTPT CEENTPT CESTTPT MIDS Relapses_char;
	if CESTDY =. then CESTDY = CEENDY;
	/*Line below is to delete relapses without know start or end time. 23 records were deleted*/
	if CESTDY =. and CEENDY =. then delete;
	if Relapses_num	> 0 then Relapse = 1;
run;

proc sort data=relapse_1; by usubjid CESTDY VISITNUM; run;

proc transpose data=relapse_1 out=relapse_2 (drop = _name_ _label_) prefix=Start_Rel_;
	by usubjid;
	var CESTDY;
	id Relapses_num;
run;

proc sort data=relapse_2; by usubjid; run;

proc sort data=master_6; by usubjid QSDY VISITNUM; run;

data master_7;
	merge master_6 (in=a) relapse_2;
	by usubjid;
	if a;
run;

*Determining which relapses happened before each visit/observation;
data master_8;
	set master_7;
	by usubjid;
	if Start_Rel_1 ne . then do;
		if lag(QSDY) <= Start_Rel_1 <= QSDY then Rel_1 = 1;
	end;
	if Start_Rel_2 ne . then do;
		if lag(QSDY) < Start_Rel_2 <= QSDY then Rel_2 = 1;
	end;
	if Start_Rel_3 ne . then do;
		if lag(QSDY) < Start_Rel_3 <= QSDY then Rel_3 = 1;
	end;
	if Start_Rel_3 ne . then do;
		if lag(QSDY) < Start_Rel_4 <= QSDY then Rel_4 = 1;
	end;
	if Start_Rel_5 ne . then do;
		if lag(QSDY) < Start_Rel_5 <= QSDY then Rel_5 = 1;
	end;
	if Start_Rel_6 ne . then do;
		if lag(QSDY) < Start_Rel_6 <= QSDY then Rel_6 = 1;
	end;
	if Start_Rel_7 ne . then do;
		if lag(QSDY) < Start_Rel_7 <= QSDY then Rel_7 = 1;
	end;
	if Start_Rel_8 ne . then do;
		if lag(QSDY) < Start_Rel_8 <= QSDY then Rel_8 = 1;
	end;
	if Start_Rel_9 ne . then do;
		if lag(QSDY) < Start_Rel_9 <= QSDY then Rel_9 = 1;
	end;
	/*Calculating number of relapses before each visit/observation and defining categories: 0, 1+*/
	Visit_relapses = sum(of Rel_1-Rel_9);
	if Visit_relapses = . then Visit_relapses = 0;
	if Visit_relapses > 1 then do Relapse = 1; end;
	if Visit_relapses = 1 then do Relapse = 1; end;
	if Visit_relapses = 0 then do Relapse = 0; end;
	
	drop Start_Rel_1-Start_Rel_9 rel1-rel9 Visit_relapses;
run;	

proc sort data=master_8; by usubjid qsdy; run;

*Calculate the time since previous visit for each visit to determine if a relapse has occurred within the last 180 days;
data master_9;
	set master_8;
	by usubjid;
	retain prior_qsdy;
	if first.usubjid then do;
		prior_qsdy = qsdy;
		qsdy_sinceprevvisit = prior_qsdy;
	end;
	if first.usubjid = 0 then do;
		qsdy_sinceprevvisit = qsdy - prior_qsdy;
		prior_qsdy = qsdy;
	end;
	if qsdy_sinceprevvisit > 180 then Relapse = 0;
	drop prior_qsdy;
run;

proc sort data=master_9; by usubjid qsdy; run;

*One file for RRMR patients;
data master_rrms;
	set master_9;
	if MSTypeCode = 1;
run;

*One file for SPMS patients;
data master_spms;
	set master_9;
	if MSTypeCode = 2;
run;

*One file for PPMS patients;
data master_spms;
	set master_9;
	if MSTypeCode = 3;
run;

*Proc mixed sf6d rrms;
proc mixed data=master_rrms covtest order=data;
    class usubjid edss_cat(ref="0") Relapse(ref="0") sex(ref="F") race(ref="WHITE");
	model sf6d = edss_cat t25fw nhpt_dh nhpt_ndh pasat Relapse age sex race/ ddfm=kr s;
	random intercept / subject=usubjid type=un;
run;


*Proc mixed sf6d spms;
proc mixed data=master_spms covtest order=data;
    class usubjid edss_cat(ref="0") Relapse(ref="0") sex(ref="F") race(ref="WHITE");
	model sf6d = edss_cat t25fw nhpt_dh nhpt_ndh pasat Relapse age sex race/ ddfm=kr s;
	random intercept / subject=usubjid type=un;
run;

*Proc mixed sf6d ppms;
proc mixed data=master_ppms covtest order=data;
    class usubjid edss_cat(ref="0") Relapse(ref="0") sex(ref="F") race(ref="WHITE");
	model sf6d = edss_cat t25fw nhpt_dh nhpt_ndh pasat Relapse age sex race/ ddfm=kr s;
	random intercept / subject=usubjid type=un;

