
Supplementary materials for

Co-Simulation Evaluation of Power Efficiency and Output Capacitance in Standalone PV MPPT Buck Converters Using 200V p-GaN HEMTs


EPC2215 GaN HEMT SPICE Simulation Code 
.subckt EPC2215 gatein drainin sourcein
.param  si={aWg*1.200e-03} so={aWg*6.150e-03} sr={aWg}
.param  aWg={Wg*1E-3} Wg=1080000 A1={3.625e-02*aWg} k2=1.874e+00 k3=9.000e-02 rpara=5.209e-03
+   rpara_s_factor=2.406e-01 aITc=3.000e-03 arTc=-6.700e-03 k2Tc=6.000e-04
+   x0_0=4.938e+00 x0_0_TC=-2.000e-03 x0_1=-1.285e-01 x0_1_TC=0.000e+00
+   dgs1=4.3e-07 dgs2=2.6e-13 dgs3=0.8 dgs4=0.23
+   ags1={1.045e-09*si} ags2={8.283e-10*si} ags3=1.376e+00 ags4=1.808e-01
+   ags5={0.000e+00*si} ags6=7.480e+01 ags7=1.055e+01
+   agd1={1.124e-15*sr} agd2={1.409e-13*sr} agd3=-6.900e+00 agd4=5.314e+00
+   agd5={2.769e-14*sr} agd6=-2.326e+01 agd7=2.129e+01 agd8={1.081e-15*sr}
+   agd9=-4.326e+01 agd10=1.029e+01
+   asd1={5.053e-11*so} asd2={3.977e-11*so} asd3=-1.941e+01 asd4=2.356e+00
+   asd5={1.449e-11*so} asd6=-8.476e+01 asd7=1.007e+01 asd8={8.934e-11*so}
+   asd9=-3.023e+01 asd10=2.523e+01
+   rg_value=0.4

rd drainin drain {((1-rpara_s_factor)*rpara*(1-arTc*(Temp-25)))}
rs sourcein source {(rpara_s_factor*rpara*(1-arTc*(Temp-25)))}
rg gatein gate {(rg_value)}

Rcsdconv drain source {100000Meg/aWg}
Rcgsconv gate source {100000Meg/aWg}
Rcgdconv gate drain {100000Meg/aWg}

bswitch drain source I=if(v(drain,source)>0,
+   (A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,source)-(k2*(1-k2Tc*(Temp-25))))/k3))*
+   v(drain,source)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,source))*v(drain,source))),
+   (-A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,drain)-(k2*(1-k2Tc*(Temp-25))))/k3))* 
+   v(source,drain)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,drain))*v(source,drain))))

bgsdiode gate source I=if( v(gate,source)>10,
+   (0.125*aWg/1077*(dgs1*(exp((10.0)/dgs3)-1)+dgs2*(exp((10.0)/dgs4)-1))),
+   (0.125*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1))))

bgddiode gate drain I=if( v(gate,drain)>10,
+   (0.125*aWg/1077*(dgs1*(exp((10.0)/dgs3)-1)+dgs2*(exp((10.0)/dgs4)-1))),
+   (0.125*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1))))


C_GS        gate source  {ags1}  TC=0,0
C_CGS1      gate source Q=(0.5*ags2*ags4*log(1+exp((v(gate,source)-ags3)/ags4))+
+   ags5*ags7*log(1+exp((v(source,drain)-ags6)/ags7)))

C_GD        gate drain  {agd1}  TC=0,0
C_CGD1      gate drain Q=(0.5*ags2*ags4*log(1+exp((v(gate,drain)-ags3)/ags4))+
+           agd2*agd4*log(1+exp((v(gate,drain)-agd3)/agd4))+
+           agd5*agd7*log(1+exp((v(gate,drain)-agd6)/agd7))+
+           agd8*agd10*log(1+exp((v(gate,drain)-agd9)/agd10)))

C_SD        source drain  {asd1}  TC=0,0
C_CSD1  source drain Q=(asd2*asd4*log(1+exp((v(source,drain)-asd3)/asd4))+
+   asd5*asd7*log(1+exp((v(source,drain)-asd6)/asd7))+
+   asd8*asd10*log(1+exp((v(source,drain)-asd9)/asd10)))

.ends
E3M0060065D SiC FET SPICE Simulation Code 
Parasitics Included
Tj = Junction Temperature
Tc = Case Temperature
D = Drain
G = Gate
S = Source

.subckt E3M0060065D d g s Tj Tc 
.param p11 = -8
.param p12 = 19
.param Rgint = 3

R1022	Tjc	0	1E6
E1022	Tjc	0 	value {limit(v(Tj),-55,260)}

R100	gk	0	1E6
E100	gk	0 	value {limit(v(g1,s1),-8,19)}

