
Table S1. Summary statistics of the MolMeDB dataset at the date of submission (April 2026). These are expected to grow as the MolMeDB database and subsequent updates to the MolMeDB RDF are added.
	basic statistics

	triplets 
	34019186

	types
	61

	predicates
	28

	class statistics

	molecular entities
	476970

	membrane assay
	974454

	methods
	57

	membranes
	49

	transporter assays
	4472

	transporters
	208

	primary sources
	3220

	outlinks

	molecule to chebi
	2132

	molecule to chembl
	20703

	molecule to pdb
	857

	molecule to pubchem
	78359

	membrane components to chebi
	30

	transporters to UniProt
	208

	total outlinks
	102289



Query S2. We have used the capabilities of the MolMeDB RDF SPARQL endpoint to search for drug permeabilities in different membrane models for drugs that act as human ABC transporter inhibitors. Human ABC transporters have been identified using UniProt RDF and matching transporters, and their inhibitors have been found in MolMeDB RDF. Which of these inhibitors are drugs has been decided using ChEBI RDF. Their permeabilities in different membrane models have been found in MolMeDB.
SPARQL endpoint: https://idsm.elixir-czech.cz/sparql/endpoint/molmedb

PREFIX bao: <http://www.bioassayontology.org/bao#>
PREFIX ebi: <http://rdf.ebi.ac.uk/dataset/>
PREFIX GO: <http://purl.obolibrary.org/obo/GO_>
PREFIX mmdbvoc: <https://rdf.molmedb.upol.cz/vocabulary#>
PREFIX obo: <http://purl.obolibrary.org/obo/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX repr: <https://w3id.org/reproduceme#>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX up: <http://purl.uniprot.org/core/>

SELECT DISTINCT ?prot ?ChEBI_mol ?membrane ?LogPerm WHERE {
	# Human ABC transporters
	SERVICE <https://sparql.uniprot.org/sparql> {
		?prot up:classifiedWith GO:0140359 ;
       		  up:organism/up:scientificName "Homo sapiens" }
  
	# inhibitors of human ABC transporters with ChEBI match
	?assay bao:BAO_0090012 [ a bao:BAO_0000283 ;
    						skos:exactMatch ?prot ] ;
           bao:BAO_0090012 ?mol ;
           bao:BAO_0000208/^bao:BAO_0095000 [a mmdbvoc:InhibitionAssay ;
                           sio:SIO_000300 repr:PositiveResult ] .
	?mol  a bao:BAO_0000076 ;
          	rdfs:label ?name ;
           skos:closeMatch ?ChEBI_mol .
  
	# ChEBI molecules classified as drugs
	SERVICE <https://idsm.elixir-czech.cz/sparql/endpoint/idsm> { GRAPH ebi:chebi {
        	?ChEBI_mol rdfs:subClassOf
          		[ owl:someValuesFrom/rdfs:subClassOf* obo:CHEBI_23888 ;
            	  rdf:type owl:Restriction ;
            	  owl:onProperty obo:RO_0000087 ] ; }}

	?perm_assay bao:BAO_0090012 ?mol ;
  			    bao:BAO_0090012 [a mmdbvoc:MembraneModel ;
       						     rdfs:label ?membrane ];
     		    bao:BAO_0000208 [ a mmdbvoc:LogPerm ;
     							  sio:SIO_000300 ?LogPerm ] .
}


Query S3: an example of how to query SPARQL endpoint for computational/experimental data

PREFIX mmdbvoc: <https://rdf.molmedb.upol.cz/vocabulary#>
PREFIX bao: <http://www.bioassayontology.org/bao#>
PREFIX sachem: <http://bioinfo.uochb.cas.cz/rdf/v1.0/sachem#>

SELECT DISTINCT * WHERE {
  ?assay bao:BAO_0000208 ?endpoint ;
         bao:BAO_0000212 ?method .
  
  #method type
  #bao:BAO_0002202 - assay design method (experimental)
  #bao:BAO_0002094 - computational method
  #bao:BAO_0002301 - simulation method
  ?method a bao:BAO_0002202 .
  
  #endpoint type
  #mmdbvoc:LogPerm
  #mmdbvoc:LogK
  ?endpoint a mmdbvoc:LogK
}

