
Online Resource 1.
1 Detail of the functions used
Table. 1. Function dependencies
	Function Name
	Function Purpose
	Argument List
	Calls or Depends On
	Used By / Returns

	runSim
	Main simulation driver that coordinates event sampling, looping, and output extraction
	rand1, rand2, rand3, rand4, rand5, hipAlpha, hipBeta, hipEfficacy, vertAlpha, vertBeta, vertEfficacy, meanSurv, sdSurv, baseUtility, hipUtilityMult, vertUtilityMult, hipCost, vertCost, annualCost, discRateC, discRateQ, discRateCi, discRateQi, hipDeathThreshold, maxIter, verbose
	sampleWeibull, sampleNormal, REDUCE, ProcessEvent
	Outputs QALY, dQALY, cost, dCost, death

	sampleWeibull
	Samples a Weibull-distributed event time
	alpha, beta, rand
	—
	Used within runSim

	sampleNormal
	Samples a Normally-distributed event time
	mean, sd, rand
	—
	Used within runSim

	ProcessEvent
	Determines next event and routes to the appropriate handler
	status, tVert2, discRateQi, discRateC, discRateCi, vertCost, hipCost, annualCost, vertUtilityMult, hipUtilityMult, hipDeathRisk, hipDeathThreshold
	getNextEvent, handleVertEvent, handleHipEvent, handleDeathEvent
	Called by runSim → REDUCE

	getNextEvent
	Identifies the earliest of the three scheduled events
	tVert, tHip, tDeath
	—
	Used within ProcessEvent

	handleVertEvent
	Updates state and outcomes after a vertebral fracture
	currU, vertStatus, lastTime, nextTime, tVert2, discRateQi, discRateC, vertCost, vertUtilityMult
	calcDiscountedQALY, calcDiscountedCost
	Used within ProcessEvent

	handleHipEvent
	Handles utility and cost changes after hip fracture and determines fracture-related death
	currU, lastTime, nextTime, discRateQi, discRateC, discRateCi, hipCost, annualCost, hipUtilityMult, hipDeathRisk, hipDeathThreshold
	calcDiscountedQALY, calcDiscountedCost, calcDiscAnnCost
	Used within ProcessEvent

	handleDeathEvent
	Finalizes state at death and calculates final QALYs and costs
	currU, lastTime, nextTime, discRateQi, discRateCi, annualCost
	calcDiscountedQALY, calcDiscAnnCost
	Used within ProcessEvent

	calcDiscountedQALY
	Computes QALYs over an interval with continuous discounting
	u, t1, t2, discRateQi
	—
	Used in all event handlers

	calcDiscountedCost
	Computes a one-time cost with exponential discounting
	cost, t, discRateC
	—
	Used in vertebral and hip handlers

	calcDiscAnnCost
	Calculates the present value of a stream of annual costs using continuous discounting
	cost, t, discRateCi
	—
	Used in hip and death handlers



2 Overview of LAMBDA, REDUCE, LET, VSTACK and HSTACK
2.1 LAMBDA
=LAMBDA(x, y, x + y)


This simple function takes two inputs (x and y) and returns their sum. This can be saved in the spreadsheet using Name Manager, or more easily using the AFE. It then allows a user to call the function in any spreadsheet cell. This is powerful because it allows recursion. Consider the following example. We define a new name, Factorial:
=LAMBDA(n, IF(n<=1, 1, n * Factorial(n - 1)))


This formula will return 1 when n is 1 but otherwise will return the factorial of the number supplied (e.g., for 5 this is 5 x 4 x 3 x 2 x 1). It should be noted that recursion in a LAMBDA function can only be called up to 254 level deep. 
2.2 REDUCE
In cases where we need to exceed this limit, we can make use of REDUCE (or SCAN or MAP, but these are beyond the scope of this tutorial) for iterative solutions. REDUCE applies a LAMBDA function repeatedly to an array carrying forward an accumulated result. In the factorial example above this becomes:
=REDUCE(1, SEQUENCE(5), LAMBDA(a, x, a * x))


The SEQUENCE function is a dynamic array function that generates an array of sequential integers, in this case {1;2;3;4;5). The REDUCE function starts with an accumulator (a = 1) and multiplies each x from the sequence into the accumulator. 
(((1 × 1) × 2) × 3) × 4) × 5 = 120


