Supplementary Material
Manuscript: Seroprevalence, immune response dynamics, and incidence of COVID-19 after CoronaVac vaccination in a fully vaccinated small municipality in Northeast Brazil: a population-based surveillance study.
This document provides the complete and reproducible Stata code used for all data analysis, tables, and figures presented in the manuscript.
1. Data Description
Note on file naming: The original Excel data files are primarily titled in Portuguese, as they were organized by the Brazilian research team during the study, which was conducted entirely in Brazil. File names have been preserved in their original form to maintain traceability with the local data management workflow.
1.1 Raw and Primary Data
	Filename
	Observations
	Key Components

	guara_d1.xlsx
	5,047
	1st vaccine dose data (CPF, name, date, category, vaccine type)

	guara_d2.xlsx
	5,010
	2nd vaccine dose data (CPF, name, date, category, vaccine type)

	guara_d3.xlsx
	4,495
	3rd vaccine dose (booster) data

	guara_d4.xlsx
	1,057
	4th vaccine dose (2nd booster) data

	exames_guara_lacen_limpo.xlsx
	6,208
	Laboratory data (serology and RT-PCR) from GAL/LACEN system

	guara_esus_notifica_limpo_2022.xlsx
	117
	Symptomatic case notifications from e-SUS Notifica system


CPF: Brazilian Individual Taxpayer Registry number was used as a unique identifier.
1.2 Processed and Merged Data
	Filename
	Observations
	Description

	vacina_final.xlsx
	1,714
	Vaccine Database (CoronaVac): Final list of individuals who received complete primary vaccination series

	merge_vacina_SORO_pos_vacina.xlsx
	544
	Serology Database: Merged vaccine + IgG test results for seroprevalence analyses

	swab_coletado_depois_vacinado.xlsx
	706
	RT-PCR (Swab) Database: Merged vaccine + RT-PCR test results for detectable infection analyses

	merge_vacina_SWAB_pos_vacina.xlsx
	798
	RT-PCR (Swab) Full Database: Complete merged vaccine + RT-PCR data including all exam types

	BANCO_UNIFICADO_COVID_GUARAMIRANGA.xlsx
	1,898
	Unified Master Database: Consolidated file merging all data sources