e33	NET3	0	Value {Limit(15.9430u*V(Tj)**2-7.0092m*V(Tj)+2.9816,1.5,3.5)}
R_cc		NET3	0 	1E6

xgmos	d3 d1 gk s1 Tjc NET3 gmos_E3M0060065D

RS		s	sa	7.68m
Ls 		sa	s1	4.9n
R_Ls		sa	s1	5

R_g 		g1	g2	{Rgint}
RG		g	ga	40.343m
Lg 		ga	g2	8.927n

Rd		d	da	64.94u
Ld 		da	d3      3.848n
R_Ld		da	d3	5

Ed		Id	0	value {I(Vdrain_s)}
Rdd		Id	0	1E6

vdrain_s	d3	d1	0
Gheat		0	Tj	value {abs((V(d1,s1)*v(Id)))+abs((V(g1,g2)**2/Rgint))}
xCGD		d3	g1	cgdmos_E3M0060065D
CGS		g1	s1	1011p
R_CGS		g1	s1	1E6

R15	dd1	d1	10E6
e15	dd1	d1	value {
+				if (V(gk)>V(NET3),
+					Limit(((7.2992m*V(Tjc)**2+109.4884m*V(Tjc)-271.2992)*(V(gk)**2)+
+					(-184.3411m*V(Tjc)**2-2.7651*V(Tjc)+6784.3)*v(gk)+
+					(856.1240m*V(Tjc)**2+12.8419*V(Tjc)-30456.1))/1000,-3.5,20)
+					,
+					Limit(((-700.6559u*V(Tjc)**2+181.7979m*V(Tjc)-4.1070)*(V(gk)**2)+
+					(-6.2314m*V(Tjc)**2+1.8296*V(Tjc)-391.8456)*v(gk)+
+					(20.8706m*V(Tjc)**2-5.8408*V(Tjc)-1567.0))/1000,-3.5,2.5)
+					)
+					}


D1		s1	dd1	bodydiode_E3M0060065D
xCds		d3	s1	cds_E3M0060065D
R_DS1		d1	s1	0.5G

.model bodydiode_E3M0060065D d(is=0.88p bv=929 n=6 T_abs=25
+	rs=0.060 Tnom=25 tt=0.5n ibv=500u level=1)

R0 N1 Tj 0.130163
R1 N2 N1 0.409989
R2 N3 N2 0.234421
R3 Tc N3 0.217147

C0 Tj 0 0.607m
C1 N1 0 2.81m
C2 N2 0 10.61m
C3 N3 0 83.36m

.ends E3M0060065D

.subckt gmos_E3M0060065D d3 d1 gk s1 Tjc NET3

.func gain(vgs,t) {
+	Limit(((-1.3111u*t**2+142.0330u*t+8.7696m)*vgs**4+  
+	(69.4628u*t**2-7.9794m*t-423.1987m)*vgs**3+ 
+	(-1.3281m*t**2+169.8177m*t+6.8886)*vgs**2+
+	(10.8307m*t**2-1.6485*t-47.7297)*vgs+
+	(-31.9214m*t**2+6.1634*t+209.5068))/1000,0.001,2)
+
+}

.func nval(vgs,t) {
+	Limit(((15.7669u*t**2-2.3604m*t+7.9856m)*vgs**4+  
+	(-839.2145u*t**2+124.7502m*t+27.1530m)*vgs**3+ 
+	(16.1319m*t**2-2.3745*t-6.0628)*vgs**2+
+	(-131.8940m*t**2+19.1419*t+119.4963)*vgs+
+	(372.8966m*t**2-52.5573*t+22.1726))/1000,.005,2)
+}

.func lam(vgs,t) {
+	Limit(((12.7351n*t**2-2.0859u*t-113.8120u)*vgs**5+
+	(-811.0976n*t**2+133.1795u*t+6.2287m)*vgs**4+  
+	(19.9872u*t**2-3.2782m*t-125.8459m)*vgs**3+ 
+	(-234.8839u*t**2+38.5392m*t+1.1486)*vgs**2+
+	(1.2826m*t**2-211.7719m*t-4.5659)*vgs+
+	(-2.5635m*t**2+428.9293m*t+14.9029))/1000,.00001,0.15)
+}

.func lam3(vgs,t) {
+	Limit(((-103.9952u*t**2+266.1324m*t-19.5883)*vgs**2+
+	(-1.4645m*t**2-5.3604*t+373.9261)*vgs+
+	(45.9392m*t**2+19.6122*t-1009.0))/1000,0,3)	
+}

.func drain_current(vgs,vds,vth,g,n,l) {
+	g*(vgs-vth)*(log(1+exp(vgs-vth))**2 - log(1+exp(vgs-vth-n*vds))**2)*(1+l*vds)
+}


R1001 gr 0	1E6
E1001 gr 0	value {limit(V(gk),-8,15)}