We can save this as a named function for the general case:
=LAMBDA(n, REDUCE(1, SEQUENCE(n), LAMBDA(a, x, a * x)))


2.3 LET
The LET function in Excel allows users to assign names to intermediate calculations within a formula. This improves readability, reduces redundancy, and enhances performance by preventing repeated evaluation of the same expression. It is especially useful in complex formulas.
The basic structure of LET is:
LET(name1, value1, name2, value2, ..., calculation_using_names)


Each name is assigned a value, and the final expression uses those names in place of repeated logic.
=LET(
  x, 5,
  y, 10,
  x + y
)





This returns 15 by first assigning x = 5 and y = 10, then evaluating x + y.
In simulation models, LET can be used to define components like time, utility, or event flags, which are then reused in calculations within a LAMBDA or REDUCE function. 
2.4 HSTACK
The HSTACK function in Excel is used to horizontally combine multiple values or arrays into a single row. It is particularly useful in simulation models for constructing or updating a patient's state vector at each time point, allowing multiple variables to be grouped into a structured format.
The basic structure of HSTACK is:
HSTACK(value1, value2, ..., valueN)


Each argument is placed side-by-side in the resulting output, forming a single row of values.
=HSTACK(0, 1, TRUE, "Alive")


This returns a horizontal array: {0, 1, TRUE, “Alive}. In the context of patient-level simulation, HSTACK is used to assemble a complete row representing the patient's current state, including time, accumulated outcomes, event flags, and death status. These rows can then be appended using VSTACK to build a full event history matrix.
2.5 VSTACK
While HSTACK arranges values horizontally into a single row, VSTACK combines values or arrays vertically into a column structure. In simulation workflows, VSTACK is used to append new state vectors to an existing patient history matrix, adding one row per simulation step.
=VSTACK({0, 1}, {2, 3})


This returns a vertical array:{0, 1
 2, 3}




3 Patient histories
Figure 1 – Example of dynamic full patient history output available by calling runSim with verbose set to TRUE

4 [bookmark: _Ref204616342]
Sampling Functions
Time to fracture events is modeled using the Weibull distribution. The inverse cumulative distribution function is applied to a uniform random variable between 0 and 1. The equation used is:

where t is the time to event, u is the random draw, and α and β are the shape and scale parameters, respectively. This is implemented in Excel using the formula in Box 1.
[bookmark: _Ref204609863]Box 1. This sampleWeibull function takes three arguments and returns a simulated event time. It is stored as a named function and used when sampling times to vertebral and hip fracture events.

=LAMBDA(alpha, beta, rand, beta * (-LN(rand))^(1 / alpha))


Baseline survival time is drawn from a Normal distribution using the inverse transform method. The corresponding equation is:

where μ is the mean survival time, σ is the standard deviation, and Φ−1(u) is the inverse cumulative distribution function of the standard normal distribution. The function is implemented in Excel using the formula in Box 2.
[bookmark: _Ref204609917]Box 2. This sampleNormal function returns a normally distributed survival time and can be reused across patients or scenarios. For convenience, we use the MAX function to ensure positive draws.


=LAMBDA(mean, sd, u, MAX(0, NORM.INV(u, mean, sd)))




5 [bookmark: _Ref204616348]Discounting Functions
5.1 Discounting QALYs
Discounted QALYs are calculated over a time interval [t1,t2] using the formula for continuous discounting:

Where u is the constant utility over the interval, r is the annual discount rate for QALYs, t1 and t2 are the start and end times of the interval. This function assumes continuous utility over the interval and returns the present value of QALYs accrued. It is implemented in Excel using the formula show in Box 3.
[bookmark: _Ref204610213]Box 3. Excel formula for the calculation of the discounted QALY between two time points, calcDiscountedQALY

=utility * (EXP(-rate * startTime) - EXP(-rate * endTime)) / rate


5.2 Discounting One-Time Costs
For one-time costs (e.g., fracture treatment costs), continuous discounting is applied using the exponential discounting formula:

where C is the cost applied at time t, and r is the discount rate for costs. This function returns the present value of a one-time cost incurred at time t. It is implemented in Excel using the formula show in Box 4.
[bookmark: _Ref204610265]Box 4. Excel formula for the calculation of the present value of a one-time cost incurred at time t, calcDiscountedCost


=eventCost / ((1 + rate) ^ eventTime)