2. Stata Code for Data Preparation and Analysis
Setup: Define Working Directory
Before running any code, set the datadir local macro to the directory where all data files are stored. All subsequent code references this macro for file paths.
/*==============================================================================
SETUP: Define working directory
IMPORTANT: Change the path below to match the location of your data files.
All data files listed in Section 1 must be placed in this directory.
==============================================================================*/
local datadir "INSERT_YOUR_DATA_DIRECTORY_PATH_HERE"
// Example:
// local datadir "C:/Users/username/Documents/Guaramiranga_Data"
// local datadir "/Users/username/Documents/Guaramiranga_Data"
SECTION 1: DATA PREPARATION
1.1: Import, prepare, and save main vaccination database (N=1,714)
display "--- Preparing Vaccination Data ---"
import excel using "`datadir'/VACINA_FINAL.xlsx", sheet("Sheet1") firstrow clear
rename *, lower
tostring cpf, replace format(%11.0f)
gen data_d1 = date(data_d1_real, "DMY")
gen data_d2 = date(data_d2, "DMY")
format data_d1 data_d2 %tdDD/NN/YYYY
gen intervalo_d1_d2 = data_d2 - data_d1
gen faixa_etaria = .
replace faixa_etaria = 1 if idade >= 18 & idade <= 30
replace faixa_etaria = 2 if idade > 30 & idade <= 40
replace faixa_etaria = 3 if idade > 40 & idade <= 50
replace faixa_etaria = 4 if idade > 50 & idade <= 60
replace faixa_etaria = 5 if idade > 60 & idade < .
label define faixa_lbl 1 "18-30" 2 "31-40" 3 "41-50" 4 "51-60" 5 ">60"
label values faixa_etaria faixa_lbl
save "`datadir'/vacina_prep.dta", replace
1.2: Import and prepare serology database (N=544)
display "--- Preparing Serology Data ---"
import excel using "`datadir'/merge_vacina_SORO_pos_vacina.xlsx", sheet("so vacinados corona") firstrow clear
rename *, lower
gen data_coleta_dt = date(data_coleta, "MDY")
gen d2_dt = d2
gen dias_pos_d2 = data_coleta_dt - d2_dt
gen soro_reagente = (resultado == "Reagente")
gen sexo_masc = (paciente_sexo == "Masculino")
merge 1:1 cpf using "`datadir'/vacina_prep.dta", keep(match) nogen force
keep if !missing(dias_pos_d2) & !missing(soro_reagente) & !missing(idade) & !missing(sexo_masc)
save "`datadir'/sorology_prep.dta", replace
1.3: Import and prepare RT-PCR (swab) database (N=706)
display "--- Preparing RT-PCR Data ---"
import excel using "`datadir'/swab_coletado_depois_vacinado.xlsx", sheet("coletado_depois_vacinado") firstrow clear
rename *, lower
gen data_coleta_dt = date(data_coleta, "DMY")
gen d2_dt = d2
gen dias_pos_d2 = data_coleta_dt - d2_dt
gen detectavel = (resultado == "Detectavel")
keep if !missing(dias_pos_d2) & !missing(detectavel)
save "`datadir'/swab_prep.dta", replace
1.4: Import and prepare symptomatic cases database (e-SUS Notifica) (N=116)
display "--- Preparing Symptomatic Cases Data ---"
import excel using "`datadir'/guara_esus_notifica_LIMPO_2022.xlsx", sheet("Sheet1") firstrow clear
rename *, lower
gen dias_pos_d2 = tempo_coleta_d2
keep if !missing(dias_pos_d2)
save "`datadir'/esus_prep.dta", replace
SECTION 2: ANALYSIS REPRODUCTION
Table 1: Demographic and vaccination characteristics
display "--- Generating Table 1 ---"
use "`datadir'/vacina_prep.dta", clear
summarize idade, detail
tabulate paciente_sexo
tabulate categoria_d1
summarize intervalo_d1_d2, detail
Table 2: Seropositivity by time strata
display "--- Generating Table 2 ---"
use "`datadir'/sorology_prep.dta", clear
gen estrato_tempo = .
replace estrato_tempo = 1 if dias_pos_d2 >= 0 & dias_pos_d2 <= 90
replace estrato_tempo = 2 if dias_pos_d2 > 90 & dias_pos_d2 <= 180
replace estrato_tempo = 3 if dias_pos_d2 > 180 & dias_pos_d2 <= 270
replace estrato_tempo = 4 if dias_pos_d2 > 270
label define estrato_label 1 "0-90 days" 2 "91-180 days" 3 "181-270 days" 4 ">270 days"
label values estrato_tempo estrato_label
tabulate estrato_tempo soro_reagente, exact
forvalues i = 1/4 {
    ci proportions soro_reagente if estrato_tempo == `i', exact
}
Table 3: Adjusted Poisson Regression Model
display "--- Generating Table 3: Adjusted Poisson Regression Model ---"
use "`datadir'/sorology_prep.dta", clear
destring idade, replace
glm soro_reagente dias_pos_d2 idade sexo_masc, family(poisson) link(log) vce(robust) eform
estimates store poisson_model
SECTION 3: FIGURE GENERATION
Note on Figure Numbering: The figure numbers below correspond to their numbering in the main manuscript.
Figure 1 (Timeline of Sample Collections): Code provided below.
Figure 2 (Vaccination Timeline): Not generated by this script; created manually based on aggregate data.
Figure 3 (Flowchart): Not generated by this script; created manually.
Figure 4 (Predicted Seropositivity Decline): Code provided below.
Figure 5 (Temporal Trends in IgG and RT-PCR Positivity): Code provided below.

Figure 1: Timeline of Sample Collections
This code generates a bar chart showing the daily frequency of serology (IgG) and RT-PCR (swab) sample collections over the study period. Both sample types are overlaid on the same chart for comparison.
Step 1: Prepare Serology Daily Counts
use "`datadir'/sorology_prep.dta", clear
gen data_num = data_coleta_dt
format data_num %td
collapse (count) n_soro = data_num, by(data_num)
rename data_num data_coleta_dt
save "`datadir'/temp_soro_counts.dta", replace
Step 2: Prepare RT-PCR (Swab) Daily Counts
use "`datadir'/swab_prep.dta", clear
gen data_num = data_coleta_dt
format data_num %td
collapse (count) n_swab = data_num, by(data_num)
rename data_num data_coleta_dt
Step 3: Merge Datasets
merge 1:1 data_coleta_dt using "`datadir'/temp_soro_counts.dta"
replace n_swab = 0 if n_swab == .
replace n_soro = 0 if n_soro == .
Step 4: Generate the Bar Chart
graph twoway (bar n_swab data_coleta_dt, fcolor(orange) lcolor(orange)) (bar n_soro data_coleta_dt, fcolor(blue) lcolor(blue)), title("Daily Frequency of Sample Collections - Guaramiranga", size(medlarge)) ytitle("Number of Samples Collected", size(medium)) xtitle("Collection Date", size(medium)) ylabel(0(20)80, angle(horizontal) labsize(small)) xlabel(22281 "Jan/2021" 22460 "Jul/2021" 22645 "Jan/2022" 22826 "Jul/2022", labsize(small) angle(0)) legend(order(1 "Swab (RT-PCR)" 2 "Serology (IgG)") pos(2) ring(0) size(small)) graphregion(color(white)) plotregion(margin(small) color(white)) name(timeline_bar_chart, replace)
Step 5: Export Graph in High Resolution
graph export "`datadir'/Figure1_Timeline_Sample_Collections.png", as(png) name(timeline_bar_chart) replace width(4200) height(2400)
erase "`datadir'/temp_soro_counts.dta"
Figure 4: Predicted Seropositivity Decline (Poisson Model)
This figure combines the predicted probability curve from the Poisson model with observed proportions at each time stratum.
// STEP 1: Generate and save model predictions
display "Step 1: Generating model predictions for Figure 4"
use "`datadir'/sorology_prep.dta", clear
destring idade, replace
glm soro_reagente dias_pos_d2 idade sexo_masc, family(poisson) link(log) vce(robust)
margins, at(dias_pos_d2=(0(10)330) idade=(36.1) sexo_masc=0) saving("`datadir'/margins_pred.dta", replace)
use "`datadir'/margins_pred.dta", clear
rename _at1 dias_pos_d2
rename _margin prob_pred
rename _ci_lb lower_ci
rename _ci_ub upper_ci
foreach var of varlist prob_pred lower_ci upper_ci {
    replace `var' = `var' * 100
}
save "`datadir'/predictions_for_plot.dta", replace

// STEP 2: Generate observed proportions for each time stratum
display "Step 2: Calculating observed proportions for Figure 4"
use "`datadir'/sorology_prep.dta", clear
gen estrato_tempo = .
replace estrato_tempo = 1 if dias_pos_d2 >= 0 & dias_pos_d2 <= 90
replace estrato_tempo = 2 if dias_pos_d2 > 90 & dias_pos_d2 <= 180
replace estrato_tempo = 3 if dias_pos_d2 > 180 & dias_pos_d2 <= 270
replace estrato_tempo = 4 if dias_pos_d2 > 270
cap postclose obs_data
postfile obs_data estrato_midpoint obs_n obs_prop obs_lower obs_upper using "`datadir'/observed_data.dta", replace
forvalues i = 1/4 {
    if `i' == 1 local current_midpoint = 45
    if `i' == 2 local current_midpoint = 135
    if `i' == 3 local current_midpoint = 225
    if `i' == 4 local current_midpoint = 290
    ci proportions soro_reagente if estrato_tempo == `i', exact
    local n = r(N)
    local prop = r(mean) * 100
    local lower = r(lb) * 100
    local upper = r(ub) * 100
    post obs_data (`current_midpoint') (`n') (`prop') (`lower') (`upper')
}
postclose obs_data
display "Observed data saved successfully."