G2 d1 s1 value {
+	if(V(d3,s1)<=0,
+		if (V(gk)<=V(NET3),
+		0
+		,
+		-drain_current(V(gk),V(s1,d3),V(NET3),gain(V(gk),V(Tjc)),nval(V(gk),V(Tjc)),lam3(V(gr),V(Tjc)))*(834.8241n*V(Tjc)**2+166.3685u*V(Tjc)+995.3190m)
+		)
+		,
+		if (V(gk)<=V(NET3),
+		0
+		,
+		drain_current(V(gk),V(d3,s1),V(NET3),gain(V(gk),V(Tjc)),nval(V(gk),V(Tjc)),lam(V(gk),V(Tjc)))*(834.8241n*V(Tjc)**2+166.3685u*V(Tjc)+995.3190m)
+		)
+			)
+			}

.ends gmos_E3M0060065D

.subckt cgdmos_E3M0060065D d3 g1
.param k1=699.33p
.param k2=0.359866
.param ka=2397.706
.param kb=0.13563
.param kc=3.164102

G11 g1 d11 value {
+		k1*(
+		(1+(limit(v(d3,g1),0.1,270))*(1+ka*(1+TANH(kb*V(d3,g1)-kc))/2))**(-k2)
+		)*ddt(v(g1,d3))
+			}
R_CGD d11 d3 1E-4
.ends cgdmos_E3M0060065D


.subckt cds_E3M0060065D d3 s1
.param Cjo = 957p
.param Vj  = 2.14
.param M   = 0.54

G12 d12 s1 value {
+		(Cjo/(1+(limit(v(d3,s1),0.1,270)/Vj)**M))*ddt(v(d3,s1))
+			}
R_CDS d12 d3 1E-4

.ends cds_E3M0060065D

[bookmark: _Hlk162008942]Duty-Cycle P&O Algorithm for MATLAB Simulink 
function D = DutyRatio(V,I)

Dmax = 0.85;
Dmin = 0;
Dinit = 0.85;
deltaD = 0.000006;
persistent Vold Pold Dold;

dataType = 'double';


if isempty(Vold)
    Vold = 0;
    Pold = 0;
    Dold = Dinit;
end

P = V*I;
dV = V-Vold;
dP = P-Pold;

if dP ~= 0
    if dP<0
        if dV<0
            D = Dold - deltaD;
        else
           D = Dold + deltaD;
        end
    else
        if dV<0
            D = Dold + deltaD;
        else
            D = Dold - deltaD;
        end
    end
else D = Dold;
end

if D >= Dmax || D <= Dmin
    D = Dold;
end

Dold = D;
Vold = V;
Pold = P;

MATLAB Simulink Diagram for Proposed PV MPPT System

Fig. S1. MATLAB Simulink Diagram for Proposed PV MPPT System
SPICE Simulation for Power Losses Evaluation

Fig. S2. SPICE simulation of hard switching multi-pulse test

Fig. S3. SPICE hard switching simulation with gate driver modules

Characterization of CISS, COSS and CRSS for EPC2215 GaN HEMT
[image: ]
Fig. S4. 6. Characterization of CISS, COSS and CRSS for EPC2215 GaN HEMT
Schematic and Proposed PCB Design for the Hard-Switching-Multi-Pulse Test

Fig. S5. Schematics of PCB design for the proposed testing
[bookmark: _Hlk158118370]

Fig. S6. On-Board GaN Half Bridge Design
[image: ]
Fig. S7. GaN HEMT PCB 3D layout for hard switching multi-pulse testing

'PULSE(0 6 50n 20n 20 1.383u 2u)

-param RGON=2;
“param RGOFF=2; Turn-off Gate Resistor

b EPCGaNLibrary.ib

b ADuMA1210csub
“temp 25

b "Cree Power C3D Packaged SPICE Model Library.Jib™

V_Ss(on)

.tran 0 26u 0 1n

lib EPCGaNLibrary.lib

-option RELTOL=0.01 .model SN_GDH VSWITCH Roff=1e6 Ron=2 Voff=0 Von=1
-option ABSTOL=1E-9 4 Voff=0 Von=1
-option CHGTOL=1E-12

.option VNTOL=1E-6

{VDRV_P}

0.2n .option noopiter
-option gminsteps=0
~option topologycheck=0

-option temp=25; Set Tj

PULSE(1 -1 0 1n 1n){T_ON} {T_P})

-param RGOFF=2; Turn-off Gate Resistor
{VDRV_P}

-param VDRV_P=5.5; Turn-on Gate Voltage
-param VDRV_N=0; Turn-off Gate Voltage
-param DT=50n; dead time

-param T_ON=1.7777U; Turn-on period

-param T_P=2.2222U; total period

PULSE(-1 1 {DT} 1] ON-2°DT} {T_P})