5.3 Discounting Ongoing Annual Costs
For recurring annual costs (e.g., long-term care following hip fracture), the present value of a continuous stream of costs from time t until death is calculated using:

where: where C is the cost applied at the start time, t, of the recurring cost stream and r is the discount rate for costs. It is implemented in Excel using the formula show in Box 5.
[bookmark: _Ref204610306]Box 5. Excel formula for calculation of the present value of a stream of annual costs using continuous discounting, calcDiscAnnCost


=annualCost * (1 - EXP(-rate * timeLimit)) / rate


This approach assumes a constant cost flow over time and continuous discounting beginning at the time of the initiating event.


6 Full function code
This section specifies the full function code for all of the functions apart from those already specified in full in Sections 4 & 5.
6.1 runSim
=LET(
    tHip, sampleWeibull(hipAlpha, hipBeta, rand1) * hipEfficacy,
    tVert, sampleWeibull(vertAlpha, vertBeta, rand2) * vertEfficacy,
    tVert2, sampleWeibull(vertAlpha, vertBeta, rand3),
    tDeath, sampleNormal(meanSurv, sdSurv, rand4),
    hipDeathRisk, rand5,
    initialStatus, HSTACK(0, baseUtility, 0, 0, 0, 0, tVert, tHip, tDeath, 0, 0, 0),
    steps, SEQUENCE(maxIter),
    history, REDUCE(
        initialStatus,
        steps,
        LAMBDA(acc, i,
            LET(
                lastRow, INDEX(acc, ROWS(acc), 0),
                isAlive, NOT(INDEX(lastRow, 12)),
                nextRow, processEvent(
                    lastRow,
                    tVert2,
                    discRateQi,
                    discRateC,
                    discRateCi,
                    vertCost,
                    hipCost,
                    annualCost,
                    vertUtilityMult,
                    hipUtilityMult,
                    hipDeathRisk,
                    hipDeathThreshold
                ),
                IF(isAlive, VSTACK(acc, nextRow), acc)
            )
        )
    ),
    final, INDEX(history, ROWS(history), 0),
    IF(
        verbose,
        history,
        HSTACK(INDEX(final, 3), INDEX(final, 5), INDEX(final, 4), INDEX(final, 6), INDEX(final, 12))
    )
)

6.2 processEvent
=LET(
    lastTime, INDEX(status, 1),
    currU, INDEX(status, 2),
    qaly, INDEX(status, 3),
    cost, INDEX(status, 4),
    discQaly, INDEX(status, 5),
    discCost, INDEX(status, 6),
    tVert, INDEX(status, 7),
    tHip, INDEX(status, 8),
    tDeath, INDEX(status, 9),
    vertStatus, INDEX(status, 10),
    hipStatus, INDEX(status, 11),
    deathFlag, INDEX(status, 12),
    nextEvent, getNextEvent(tVert, tHip, tDeath),
    nextTime, INDEX(nextEvent, 1),
    eventCode, INDEX(nextEvent, 2),
    CHOOSE(
        eventCode,
        LET(
            h, handleVertEvent(
                currU,
                vertStatus,
                lastTime,
                nextTime,
                tVert2,
                discRateQi,
                discRateC,
                vertCost,
                vertUtilityMult
            ),
            newU, INDEX(h, 1),
            deltaQ, INDEX(h, 2),
            deltaDQ, INDEX(h, 3),
            deltaC, INDEX(h, 4),
            deltaDC, INDEX(h, 5),
            newTVert, INDEX(h, 6),
            newVertStatus, INDEX(h, 7),
            HSTACK(
                nextTime,
                newU,
                qaly + deltaQ,
                cost + deltaC,
                discQaly + deltaDQ,
                discCost + deltaDC,
                newTVert,
                tHip,
                tDeath,
                newVertStatus,
                hipStatus,
                deathFlag
            )
        ),
        LET(
            h, handleHipEvent(
                currU,
                lastTime,
                nextTime,
                discRateQi,
                discRateC,
                discRateCi,
                hipCost,
                annualCost,
                hipUtilityMult,
                hipDeathRisk,
                hipDeathThreshold
            ),
            newU, INDEX(h, 1),
            deltaQ, INDEX(h, 2),
            deltaDQ, INDEX(h, 3),
            deltaC, INDEX(h, 4),
            deltaDC, INDEX(h, 5),
            newTHip, INDEX(h, 6),
            newDeathFlag, INDEX(h, 7),
            newHipStatus, INDEX(h, 8),
            HSTACK(
                nextTime,
                newU,
                qaly + deltaQ,
                cost + deltaC,
                discQaly + deltaDQ,
                discCost + deltaDC,
                tVert,
                newTHip,
                tDeath,
                vertStatus,
                newHipStatus,
                newDeathFlag
            )
        ),
        LET(
            h, handleDeathEvent(currU, lastTime, nextTime, discRateQi, discRateCi, annualCost),
            newLastTime, INDEX(h, 1),
            newU, INDEX(h, 2),
            deltaQ, INDEX(h, 3),
            deltaC, INDEX(h, 4),
            deltaDQ, INDEX(h, 5),
            deltaDC, INDEX(h, 6),
            newDeathFlag, INDEX(h, 7),
            HSTACK(
                newLastTime,
                newU,
                qaly + deltaQ,
                cost + deltaC,
                discQaly + deltaDQ,
                discCost + deltaDC,
                tVert,
                tHip,
                tDeath,
                vertStatus,
                hipStatus,
                newDeathFlag
            )
        )
    )
)

