$SIZES PC=-40
$PROBLEM DIMNEW=3000 
$INPUT ID TIME DV MDV CMT AMT RATE WGT DROP DROP DROP DROP AGE ICL1 IV4 IV1 IQ1T4 IV5 ICL5 IV9 IQ5T9 IV10 ICL10 IV11 IQ10T11 IV12 IV15 
IQ12T15 ICL12 IV16 IV18 ICL16 IQ16T18 IV19 IV20 IV21 ICL19 IQ19T20 IQ19T21 IV22 IV24 IQ22T24 ICL22 IV25 IV27 IV28 IQ25T27 IQ25T28 ICL25 FIRST PDV
$SUBROUTINE ADVAN13 TOL=9
$MODEL
COMP (COMP1)  ;Morphine central/IV CMT
COMP (COMP2)  ;Morphine oral dosing CMT
COMP (COMP3)  ;Morphine rectal dosing CMT
COMP (COMP4)  ;Morphine peripheral CMT
COMP (COMP5)  ;Midazolam central/IV CMT
COMP (COMP6)  ;Midazolam oral/enteral dosing CMT
COMP (COMP7)  ;Midazolam buccal/nasal dosing CMT  
COMP (COMP8)  ;Midazolam rectal dosing CMT  
COMP (COMP9)  ;Midazolam peripheral CMT
COMP (COMP10) ;Fentanyl central CMT
COMP (COMP11) ;Fentanyl peripheral CMT
COMP (COMP12) ;Clonidine central/IV CMT  
COMP (COMP13) ;Clonidine oral/enteral dosing CMT
COMP (COMP14) ;Clonidine epidural dosing CMT
COMP (COMP15) ;Clonidine peripheral CMT
COMP (COMP16) ;Ketamine central/IV CMT  
COMP (COMP17) ;Ketamine intramuscular dosing CMT
COMP (COMP18) ;Ketamine peripheral CMT
COMP (COMP19) ;Propofol central/IV CMT 
COMP (COMP20) ;Propofol peripheral CMT 1
COMP (COMP21) ;Propofol peripheral CMT 2
COMP (COMP22) ;Lorazepam central/IV CMT
COMP (COMP23) ;Lorazepam oral/enteral dosing CMT  
COMP (COMP24) ;Lorazepam peripheral CMT 
COMP (COMP25) ;Methadon central CMT  
COMP (COMP26) ;Methadon oral/enteral dosing CMT  
COMP (COMP27) ;Methadon Peripheral CMT 1  
COMP (COMP28) ;Methadon Peripheral CMT 2 
COMP (COMP29) ;Dependence concentration Fentanyl
COMP (COMP30) ;Dependence concentration Morphine
COMP (COMP31) ;Dependence concentration Ketamine

$PK

; assign PK parameters from literature based on weight and age.
; Details on calculations and references used can be found in Supplemental Digital Content 1.
V4=IV4 
V1=IV1
V5=IV5 
V9=IV9 
V10=IV10
V11=IV11
V12=IV12 
V15=IV15
V16=IV16 
V18=IV18 
V19=IV19 
V20=IV20 
V21=IV21 
V22=IV22 
V24=IV24 
V25=IV25
V27=IV27
V28=IV28

CL1=ICL1 
Q1T4=IQ1T4 
CL5=ICL5 
Q5T9=IQ5T9 
CL10=ICL10 
Q10T11=IQ10T11 
Q12T15=IQ12T15 
CL12=ICL12 
CL16=ICL16 
Q16T18=IQ16T18 
CL19=ICL19 
Q19T20=IQ19T20 
Q19T21=IQ19T21 
Q22T24=IQ22T24 
CL22=ICL22
CL25 = ICL25
Q25T27 = IQ25T27
Q25T28 = IQ25T28

;set parameters for extravascular dosing
; morphine
K2T1 = 6; Oral absorption rate morphine 
F2 = 0.34 ; Oral bioavailability morphine 
K3T1 = 1; Rectal absorption rate morphine 
F3 = 0.533 ; Rectal bioavailability morphine 

