Additional File 2 – Stan model details

Full model statement for the hierarchical, continuous-time movement model with a dynamic behavioral parameter:

Stan code for the continuous time, dynamic parameter correlated random walk movement model. Corresponding Stan-type file available from co-authors upon request.


data {
  int N; // # of fixes in track
  vector[N] x; // x coordinates
  vector[N] y; // y coordinates
  vector[N] dt; // time intervals

  vector[N] cov_1; // covariates
  vector[N] cov_2;
  vector[N] cov_3;
  vector[N] cov_4;
  vector[N] cov_5;
}

parameters {

  vector[N] gamma_raw;                // logit behavior parameter -- time-varying, correlates steps
  real<lower=0> sigmax;               // movement process noise in x
  real<lower=0> sigmav;               // behavior process noise
  vector[7] beta;                     // covariate coefficients

}

transformed parameters{

  // Introduce the logit link on the behavior parameter
  vector<lower=0,upper=1>[N] gamma;

  for(j in 1:N){
    gamma[j] = inv_logit( gamma_raw[j] );

  }

}

model {

   // Prior on behavior process noise -- assume there is variability in behavior
  sigmav ~ inv_gamma( 2 , 5 );

  // Priors on movement process noise -- close to zero
  sigmax ~ inv_gamma( 3 , 1 ); 

  // Priors on coefficients -- null model is no effect of covariates on behavior
  beta ~ normal( 0 , 1 );

  for (i in 3:N) {

    // Behavior is a linear combination of covariates
    gamma_raw[i] ~ normal( beta[1] + beta[2] * cov_1[i] + beta[3] * cov_2[i] + beta[4] * cov_1[i]*cov_2[i] + beta[5] * cov_3[i] + beta[6] * cov_4[i] + beta[7] * cov_5[i], dt[i] * sqrt(sigmav) );


    // Movement process is independent in x and y
    x[i] ~ normal( x[i-1] + gamma[i] * ( dt[i] / dt[i-1] ) * ( x[i-1] - x[i-2] ) , dt[i] * sqrt(sigmax) );
    y[i] ~ normal( y[i-1] + gamma[i] * ( dt[i] / dt[i-1] ) * ( y[i-1] - y[i-2] ) , dt[i] * sqrt(sigmax) );

  }

}

2

image1.png
Aty
Individual movement process:  X;|X;; 1, 2 ~ N (xj,.q a2 (K1 = Xjama), AL, ,ﬂx,,l)

i1
Individual behavioral process: logit(v;:) ~ N (21,85, At 02 )
Population-level process: ﬂj,k ~N (ﬁ,,,k, Bk)
N (050, 05.)
~ N (0500 02,)
Priors: By ~N(0,T)

o7, ~N¥(3,3)
a2, ~N*(3,32)
a§ r~1G(2,1)
02 ~1G(2,1)
a2, ~1G(2,1)




