//Coloc macro


close("*"); // close any window
// clears the Log window for this round
print("\\Clear");
// Clear previous results window
run("Clear Results");
//run("Clear Results");

 // Determine general analysis parameters 
Dialog.create("Experimental and Calculation Variables");
Dialog.addChoice("Name of Bait1", newArray("VPS25", "VPS20L", "VPS36A", "CHMP7"));
Dialog.addChoice("Bait1 Channel", newArray("C1-", "C2-", "C3-", "C4-"));
Dialog.addChoice("Name of Bait2", newArray("Dextran", "PDI2", "IscU", "VPS25", "VPS20L", "VPS36A", "CHMP7"));
Dialog.addChoice("Bait2 Channel", newArray("C1-", "C2-", "C3-", "C4-"));
Dialog.addFile("WEKA training model for Bait1", "defaultPath");
Dialog.addSlider("Threshold for WEKA segmentation", 0, 1, 0.8);
Dialog.addFile("WEKA training model for bait2", "defaultPath");
Dialog.addSlider("Threshold for WEKA segmentation bait 2", 0, 1, 0.8);
Dialog.addDirectory ("Select your input folder", "defaultPath");
Dialog.addDirectory ("Select your folder for results", "defaultPath");
Dialog.show();
bait1 = Dialog.getChoice();
channelBait1 = Dialog.getChoice();
bait2 = Dialog.getChoice();
channelBait2 = Dialog.getChoice();
modelBait1 = Dialog.getString();
t1= Dialog.getNumber();
modelBait2 = Dialog.getString();
t2 = Dialog.getNumber();
inputDir = Dialog.getString();
outputDir = Dialog.getString();
print ("Bait1 is ", bait1);
print ("Bait2 is ", bait2);
print ("Bait1 model is in ", modelBait1);
print ("Bait2 model is in ", modelBait2);
print ("Threshold of bait 1 is: ", t1);
print ("Threshold of bait 2 is: ", t2);
print ("Files will be saved in ", outputDir);
print ("Look your analysis values");
wait (5000); // give time to review analyses parameters

//Measure start time of the entire  workflow
startTime = getTime();

// Analysis
list = getFileList(inputDir);

print("-----The input folder contains "+list.length+" files that will be processed.-----");