; Midazolam
K6T5 = 1; oral enteral absorption rate Midazolam
F6 = 0.27; oral/enteral bioavailability Midazolam
K7T5 = 3; buccal/nasal absorption rate Midazolam
F7 = 0.83; buccal/nasal bioavailability Midazolam
K8T5 = 3; Rectal absorption rate Midazolam
F8 = 0.18; rectal bioavailability Midazolam

; Clonidine
K14T12 = 0.71; Epidural absorption rate Clonidine
F14 = 1; Epidural bioavailability Clonidine
K13T12 = 1.53; oral absorption rate Clonidine
F13 = 0.554 ; oral bioavailability Clonidine
ALAG13 = 0.148 ; oral absorption lag Clonidine

; S-Ketamine
F17 = 1; Intramuscular bioavailability Ketamine
K17T16 = 1.98; intramuscular absorption rate Ketamine

; Lorazepam
F23 = 0.93 ;oral bioavailability Lorazepam
K23T22= 1.04; Oral absorption rate Lorazepam
ALAG23 = 0.27 ;Oral absorption lag Lorazepam

; Methadone
F26 = 0.86 ;oral/enteral bioavailability methadone
K26T25 = 1 ;oral absorption rate methadone

;set parameters for distribution and clearance
; Morphine
KEL1 = CL1/V1
K1T4 = Q1T4/V1
K4T1 = Q1T4/V4

;Midazolam
KEL5 = CL5/V5
K5T9 = Q5T9/V5
K9T5 = Q5T9/V9

;Fentanyl
KEL10 = CL10/V10
K10T11 = Q10T11/V10
K11T10 =Q10T11/V11

;Clonidine
KEL12 = CL12/V12
K12T15 = Q12T15/V12
K15T12 =Q12T15/V15

; Ketamine
KEL16 = CL16/V16
K16T18 = Q16T18/V16
K18T16 = Q16T18/V18

; Propofol
K19T20 = Q19T20/V19
K20T19 = Q19T20/V20
K19T21 = Q19T21/V19
K21T19 =Q19T21/V21
KEL19 = CL19/V19

;lorazepam
KEL22 =CL22/V22
K22T24 =Q22T24/V22
K24T22 =Q22T24/V24

; Methadon
KEL25 = CL25/V25
K25T27 = Q25T27/V25
K27T25 = Q25T27/V27
K25T28 = Q25T28/V25
K28T25 = Q25T28/V28

MU_1 = THETA(2)
MU_2 = THETA(1)
MU_3 = THETA(3)
MU_4 = THETA(4)
MU_5 = THETA(5)
MU_6 = THETA(6)
MU_7 = THETA(7)
MU_8 = THETA(8)
MU_9 = THETA(9)
MU_10 = THETA(10)
MU_11 = THETA(11)

BASE = EXP(MU_2 + ETA(2))  ;baseline scale
DELTA = MU_1 + ETA(1)    ;unexplained variability (variance) 

LGPIN00 = MU_3 + ETA(3)
LGPIN0X = MU_4 + ETA(4)
LGPIN12 = MU_5 + ETA(5)

PIN00 = EXP(LGPIN00 )/(1+EXP(LGPIN00))
PIN0X = EXP(LGPIN0X )/(1+EXP(LGPIN0X))
PIN12 = EXP(LGPIN12 )/(1+EXP(LGPIN12))

KDEP1 = EXP(MU_6 + ETA(6))
SLOPE1 = EXP(MU_7 + ETA(7))
KDEP2 = EXP(MU_8 + ETA(8))
SLOPE2 = EXP(MU_9 + ETA(9))
KDEP3 = EXP(MU_10 + ETA(10))
SLOPE3 = EXP(MU_11 + ETA(11))