// STEP 3: Combine and create the final plot
display "Step 3: Creating the final combined graph for Figure 4"
use "`datadir'/predictions_for_plot.dta", clear
preserve
use "`datadir'/observed_data.dta", clear
keep estrato_midpoint obs_prop obs_lower obs_upper
save "`datadir'/obs_temp.dta", replace
restore
gen estrato_midpoint = .
replace estrato_midpoint = 45 if dias_pos_d2 >= 0 & dias_pos_d2 <= 90
replace estrato_midpoint = 135 if dias_pos_d2 > 90 & dias_pos_d2 <= 180
replace estrato_midpoint = 225 if dias_pos_d2 > 180 & dias_pos_d2 <= 270
replace estrato_midpoint = 290 if dias_pos_d2 > 270
merge m:1 estrato_midpoint using "`datadir'/obs_temp.dta", keep(master match) nogen
twoway (rarea lower_ci upper_ci dias_pos_d2, color(red%20) lwidth(none)) (line prob_pred dias_pos_d2, lcolor(red) lwidth(thick)) (scatter obs_prop estrato_midpoint if obs_prop != ., mcolor(dkblue) msize(large) msymbol(square)) (rcap obs_upper obs_lower estrato_midpoint if obs_prop != ., lcolor(dkblue)), graphregion(color(white)) plotregion(margin(zero)) title("Predicted Seropositivity Decline by Time Since Second Dose", size(large)) xtitle("Days since second dose (D2)", size(medium)) ytitle("IgG Seropositivity (%)", size(medium)) xlabel(0(50)350, labsize(small)) ylabel(0(20)100, angle(horizontal) format(%3.0f) labsize(small)) legend(order(2 "Predicted (Poisson, robust variance)" 1 "95% CI (Poisson model)" 3 "Observed proportion (95% CI)") pos(7) ring(0) size(small) bmargin(small)) note("Curve represents predicted probability for a 36.1-year-old female.", size(vsmall))
graph export "`datadir'/Figure4_Poisson_Decline_Curve.png", width(3200) replace
display "Figure 4 created successfully!"
Figure 5: Temporal Trends in IgG and RT-PCR Positivity
This figure presents a grouped bar chart comparing IgG seropositivity and RT-PCR positivity across time strata.
display "Creating Figure 5: Seropositivity and RT-PCR positivity rates by time since D2"
// PART 1: Load and prepare IgG seropositivity data
use "`datadir'/sorology_prep.dta", clear
gen estrato_tempo = .
replace estrato_tempo = 1 if dias_pos_d2 >= 0 & dias_pos_d2 <= 90
replace estrato_tempo = 2 if dias_pos_d2 > 90 & dias_pos_d2 <= 180
replace estrato_tempo = 3 if dias_pos_d2 > 180 & dias_pos_d2 <= 270
replace estrato_tempo = 4 if dias_pos_d2 > 270
keep soro_reagente estrato_tempo
save "`datadir'/igg_data_temp.dta", replace