for (i=0; i<list.length; i++) {

		
		print ("--- --- --- --- --- --- --- --- --- --- --- --- --- --");
		print ("--- --- --- ANALYSIS OF IMAGE"+i+1+" --- --- --- ");

		run("Bio-Formats Importer", "open=[" + inputDir + list[i] + "] color_mode=Default open_files open_all_series view=Hyperstack stack_order=XYCZT use_virtual_stack");
		title1=getTitle();

		// Gets the time at beginning of each cycle
		timeCycle = getTime();
		
		run("Split Channels");

			// Saves channel of bait1

			selectWindow(channelBait1+title1);
			saveTitle= outputDir+File.separator+bait1+"_image"+i+1;
			print("new file path is "+saveTitle);
			saveAs("Tiff", saveTitle);
			titleBait1 = getTitle();

			selectWindow(channelBait2+title1);
			saveTitle= outputDir+File.separator+bait2+"_image"+i+1;
			print("new file path is "+saveTitle);
			saveAs("Tiff", saveTitle);
			titleBait2 = getTitle();

			selectWindow(titleBait1);
			run("Duplicate...", "duplicate");
			run("Trainable Weka Segmentation");
			wait(1000); // Plugin needs time to initialise
			call("trainableSegmentation.Weka_Segmentation.loadClassifier", modelBait1);
			call("trainableSegmentation.Weka_Segmentation.getProbability");
			selectWindow("Probability maps");
			saveTitle= outputDir+File.separator+bait1+"_image"+i+1+"_Prob";
			print("new file path is "+saveTitle);
			saveAs("Tiff", saveTitle);

					run("Duplicate...", "title=signalProb duplicate range=2-2");
					selectWindow("signalProb");
					saveTitle= outputDir+File.separator+bait1+"_image"+i+1+"_signalProb";
					print("new file path is "+saveTitle);
					saveAs("Tiff", saveTitle);
					
					// only segmented regions with more than 50% certainty will be taken in account 
					run("Threshold...");
					setThreshold(t1, 1000000000000000000000000000000.0000);
					run("Convert to Mask", "method=Default background=Dark");
					saveTitle= outputDir+File.separator+bait1+"_image"+i+1+"_signalProb_binary";
					print("new file path is "+saveTitle);
					saveAs("Tiff", saveTitle);
					binaryBait1 = getTitle();
	
					selectWindow(binaryBait1);
					run("Divide...", "value=255");
					imageCalculator("Multiply create", binaryBait1, titleBait1);
					saveTitle= outputDir+File.separator+bait1+"_image"+i+1+"_multiplied";
					print("new file path is "+saveTitle);
					saveAs("Tiff", saveTitle);
					noBackgroundBait1 = getTitle();
					

			selectWindow(titleBait2);
			run("Duplicate...", "duplicate");
			run("Trainable Weka Segmentation");
			wait(1000); // Plugin needs time to initialise
			call("trainableSegmentation.Weka_Segmentation.loadClassifier", modelBait2);
			call("trainableSegmentation.Weka_Segmentation.getProbability");
			selectWindow("Probability maps");
			saveTitle= outputDir+File.separator+bait2+"_image"+i+1+"_Prob";
			print("new file path is "+saveTitle);
			saveAs("Tiff", saveTitle);
			
			
					run("Duplicate...", "title=signalProb duplicate range=2-2");
					selectWindow("signalProb");
					saveTitle= outputDir+File.separator+bait2+"_image"+i+1+"_signalProb";
					print("new file path is "+saveTitle);
					saveAs("Tiff", saveTitle);

					// only segmented regions with more than 50% certainty will be taken in account 
					run("Threshold...");
					setThreshold(t2, 1000000000000000000000000000000.0000);
					run("Convert to Mask", "method=Default background=Dark");
					saveTitle= outputDir+File.separator+bait2+"_image"+i+1+"_signalProb_binary";
					print("new file path is "+saveTitle);
					saveAs("Tiff", saveTitle);
					binaryBait2 = getTitle();
					selectWindow(binaryBait2);
					run("Divide...", "value=255");
					imageCalculator("Multiply create", binaryBait2, titleBait2);
					saveTitle= outputDir+File.separator+bait2+"_image"+i+1+"_multiplied";
					print("new file path is "+saveTitle);
					saveAs("Tiff", saveTitle);
					noBackgroundBait2 = getTitle();
					

					// run coloc2 plugin
					run("Coloc 2", "channel_1="+ noBackgroundBait1+ " channel_2=" + noBackgroundBait2+ " roi_or_mask=" + binaryBait1+ " threshold_regression=Costes show_save_pdf_dialog spearman's_rank_correlation manders'_correlation costes'_significance_test psf=3 costes_randomisations=100 save=" +outputDir+File.separator+"image"+i+"_coloc2_parametersCalc.pdf");

					print ("--- --- --- END OF ANALYSIS OF IMAGE"+i+1+" --- --- --- ");
					print ("--- --- --- --- --- --- --- --- --- --- --- --- --- --");
		
					// Determine time needed for each image analysed
 					timeImage = getTime();
 					print ("Coloc2 analysis for Image " + i+1 + " of the list took " , (timeImage - timeCycle), "ms or ", (timeImage - timeCycle)/1000, "s or ", (timeImage - timeCycle)/60000, "min or ", (timeImage - timeCycle)/(60000*60), "h to process!");

 					print("Predicted time remaining: ", (timeImage - timeCycle)/60000*list.length-(timeImage - timeCycle)/(60000*(i+1)), "min." );
 					
 					close("*");

 				
					
		// to free up RAM
		run("Collect Garbage");
		call("java.lang.System.gc");

	}

// save log
selectWindow("Log");
saveTitle= outputDir+File.separator+bait1+"_"+bait2+"_coloc2_log_Results.txt";
print("Saved results filepath is "+saveTitle);
saveAs("Text", saveTitle);

endTime = getTime();

print ("The whlole workflow took ", (endTime - startTime), "ms or ", (endTime - startTime)/1000, "s or ", (endTime - startTime)/60000, "min or ", (endTime - startTime)/(60000*60), "h!");
print ("----------All is done!----------------");