$DES
DADT(1) = K2T1 * A(2) + K3T1 * A(3) - KEL1 * A(1) - K1T4 * A(1) + K4T1 * A(4) ;central morphine CMT
DADT(2) = -K2T1 * A(2)
DADT(3) = -K3T1 * A(3)
DADT(4) = K1T4 * A(1) - K4T1 * A(4)
DADT(5) = 0;K6T5 * A(6) + K7T5 * A(7) + K8T5 * A(8) - KEL5 * A(5) - K5T9 * A(5) + K9T5 * A(9) ; central midazolam CMT
DADT(6) = 0;-K6T5 * A(6)
DADT(7) = 0;-K7T5 * A(7)
DADT(8) = 0;-K8T5 * A(8)
DADT(9) = 0;K5T9 * A(5) - K9T5 * A(9)
DADT(10) = -KEL10 * A(10) - K10T11 * A(10) + K11T10 * A(11) ; central fentanyl cmt
DADT(11) = K10T11 * A(10) - K11T10 * A(11)
DADT(12) = 0;K13T12 * A(13) + K14T12 * A(14) - KEL12 * A(12) - K12T15 * A(12) + K15T12 * A(15) ;central clonidine CMT
DADT(13) = 0;-K13T12 * A(13)
DADT(14) = 0;-K14T12 * A(14)
DADT(15) = 0;K12T15 * A(12) - K15T12 * A(15)
DADT(16) = K17T16 * A(17) - KEL16 * A(16) - K16T18*A(16) + K18T16 * A(18) ; central ketamine CMT
DADT(17) = -K17T16 * A(17) 
DADT(18) = K16T18 * A(16) - K18T16 * A(18)
DADT(19) = 0;K20T19 * A(20) + K21T19 * A(21) - KEL19 * A(19) - K19T20 * A(19) - K19T21 * A(19) ; central propofol CMT
DADT(20) = 0;K19T20 * A(19) - K20T19 * A(20)
DADT(21) = 0;K19T21 * A(19) - K21T19 * A(21)
DADT(22) = 0;K23T22 * A(23) - KEL22 * A(22) - K22T24 * A(22) + K24T22 * A(24) ; central lorazepam CMT
DADT(23) = 0;-K23T22 * A(23)
DADT(24) = 0;K22T24 * A(22) - K24T22 * A(24)
DADT(25) = 0;K26T25 * A(26) - (KEL25  + K25T27 + K25T28) * A(25) + K27T25 * A(27) + K28T25 * A(28) ; central methadon CMT
DADT(26) = 0;-K26T25 * A(26)
DADT(27) = 0;K25T27 * A(25) - K27T25 * A(27)
DADT(28) = 0;K25T28 * A(25) - K28T25 * A(28)
DADT(29) = KDEP1 * A(10)/V10 - KDEP1 * A(29) ;Dependence compartment fentanyl
DADT(30) = KDEP2 * A(1)/V1 - KDEP2 * A(30)   ;Dependence compartment morphine
DADT(31) = KDEP3 * A(16)/V16 - KDEP3 * A(31) ;Dependence compartment ketamine

$ERROR (OBS ONLY)
IF(PDV.EQ.0) PIN0 = PIN00
IF(PDV.GE.1) PIN0 = PIN0X
IF(FIRST.EQ.1) PIN0 = 0

PIN1 = 0.5 * PIN12 
PIN1 = PIN1 * (1-PIN0)
IF(FIRST.EQ.1) PIN1 = 0
PIN1D = PIN1*2
IF(PDV.EQ.0.OR.PDV.EQ.10) PIN1D = PIN1

PIN2 = 0.5 * PIN12 
PIN2 = PIN2 * (1-PIN0-PIN1D)
IF(FIRST.EQ.1) PIN2 = 0
PIN2D = PIN2*2
IF(PDV.LE.1.OR.PDV.GE.9) PIN2D = PIN2

PINFL = PIN0 + PIN1D + PIN2D

CPMOR = A(1)/V1
CPMIDA = A(5)/V5
CPFENT = A(10)/V10
CPCLON = A(12)/V12
CPKETA = A(16)/V16
CPPROP = A(19)/V19
CPLORA = A(22)/V22
CPMDON = A(25)/V25

LACK1 = A(29) - CPFENT
IF(LACK1.LT.0) LACK1=0

LACK2 = A(30) - CPMOR
IF(LACK2.LT.0) LACK2=0