// PART 2: Load and prepare RT-PCR data
clear
import excel "`datadir'/merge_vacina_SWAB_pos_vacina.xlsx", sheet("coletado_depois_vacinado") firstrow
keep if exame == "COVID-19, Biologia Molecular"
gen rtpcr_reagente = 1 if resultado == "Detectavel"
replace rtpcr_reagente = 0 if resultado == "Nao Detectavel"
capture confirm variable D2
if _rc == 0 {
    gen data_coleta_dt = date(data_coleta, "DMY")
    gen dias_pos_d2_rtpcr = data_coleta_dt - D2
}
else {
    gen data_coleta_dt = date(data_coleta, "DMY")
    gen dias_pos_d2_rtpcr = data_coleta_dt - d2
}
gen estrato_tempo = .
replace estrato_tempo = 1 if dias_pos_d2_rtpcr >= 0 & dias_pos_d2_rtpcr <= 90
replace estrato_tempo = 2 if dias_pos_d2_rtpcr > 90 & dias_pos_d2_rtpcr <= 180
replace estrato_tempo = 3 if dias_pos_d2_rtpcr > 180 & dias_pos_d2_rtpcr <= 270
replace estrato_tempo = 4 if dias_pos_d2_rtpcr > 270
keep rtpcr_reagente estrato_tempo
save "`datadir'/rtpcr_data_temp.dta", replace