6.3 getNextEvent
=LET(
    times, HSTACK(timeVert, timeHip, timeDeath),
    labels, {1, 2, 3},
    nextTime, MIN(timeVert, timeHip, timeDeath),
    eventCode, XLOOKUP(nextTime, times, labels),
    HSTACK(nextTime, eventCode)
)

6.4 handleVertEvent
=LET(
    qalyDelta, (nextTime - lastTime) * currU,
    discQalyDelta, calcDiscountedQALY(currU, lastTime, nextTime, discRateQi),
    discCostDelta, calcDiscountedCost(vertCost, nextTime, discRateC),
    costDelta, vertCost,
    newUtility, IF(vertStatus = 0, currU * vertUtilityMult, currU),
    updatedTVert, IF(vertStatus = 0, nextTime + tVert2, 1000000),
    updatedVertStatus, IF(vertStatus = 0, 1, 2),
    HSTACK(
        newUtility,
        qalyDelta,
        discQalyDelta,
        costDelta,
        discCostDelta,
        updatedTVert,
        updatedVertStatus
    )
)
6.5 handleHipEvent
=LET(
    deathNow, deathProb < hipDeathThreshold,
    qalyDelta, (nextTime - lastTime) * currU,
    discQalyDelta, calcDiscountedQALY(currU, lastTime, nextTime, discRateQi),
    costT, annualCost * nextTime,
    discCostT, calcDiscAnnCost(annualCost, nextTime, discRateCi),
    costDelta, hipCost + IF(deathNow, costT, 0),
    discCostDelta, calcDiscountedCost(hipCost, nextTime, discRateC) + IF(deathNow, discCostT, 0),
    newUtility, currU * hipUtilityMult,
    updatedTHip, 1000000,
    deathFlag, IF(deathNow, 1, 0),
    updatedHipStatus, 1,
    HSTACK(
        newUtility,
        qalyDelta,
        discQalyDelta,
        costDelta,
        discCostDelta,
        updatedTHip,
        deathFlag,
        updatedHipStatus
    )
)

6.6 handleDeathEvent
=LET(
    qalyDelta, (nextTime - lastTime) * currU,
    discQalyDelta, calcDiscountedQALY(currU, lastTime, nextTime, discRateQi),
    costDelta, annualCost * nextTime,
    discCostDelta, calcDiscAnnCost(annualCost, nextTime, discRateCi),
    deathFlag, 1,
    HSTACK(1000000, currU, qalyDelta, costDelta, discQalyDelta, discCostDelta, deathFlag)
)




image1.emf
Check full patient history

Patient ID 1

Model armComparator

Time Utility QALY Cost Disc QALYDisc Cost tVert tHip tDeath vertStatushipStatusdeathFlag

0 0.7 0.00 0 0.00 0 4 8 14 0 0 0

4 0.6 3.08 3000 2.85 2579 7 8 14 1 0 0

7 0.6 4.47 6000 4.01 4969 1000000 8 14 2 0 0

8 0.5 5.14 13000 4.53 10345 1000000 1000000 14 2 1 0

1000000 0.5 8.23 13000 6.66 10345 1000000 1000000 14 2 1 1

Patient look up