LACK3 = A(31) - CPKETA
IF(LACK3.LT.0) LACK3=0

LAMB=BASE + LACK1 * SLOPE1 + LACK2 * SLOPE2 + LACK3 * SLOPE3
LFAC = GAMLN(DV+1)
IF(DV.LE.1) LFAC=0

PRDV = LAMB*(1-DELTA)*(LAMB*(1-DELTA)+DV*DELTA)**(DV-1)*EXP(-LAMB*(1-DELTA)-DV*DELTA)/EXP(LFAC)

;Calculate probability of each possible score
P0= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+0*DELTA)**(0-1)*EXP(-LAMB*(1-DELTA)-0*DELTA)/EXP(GAMLN(1))
P1= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+1*DELTA)**(1-1)*EXP(-LAMB*(1-DELTA)-1*DELTA)/EXP(GAMLN(2))
P2= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+2*DELTA)**(2-1)*EXP(-LAMB*(1-DELTA)-2*DELTA)/EXP(GAMLN(3))
P3= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+3*DELTA)**(3-1)*EXP(-LAMB*(1-DELTA)-3*DELTA)/EXP(GAMLN(4))
P4= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+4*DELTA)**(4-1)*EXP(-LAMB*(1-DELTA)-4*DELTA)/EXP(GAMLN(5))
P5= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+5*DELTA)**(5-1)*EXP(-LAMB*(1-DELTA)-5*DELTA)/EXP(GAMLN(6))
P6= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+6*DELTA)**(6-1)*EXP(-LAMB*(1-DELTA)-6*DELTA)/EXP(GAMLN(7))
P7= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+7*DELTA)**(7-1)*EXP(-LAMB*(1-DELTA)-7*DELTA)/EXP(GAMLN(8))
P8= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+8*DELTA)**(8-1)*EXP(-LAMB*(1-DELTA)-8*DELTA)/EXP(GAMLN(9))
P9= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+9*DELTA)**(9-1)*EXP(-LAMB*(1-DELTA)-9*DELTA)/EXP(GAMLN(10))
P10= LAMB*(1-DELTA)*(LAMB*(1-DELTA)+10*DELTA)**(10-1)*EXP(-LAMB*(1-DELTA)-10*DELTA)/EXP(GAMLN(11))

;Correction for truncation of poisson using total probability of scores [0, 10]
PTOT = P0 + P1 + P2 + P3 + P4 + P5 + P6 + P7 + P8 + P9 + P10

DIF = DV - PDV
YY =      (1-PINFL)*(PRDV/PTOT)
IF(DIF.EQ.0)              YY = PIN0+(1-PINFL)*(PRDV/PTOT)
IF(DIF.EQ.1.OR.DIF.EQ.-1) YY = PIN1+(1-PINFL)*(PRDV/PTOT)
IF(DIF.EQ.2.OR.DIF.EQ.-2) YY = PIN2+(1-PINFL)*(PRDV/PTOT)
IF(FIRST.EQ.1)           YY =      (1-PINFL)*(PRDV/PTOT)

IF(YY.LT.1E-100) YY = 1E-100

Y= -2*LOG(YY) 

$THETA
(-20, -0.622,2.3) ; baseline NRS score
(-0.1, 0.425,1) ; unexplaind variance
(-0.41) ; logit probability inflation of stable score if previous is 0
(-1.3) ; logit probablity inflation of stable score if previous is not zero
(-2.6) ; logit probability inflationof score at +-1 of previous score if score is not stable
(-5, -1.3, -0.5) ; log dependence rate
(-1, 1.6, 4) ; effect lack of fentanyl
(-7, -4.5, -1) ; log dependence rate
(0, 4.4, 8) ; effect lack of morfine
(-7, -4, -1) ; log dependence rate
(-4, 0.5, 3) ; effect lack of ketamine

$OMEGA
 0 FIX 
 0.957 ;basline
 0 FIX 
 0 FIX 
 0 FIX 
 0 FIX 
 0 FIX 
 0 FIX 
 0 FIX 
 0 FIX 
 0 FIX