// PART 3: Create combined dataset with proportions
clear
cap postclose fig5_data
postfile fig5_data estrato obs_type obs_prop obs_lower obs_upper obs_n using "`datadir'/fig5_data.dta", replace
use "`datadir'/igg_data_temp.dta", clear
forvalues i = 1/4 {
    ci proportions soro_reagente if estrato_tempo == `i', exact
    local igg_prop = r(mean) * 100
    local igg_lower = r(lb) * 100
    local igg_upper = r(ub) * 100
    local igg_n = r(N)
    post fig5_data (`i') (1) (`igg_prop') (`igg_lower') (`igg_upper') (`igg_n')
}
use "`datadir'/rtpcr_data_temp.dta", clear
forvalues i = 1/4 {
    ci proportions rtpcr_reagente if estrato_tempo == `i', exact
    local rtpcr_prop = r(mean) * 100
    local rtpcr_lower = r(lb) * 100
    local rtpcr_upper = r(ub) * 100
    local rtpcr_n = r(N)
    post fig5_data (`i') (2) (`rtpcr_prop') (`rtpcr_lower') (`rtpcr_upper') (`rtpcr_n')
}
postclose fig5_data
display "Data for Figure 5 prepared successfully."

// PART 4: Create the figure
use "`datadir'/fig5_data.dta", clear
gen bar_position = estrato - 0.2 if obs_type == 1
replace bar_position = estrato + 0.2 if obs_type == 2
twoway (bar obs_prop bar_position if obs_type == 1, color(gs8) barwidth(0.35) legend(label(1 "IgG Seropositivity (n = 544)"))) (bar obs_prop bar_position if obs_type == 2, color(gs12) barwidth(0.35) legend(label(2 "RT-PCR Positivity (n = 705)"))) (rcap obs_upper obs_lower bar_position, lcolor(black) lwidth(thin) legend(off)), graphregion(color(white)) plotregion(margin(zero)) title("Seropositivity and RT-PCR positivity rates by time since second dose (D2)", size(large)) xtitle("Time since second dose (D2)", size(medium)) ytitle("Proportion (%)", size(medium)) xlabel(1 "0-90 days" 2 "91-180 days" 3 "181-270 days" 4 ">270 days", labsize(small)) ylabel(0(20)100, angle(horizontal) format(%3.0f) labsize(small)) legend(pos(12) ring(0) size(small) bmargin(small)) note("Error bars represent 95% confidence intervals (exact binomial).", size(vsmall))
graph export "`datadir'/Figure5_Comparison.png", width(3200) replace
display "Figure 5 created successfully!"
erase "`datadir'/igg_data_temp.dta"
erase "`datadir'/rtpcr_data_temp.dta"
3. Appendix: Intermediate Files
The following .dta files are created during analysis and can be regenerated from the original Excel files:
	File
	Description

	vacina_prep.dta
	Prepared vaccination database

	sorology_prep.dta
	Prepared serology database

	swab_prep.dta
	Prepared RT-PCR database

	esus_prep.dta
	Prepared symptomatic cases database

	predictions_for_plot.dta
	Poisson model predictions for Figure 4

	observed_data.dta
	Observed proportions by time stratum

	fig5_data.dta
	Combined data for Figure 5



